*** Settings ***
Documentation     Tests divers sur la bonne saisie des résultats sur les unités et les centaines

Resource  resources/resources.robot

Suite Setup  Run Keywords  No Operation
        ...  AND    For Suite Setup
        ...  AND    Jeu de données

Suite Teardown  For Suite Teardown

*** Test Cases ***

# TODO les fonctionnalités de vérification de cohérence des résultats dans la saisie d'une unité
# ou d'une centaine ne sont pas testées.
# Elles devraient l'être ici

Une saisie de résultat partielle avec des zéros est considérée comme en erreur
    # À la base, l'unité est marquée comme en attente
    Depuis le contexte election  ${id_election}
    Page Should Contain Element
    ...  xpath=//div[@id='resultats']//article[.//span[contains(text(),'Salle des Mariages')]]//span[@title='Saisie' and contains(@class,'badge-pending')]

    # Saisie partielle d'une unité avec des zéros
    Depuis le contexte election_unite  ${id_election}  001 - Salle des Mariages
    Click On SubForm Portlet Action  election_unite  modifier
    Input Text  inscrit  728
    Input Text  votant  0
    Input Text  emargement  0
    Input Text  procuration  0
    Click On Submit Button In Subform

    # Vérifications : la saisie est en erreur dans les 2 affichages
    Depuis le contexte election  ${id_election}
    Page Should Contain Element
    ...  xpath=//div[@id='resultats']//article[.//span[contains(text(),'Salle des Mariages')]]//span[@title='Saisie' and contains(@class,'badge-error')]

    Click On Tab  election_unite  Unité(s)
    Page Should Contain Element
    ...  xpath=//div[@id='sousform-election_unite']//tr[.//a[contains(text(),'Salle des Mariages')]]//td[contains(@class,'col-10')]//i[@title="Erreur"]


Une saisie de résultat à zéro votant est bien considérée comme correcte
    [Tags]  regression

    [Documentation]  Ticket #10904 - Cas unité : personne n'est venu voter dans la journée

    # À la base, l'unité est marquée comme en attente
    Depuis le contexte election  ${id_election}
    Page Should Contain Element
    ...  xpath=//div[@id='resultats']//article[.//span[contains(text(),'Salle des fetes 1')]]//span[@title='Saisie' and contains(@class,'badge-pending')]

    # Saisie d'une unité avec 0 votant sur tous les champs de résultat
    Depuis le contexte election_unite  ${id_election}  002 - Salle des fetes 1
    Click On SubForm Portlet Action  election_unite  modifier
    Input Text  inscrit  864
    Input Text  votant  0
    Input Text  emargement  0
    Input Text  procuration  0
    Input Text  blanc  0
    Input Text  nul  0
    Input Text  candidat1  0
    Input Text  candidat2  0
    Click On Submit Button In Subform

    # Vérifications : la saisie est au vert dans les 2 affichages et on peut envoyer en validation
    Depuis le contexte election  ${id_election}
    Page Should Contain Element
    ...  xpath=//div[@id='resultats']//article[.//span[contains(text(),'Salle des fetes 1')]]//span[@title='Saisie' and contains(@class,'badge-valid')]

    Click On Tab  election_unite  Unité(s)
    Page Should Contain Element
    ...  xpath=//div[@id='sousform-election_unite']//tr[.//a[contains(text(),'Salle des fetes 1')]]//td[contains(@class,'col-10')]//i[@title="Arrivé"]

    Click Link  002 - Salle des fetes 1
    Wait Until Page Contains Element  css=#sousform-election_unite #sformulaire
    Portlet Action Should Be In SubForm  election_unite  demander_validation


Une saisie de centaine à zéro votant est bien considérée comme correcte
    [Tags]  regression
    [Documentation]  Ticket #10904 - Cas centaine : personne n'est venu voter de la journée

    Depuis le contexte centaine  ${id_election}  ${id_centaine}

    # À la base, l'unité est marquée comme en attente
    Page Should Contain Element
    ...  xpath=//div[contains(@id,'election_unite_overlay')]//tr[.//td[contains(text(),'Salle des fetes 1')]]//td[contains(@class,'col-10')]//i[@title="En attente"]                                                                    

    # Saisir une unité avec 0 votant sur la première centaine
    Click Link  xpath=//td[normalize-space(text()) = "002 - Salle des fetes 1"]//ancestor::tr/td[contains(@class, "icons")]/a
    Click On SubForm Portlet Action  election_unite  modifier
    Input Text  votant  0
    Input Text  blanc  0
    Input Text  emargement  0
    Input Text  procuration  0
    Input Text  nul  0
    Input Text  candidat1  0
    Input Text  candidat2  0
    Click On Submit Button In Subform

    # Vérification : dans le listing de la centaine, l'unité est bien marquée comme saisie
    Fermer la modale de l'unité dans la centaine
    Page Should Contain Element
    ...  xpath=//div[contains(@id,'election_unite_overlay')]//tr[.//td[contains(text(),'Salle des fetes 1')]]//td[contains(@class,'col-10')]//i[@title="Arrivé"]                                                                    


*** Keywords ***

Jeu de données
    Depuis la page d'accueil    admin  admin

    # Création de l'élection
    &{election} =  BuiltIn.Create Dictionary
    ...  libelle=Election pour saisie
    ...  code=038_saisie_resultats
    ...  type_election=Municipales
    ...  date=15/03/2026
    ...  perimetre=COMMUNE
    ...  heure_ouverture=08:00:00
    ...  heure_fermeture=12:00:00
    ...  calcul_auto_exprime=true
    ${id_election} =  Ajouter election  ${election}
    Set Suite Variable  ${id_election}

    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=David G.
    Ajouter election_candidat  ${candidat}  ${id_election}

    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=Jean Michel B.
    Ajouter election_candidat  ${candidat}  ${id_election}

    # Création d'une centaine
    &{centaine} =  BuiltIn.Create Dictionary
    ...  libelle=Première centaine
    ${id_centaine} =  Ajouter centaine à l'élection  ${centaine}  ${id_election}
    Set Suite Variable  ${id_centaine}

    # Passage à la saisie
    Depuis le contexte election  ${id_election}
    Passer à l'étape suivante  simulation  Simulation
    Depuis le contexte election  ${id_election}
    Passer à l'étape suivante  saisie  Saisie