*** Settings ***
Documentation     Test de l'affichage web
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Jeu de données
    [Documentation]  L'objet de ce test case est de creer le jeu de données
    ...  qui servira ensuite à tester le fonctionnement du portail web

    Depuis la page d'accueil    admin  admin

    # Ajout d'un logo
    Ajouter le logo  logo  openresultat  openResultat.png  logo openresultat

    # Création d'un modéle pour le portail web
    Set Suite Variable  ${titre}  Test personnalisation portail web
    &{web} =  BuiltIn.Create Dictionary
    ...  libelle=test
    ...  logo=openresultat
    ...  entete=${titre}
    ...  url_collectivite=url_test
    ...  libelle_url=test
    ...  feuille_style=* {color: #ff0000;}
    ...  jscript_stats=document.getElementById("footer").innerHTML = "Hello JavaScript!";
    ...  display_simulation=false
    ${id_modele_web} =  Ajouter web  ${web}
    Set Suite Variable  ${id_modele_web}

    #Création de deux unités, une mairie et deux bureaux à sa charge
    Set Suite Variable  ${ordre_ba}  1
    &{bureau_a} =  BuiltIn.Create Dictionary
    ...  libelle=Bureau d'A
    ...  type_unite=Bureau de vote
    ...  ordre=${ordre_ba}
    ...  code_unite=41
    ${id_bureau_a} =  Ajouter unite  ${bureau_a}
    Set Suite Variable  ${id_bureau_a}

    Set Suite Variable  ${ordre_bb}  2
    &{bureau_b} =  BuiltIn.Create Dictionary
    ...  libelle=Bureau n°B
    ...  type_unite=Bureau de vote
    ...  ordre=${ordre_bb}
    ...  code_unite=42
    ${id_bureau_b} =  Ajouter unite  ${bureau_b}
    Set Suite Variable  ${id_bureau_b}

    Set Suite Variable  ${ordre_bc}  3
    &{bureau_c} =  BuiltIn.Create Dictionary
    ...  libelle=Bûreau C
    ...  type_unite=Bureau de vote
    ...  ordre=${ordre_bc}
    ...  code_unite=43
    ${id_bureau_c} =  Ajouter unite  ${bureau_c}
    Set Suite Variable  ${id_bureau_c}

    Set Suite Variable  ${ordre_mabc}  4
    &{mairie} =  BuiltIn.Create Dictionary
    ...  libelle=Mairie ABC
    ...  type_unite=Mairie
    ...  ordre=${ordre_mabc}
    ...  perimetre=true
    ...  type_unite_contenu=Bureau de vote
    ${id_mairie} =  Ajouter unite  ${mairie}
    Set Suite Variable  ${id_mairie} 

    #lien entre ces unites pour obtenir le perimetre de l'election
    Ajouter lien_unite  Mairie ABC  42 - Bureau n°B
    Ajouter lien_unite  Mairie ABC  43 - Bûreau C
    Ajouter lien_unite  Mairie ABC  41 - Bureau d'A

    # Ajout d'un nouveaux plan et placement des unités sur ce plan
    &{plan} =  BuiltIn.Create Dictionary
    ...  libelle=Mairie ABC
    ...  image_plan=plan_centre.gif
    ...  img_unite_arrivee=img_unite_arrivee.gif
    ...  img_unite_non_arrivee=img_unite_non_arrivee.gif
    ...  par_defaut=true
    ...  largeur_icone=100
    ${id_plan} =  Ajouter plan  ${plan}
    Set Suite Variable  ${id_plan}

    # Coordonnées des points sur le plan conservé pour pouvoir tester
    # le positionnement des unités dans la suite des tests
    Set Suite Variable  ${position_x_A}  430
    Set Suite Variable  ${position_y_A}  290
    Set Suite Variable  ${position_x_B}  100
    Set Suite Variable  ${position_y_B}  50
    Set Suite Variable  ${position_x_C}  200
    Set Suite Variable  ${position_y_C}  50

    &{pos_bureau_a} =  BuiltIn.Create Dictionary
    ...  plan=Mairie ABC
    ...  unite=41 - Bureau d'A
    ...  img_unite_arrivee=bureau_a.png
    ...  position_x=${position_x_A}
    ...  position_y=${position_y_A}
    ...  largeur_icone=50
    ${id_plan_unite_a} =  Ajouter plan_unite  ${pos_bureau_a}
    Set Suite Variable  ${id_plan_unite_a}

    &{pos_bureau_b} =  BuiltIn.Create Dictionary
    ...  plan=Mairie ABC
    ...  unite=42 - Bureau n°B
    ...  img_unite_non_arrivee=bureau_na.png
    ...  position_x=${position_x_B}
    ...  position_y=${position_y_B}
    ${id_plan_unite_b} =  Ajouter plan_unite  ${pos_bureau_b}
    Set Suite Variable  ${id_plan_unite_b}

    &{pos_bureau_c} =  BuiltIn.Create Dictionary
    ...  plan=Mairie ABC
    ...  unite=43 - Bûreau C
    ...  position_x=${position_x_C}
    ...  position_y=${position_y_C}
    ${id_plan_unite_c} =  Ajouter plan_unite  ${pos_bureau_c}
    Set Suite Variable  ${id_plan_unite_c}

    # Creation d'une election avec les options de calcul auto des votes exprimés
    # et d'envoi auto à l'affichage activé
    &{election} =  BuiltIn.Create Dictionary
    ...  libelle=l'election de test de la page web
    ...  code=lyoko
    ...  type_election=Municipales
    ...  date=09/06/1995
    ...  perimetre=Mairie ABC
    ...  heure_ouverture=08:00:00
    ...  heure_fermeture=10:00:00
    ...  calcul_auto_exprime=true
    ${id_election} =  Ajouter election  ${election}
    Set Suite Variable  ${id_election}
    ${id_dossier_web_elec} =  Set Variable If  ${id_election} > 9  0${id_election}  00${id_election}
    Set Suite Variable  ${id_dossier_web_elec}
    Set Suite Variable  ${titre_election}  ${election.libelle} (${election.date})
    Element Should Contain In Subform  css=div.message  enregistrées

    # Durant l'étae de simulation, la saisie des résultats, l'accés à la page web
    # et le paramétrage de l'élection sont possible. C'est donc plus pratique pour
    # tester l'affichage web
    Passer à l'étape suivante  simulation  Simulation

    # Ajout de candidats
    Set Suite Variable  ${ordre_candidat1}  37
    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=David G.
    ...  ordre=${ordre_candidat1}
    Ajouter election_candidat  ${candidat}  ${id_election}

    Set Suite Variable  ${ordre_candidat2}  38
    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=Jean Michel B.
    ...  ordre=${ordre_candidat2}
    Ajouter election_candidat  ${candidat}  ${id_election}

    # Création d'une centaine
    &{centaine} =  BuiltIn.Create Dictionary
    ...  libelle=Centaine
    ...  votant_defaut=200
    ${id_centaine} =  Ajouter centaine à l'élection  ${centaine}  ${id_election}
    Set Suite Variable  ${id_centaine}
    ${id_dossier_web_centaine} =  Set Variable If  ${id_centaine} > 9  0${id_centaine}  00${id_centaine}
    Set Suite Variable  ${id_dossier_web_centaine}
    Set Suite Variable  ${titre_centaine}  ${centaine.libelle} (${election.date})


Gestion du fichier bypass pour accès au portail web
    [Documentation]  L'objet de ce test case est de vérifier que le fichier bypass pour accès au portail web
    ...  est correctement créé.

    # Vérification de la présence des fichiers envoyés lors de l'activation du modèle web
    Activer modèle web  ${id_modele_web}
    Le fichier doit exister  ../web/dyn/param.ini
    Le fichier doit exister  ../web/img/logo.png

    #Cas portail non activé
#    Go To  http://localhost/openresultat/web/index.php
#    Page Should Contain  Le portail web n'est pas actif
    Copy File  ${EXECDIR}${/}binary_files${/}bypass.json  ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json

    # Vérification que le fichier existe
    File Should Exist  ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json

    # Cas déconnecté et bypass redirection activé
    Depuis la page d'accueil    admin  admin
    Se déconnecter
    Go To  http://localhost/openresultat/web/index.php
    Page Should Contain  Vous devez être identifié pour accéder au portail.

    # Cas connecté et bypass redirection activé
    Depuis la page d'accueil    admin  admin
    Go To  http://localhost/openresultat/web/index.php
    Page Should Contain  Choix de l'élection


    Run  sed -i 's/"bypass_redirection": 1/"bypass_redirection":0/' ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json
    Run  sed -i 's/"bypass_general": 0,/"bypass_general":1,/' ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json

    # Cas déconnecté et bypass général activé
    Depuis la page d'accueil    admin  admin
    Se déconnecter
    Go To  http://localhost/openresultat/web/index.php
    Page Should Contain  Choix de l'élection

    # Cas connecté et bypass redirection activé
    Depuis la page d'accueil    admin  admin
    Go To  http://localhost/openresultat/web/index.php
    Page Should Contain  Choix de l'élection

    # Cas aucun bypass et déconnecté
    Run  sed -i 's/"bypass_general": 1,/"bypass_general": 0,/' ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json
    Run  sed -i 's/"bypass_redirection": 1/"bypass_redirection": 0/' ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json

    Depuis la page d'accueil    admin  admin

    Se déconnecter
    Go To  http://localhost/openresultat/web/index.php
    Page Should Contain  Choix de l'élection
    Remove File  ${EXECDIR}${/}..${/}web${/}dyn${/}bypass.json


Désactivation du modèle web
    [Documentation]  Test servant à vérifier que la désactivation du modèle entraine bien
    ...  la suppression du fichier de paramétrage et du logo dans le répertoire web.
    ...  Vérifie également que si aucun modèle n'est actif le portail web est désactivé.

    # Désactivation du modèle web
    Depuis la page d'accueil    admin  admin
    Depuis le contexte web  ${id_modele_web}
    Click On Form Portlet Action  web  desactiver  modale
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    La page ne doit pas contenir d'erreur

    # Vérification de la suppression des fichiers
    File Should Not Exist  ../web/dyn/param.ini
    File Should Not Exist  ../web/img/logo.png

    # Vérification de la désactivation du portail
    Go To  http://localhost/openresultat/web/index.php
    La page ne doit pas contenir d'erreur
    Page Should Contain  Le portail web n'est pas actif

    # Vérification de l'affichage du widget web
    Depuis la page d'accueil  admin  admin
    La page ne doit pas contenir d'erreur
    Page Should Contain  Le portail web n'est pas actif

Passage des unités en fin de validité
    [Documentation]  Pour éviter que les unités créées dans ce test ne provoquent
    ...  des erreurs liées à la vérification que le code unité est unique pour
    ...  les unités valides, on passe toutes les unités en fin de validité

    Passer l'unité en fin de validité  41
    Passer l'unité en fin de validité  42
    Passer l'unité en fin de validité  43