*** Settings ***
Documentation     A resource file with reusable keywords and variables.
...
...               The system specific keywords created here form our own
...               domain specific language. They utilize keywords provided
...               by the imported Selenium2Library.
Library           Selenium2Library

*** Variables ***
${SERVER}         localhost
${BROWSER}        Firefox
${DELAY}          0
${VALID USER}     admin
${VALID PASSWORD}    admin
${LOGIN URL}      http://${SERVER}/openexemple/
${WELCOME URL}    http://${SERVER}/openexemple/scr/dashboard.php
${ERROR URL}      http://${SERVER}/openexemple/scr/login.php

*** Keywords ***
Open Browser To Login Page
    Open Browser    ${LOGIN URL}    ${BROWSER}
    Maximize Browser Window
    Set Selenium Speed    ${DELAY}
    Login Page Should Be Open

Login Page Should Be Open
    Element Text Should Be    css=#title h2    Veuillez Vous Connecter
    Title Should Be    :: openMairie :: openExemple - Framework

Go To Login Page
    Go To    ${LOGIN URL}
    Login Page Should Be Open
    Page Should Not Contain Errors

Go To Dashboard
    Click Link    css=#logo h1 a.logo
    Page Title Should Be    Tableau De Bord
    Page Should Not Contain Errors

Input Username
    [Arguments]    ${username}
    Input Text    login    ${username}

Input Password
    [Arguments]    ${password}
    Input Text    password    ${password}

Submit Credentials
    Click Button    login.action.connect

Error On Login Page Should Be Open
    Location Should Be    ${ERROR URL}
    Error Message Should Be    Votre identifiant ou votre mot de passe est incorrect.

Welcome Page Should Be Open
    Location Should Be    ${WELCOME URL}
    Valid Message Should Be    Votre session est maintenant ouverte.

Login With Credentials
    [Arguments]    ${username}    ${password}
    Open Browser To Login Page
    Input Username    ${username}
    Input Password    ${password}
    Submit Credentials
    Wait Until Element Is Visible    css=#actions a.actions-logout
    Element Should Contain    css=#actions a.actions-logout    Déconnexion
    Page Should Not Contain Errors

Logout
    Click Link    css=#actions a.actions-logout
    Login Page Should Be Open
    Page Should Not Contain Errors

Click On Back Button
    Click Element    css=a.retour
    Page Should Not Contain Errors

Click On Menu Rubrik
    [Arguments]    ${rubrikclass}
    Click Element    css=#menu ul#menu-list li.rubrik h3 > a.${rubrikclass}-20

Click On Menu Element In Rubrik
    [Arguments]    ${rubrikclass}    ${elemclass}
    Click On Menu Rubrik    ${rubrikclass}
    Wait Until Element Is Visible    css=#menu ul#menu-list li.rubrik ul.rubrik li.elem a.${elemclass}-16
    Click Element    css=#menu ul#menu-list li.rubrik ul.rubrik li.elem a.${elemclass}-16
    Page Should Not Contain Errors

Menu Element In Rubrik Should Be Selected
    [Arguments]    ${rubrikclass}    ${elemclass}
    Element Should Be Visible    css=#menu ul#menu-list li.rubrik ul.rubrik li.elem.ui-state-focus.${elemclass}

Page Title Should Be
    [Arguments]    ${messagetext}
    Wait Until Element Is Visible    css=#title h2
    Element Text Should Be    css=#title h2    ${messagetext}

First Tab Title Should Be
    [Arguments]    ${messagetext}
    Element Text Should Be    css=#formulaire ul.ui-tabs-nav li a    ${messagetext}

Page Should Not Contain Errors
    Page Should Not Contain    Erreur de base de données.
    Page Should Not Contain    Fatal error
    Page Should Not Contain    Parse error
    Page Should Not Contain    Notice

Message Should Be
    [Arguments]    ${messagetext}
    Element Text Should Be    css=div.message p span.text   ${messagetext}

Error Message Should Contain
    [Arguments]    ${messagetext}
    Element Should Contain    css=div.message.ui-state-error p span.text   ${messagetext}

Error Message Should Be
    [Arguments]    ${messagetext}
    Element Text Should Be    css=div.message.ui-state-error p span.text   ${messagetext}

Valid Message Should Be
    [Arguments]    ${messagetext}
    Element Text Should Be    css=div.message.ui-state-valid p span.text   ${messagetext}