*** Settings ***
Documentation  Test du fonctionnement du système des modules


# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Affichage de la page de paramétrage des modules
    [Documentation]  Avec un profil administrateur, depuis le menu paramétrage dossiers > workflows > événement
    ...  on vérifie si on n'as pas d'erreur à l'affichage de la page.

    Depuis la page d'accueil  admin  admin

    Set Suite Variable  ${libelle_evenement}  TEST_600_Modules

    # Création d'un événement de workflow de test du module
    @{etat_source} =  Create List
    ...    dossier accepter
    ...    dossier accepté tacitement
    ...    dossier rejeter manque de pieces
    ...    delai de notification envoye
    ...    dossier incomplet
    @{type_di} =  Create List
    ...    PCI - P - Initial
    ...    PA - P - Initial
    ...    DP - P - Initiale
    ...    IN - P - Initiale
    &{args_evenement} =  Create Dictionary
    ...  libelle=${libelle_evenement}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=recepisse_1 RECEPISSE DE DEPOT
    ...  document_type=Attestation

    Ajouter l'événement depuis le menu  ${args_evenement}

    Depuis le contexte de l'événement  ${libelle_evenement}

    Click Element Until New Element  css=#lien_module  css=.add-16
    # La page ne doit pas contenir d'erreurs
    La page ne doit pas contenir d'erreur

    Page Should Contain  lien_module

    # On s'assure de ne pas avoir d'erreur si aucun module n'est chargée
    # On vérifie l'existance du répertoire
    ${status_modules} =  Run Keyword And Return Status  Directory Should Exist  ${EXECDIR}${/}..${/}modules
    Set Suite Variable  ${status_modules}
    # On déplace le répertoire
    Run Keyword If  ${status_modules} == True  Run  mv ${EXECDIR}${/}..${/}modules ${EXECDIR}${/}..${/}tmp-modules
    # On tests les modules
    Run Keyword If  ${status_modules} == True  Depuis le contexte de l'événement  ${libelle_evenement}
    Run Keyword If  ${status_modules} == True  Click Element  css=#lien_module
    Run Keyword If  ${status_modules} == True  La page ne doit pas contenir d'erreur
    Run Keyword If  ${status_modules} == True  Page Should Contain  lien_module

Reset Params - Affichage de la page de paramétrage des modules
    # On rétablis l'existance le répertoire
    Run Keyword If  ${status_modules} == True  Run  mv ${EXECDIR}${/}..${/}tmp-modules ${EXECDIR}${/}..${/}modules