*** Settings ***
Documentation     Test de l'affichage responsive dans le container div#content
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Test Cases ***
Jeu de données
    [Documentation]  L'objet de ce test case est de creer le jeu de données
    ...  qui servira ensuite à tester le fonctionnement du calcul des sièges

    Depuis la page d'accueil    admin  admin

    # Nombre de siège non défini pour tester le remplissage avec les valeurs par défauts
    # issus du paramétrage
    &{election} =  BuiltIn.Create Dictionary
    ...  libelle=Municipales 1998 1er tour
    ...  code=MUN98-1
    ...  tour=1
    ...  principal=true
    ...  type_election=Municipales
    ...  date=15/03/1998
    ...  perimetre=COMMUNE
    ...  heure_ouverture=08:00:00
    ...  heure_fermeture=18:00:00
    ...  calcul_auto_exprime=true
    ...  sieges_mep=20
    ${id_election} =  Ajouter election  ${election}
    Set Suite Variable  ${id_election}
    Element Should Contain In Subform  css=div.message  enregistrées

    # Ajout des candidats
    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=David G.
    ...  ordre=1
    ...  prefecture=100
    ...  age_moyen=45
    ...  age_moyen_com=46
    ${id_candidat1} =  Ajouter election_candidat  ${candidat}  ${id_election}
    &{candidat} =  BuiltIn.Create Dictionary
    ...  candidat=Jean Michel B.
    ...  ordre=2
    ...  prefecture=101
    ...  age_moyen=38
    ...  age_moyen_com=41
    ${id_candidat2} =  Ajouter election_candidat  ${candidat}  ${id_election}

    # Durant l'étape de simulation, la saisie des résultats, le calcul des sièges
    # et le paramétrage de l'élection sont possible, c'est donc l'étape la plus pratique
    # pour ce test
    #Depuis le contexte election  ${id_election}

Affichage du portlet
    [Documentation]  L'objet de ce test case est de vérifier que les portlets s'affichent correctement, peu importe le format de la page.

    # Affichage en format Mobile
    Display screen as  Mobile 
    Depuis la page d'accueil    admin  admin
    Depuis le contexte election  ${id_election}
    # Le bouton d'action du portlet doit être visible
    Page Should Contain Element  css=label.display_portlet__label
    # Au clic sur le bouton, les liens d'actions du portlet doivent être visibles
    Click Element  css=label.display_portlet__label
    Element Should Be Visible  css=ul.election_portlet-list
    # On passe au format Desktop
    Display screen as  Desktop
    # Le bouton d'action du portlet ne doit pas être visible, mais les liens d'actions du portlet doivent être visibles
    Element Should Not Be Visible  css=label.display_portlet__label
    Element Should Be Visible  css=ul.election_portlet-list
    # On passe au format Mobile
    Display screen as  Mobile
    # N'ayant pas recliqué sur le bouton d'action du portlet, les liens d'actions du portlet doivent être visibles
    Element Should Be Visible  css=ul.election_portlet-list
    # On reclique sur le bouton d'action du portlet et la liste disparaît
    Click Element  css=label.display_portlet__label
    Element Should Not Be Visible  css=ul.election_portlet-list