*** Settings ***
Documentation     Test du workflow - étape de paramétrage - import des candidats via un fichier XML
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Jeu de données
    [Documentation]  L'objet de ce test case est de creer le jeu de données

    Depuis la page d'accueil    admin  admin
    # Creation d'une election
    &{election} =  BuiltIn.Create Dictionary
    ...  libelle=Election 023_02
    ...  code=EUR_23_02
    ...  type_election=Europeenes
    ...  date=09/06/2024
    ...  perimetre=COMMUNE
    ${id_election} =  Ajouter election  ${election}
    Set Suite Variable  ${id_election}

    # Création d'un candidat et d'un parti politique qui serviront
    # par la suite à vérifier que si ils existent déjà ils ne sont
    # pas re-créé
    &{values} =  Create Dictionary
    ...  libelle=parti_commun
    ...  couleur=#ff0000
    Ajouter parti_politique  ${values}
    Set Suite Variable  ${lib_parti_existant}  ${values.libelle}

    &{values} =  BuiltIn.Create Dictionary
    ...  libelle=candidat_commun
    Ajouter candidat  ${values}
    Set Suite Variable  ${lib_candidat_existant}  ${values.libelle}

Import des candidats via un fichier XML - Référence commune
    [Documentation]  Depuis le contexte de l'élection 023_02, clique sur l'action
    ...  "importer les candidats". Rempli le formulaire en choisissant comme unité
    ...  de référence la commune et valide le formulaire.
    ...  Vérifie ensuite les informations des candidats ajoutés à l'élection ainsi
    ...  que le paramétrage des candidats et leur parti.
    ...  Vérifie notamment que les candidats et partis existant ne sont pas en
    ...  doublons et que ceux qui n'existaient pas ont été ajoutés.

    &{import_values} =  Create Dictionary
    ...  fichier=xml_parametrage_election.xml
    ...  reference=commune
    ...  code_reference=23024
    Importer les candidats de l'élection  ${id_election}  ${import_values}
    # Vérification du message
    Valid Message Should Contain  Nouveaux partis politique ajoutés : 1
    Valid Message Should Contain  Nouveaux candidats ajoutés : 1
    Valid Message Should Contain  Candidats associés à l'élection : 2
    Valid Message Should Contain  Candidats dont l'ajout à échoué : 0

    # Vérification des candidats de l'élection, de leur numéro d'ordre, parti et code préfécture
    Depuis le contexte election_candidat par recherche  ${id_election}  ${lib_candidat_existant}
    Element Should Contain  css=#ordre  1
    Element Should Contain  css=#prefecture  001
    Element Should Contain  css=#parti_politique  ${lib_parti_existant}

    ${lib_new_candidat} =  Set Variable  CANDIDAT_REF_COMMUNE
    ${lib_new_parti} =  Set Variable  PARTI_REF_COM
    Depuis le contexte election_candidat par recherche  ${id_election}  CANDIDAT_REF_COMMUNE
    Element Should Contain  css=#ordre  2
    Element Should Contain  css=#prefecture  002
    Element Should Contain  css=#parti_politique  ${lib_new_parti}

    # Vérification de l'existance des partis
    Depuis le listing  parti_politique
    # Vérifie que le parti existant n'a pas de doublon
    Use Simple Search  Tous  ${lib_parti_existant}
    Element Should Contain  css=.tab-tab  ${lib_parti_existant}
    Element Should Contain  css=.pagination-text  1 - 1 enregistrement(s) sur 1
    # Vérifie que le nouveau parti a bien été ajouté
    Use Simple Search  Tous  ${lib_new_parti}
    Element Should Contain  css=.tab-tab  ${lib_new_parti}

    # Vérification de l'existance des candidats
    Depuis le listing  candidat
    # Vérifie que le candidat existant n'a pas de doublon
    Use Simple Search  Tous  ${lib_candidat_existant}
    Element Should Contain  css=.tab-tab  ${lib_candidat_existant}
    Element Should Contain  css=.pagination-text  1 - 1 enregistrement(s) sur 1
    # Vérifie que le nouveau candidat a bien été ajouté
    Use Simple Search  Tous  ${lib_new_candidat}
    Element Should Contain  css=.tab-tab  ${lib_new_candidat}

Import des candidats via un fichier XML - Format de fichier incorrect

    # Accède à l'élection
    Depuis le contexte election  ${id_election}
    # Accède au formulaire d'import
    Click On Form Portlet Action  election  import_candidats
    # Sélectionne un fichier n'ayant pas la bonne extension et vérifie le message d'erreur
    Add File and Expect Error Message Contain  fichier  candidat1.png  Le fichier n'est pas conforme à la liste des extension(s) autorisée(s)