*** Settings ***
Documentation  Test de task.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  Run Keywords
    ...  For Suite Setup
    ...  AND    Activer le mode service consulté
    ...  AND    Activation des options des task
    ...  AND    Activation des platau_type_demande

Suite Teardown  Run Keywords
    ...  Désactiver le mode service consulté
    ...  AND    Desactivation des options des task
    ...  AND    For Suite Teardown


*** Test Cases ***
Vérification de l'ajout de deux consultation Plat'AU sur le même dossier dans le même traitement des tâches
    [Documentation]  Vérifie la création de dossier avec deux tâches issues de Plat'AU.
    ...  Dans ce contexte la 2ème tâche ne doit pas se retrouver en brouillon.
    
    # Suppression du suffixe P0 sur les PCI
    &{val_PCI} =  Create Dictionary
    ...  suffixe=false
    Modifier type de dossier d'instruction  PCI  P  ${val_PCI}

    # Isole le contexte du test (création d'une collectivité)
    &{librecom_1_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBRECOM_WS_DOUBLE_DI_PLATAU_1
    ...  departement=060
    ...  commune=040
    ...  insee=62040
    ...  direction_code=TT
    ...  direction_libelle=Direction de LIBRECOM_WS_DOUBLE_DI_PLATAU_1
    ...  direction_chef=Chef
    ...  division_code=TT
    ...  division_libelle=Division TT
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Agathe Youh
    ...  guichet_om_utilisateur_email=ayouh@openads-test.fr
    ...  guichet_om_utilisateur_login=ayouh
    ...  guichet_om_utilisateur_pwd=ayouh
    ...  instr_om_utilisateur_nom=Najem Cadamon
    ...  instr_om_utilisateur_email=ncadamon@openads-test.fr
    ...  instr_om_utilisateur_login=ncadamon
    ...  instr_om_utilisateur_pwd=ncadamon
    ...  code_entite=LBCOM_60
    ...  acteur=LIBRECOM-ACT-060

    &{librecom_2_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBRECOM_WS_DOUBLE_DI_PLATAU_2
    ...  departement=${librecom_1_values.departement}
    ...  commune=${librecom_1_values.commune}
    ...  insee=${librecom_1_values.insee}
    ...  direction_code=UU
    ...  direction_libelle=Direction de LIBRECOM_WS_DOUBLE_DI_PLATAU_2
    ...  direction_chef=Chef
    ...  division_code=UU
    ...  division_libelle=Division UU
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Zom Doug
    ...  guichet_om_utilisateur_email=zdoug@openads-test.fr
    ...  guichet_om_utilisateur_login=zdoug
    ...  guichet_om_utilisateur_pwd=zdoug
    ...  instr_om_utilisateur_nom=Gen Hial
    ...  instr_om_utilisateur_email=ghial@openads-test.fr
    ...  instr_om_utilisateur_login=ghial
    ...  instr_om_utilisateur_pwd=ghial
    ...  code_entite=LBCOM_61
    ...  acteur=LIBRECOM-ACT-061

    Isolation d'un contexte  ${librecom_1_values}
    Isolation d'un contexte  ${librecom_2_values}


    # active l'option entité pour la collectivité/le service
    &{param_entite} =  Create Dictionary
    ...  libelle=option_om_collectivite_entity
    ...  valeur=true
    ...  om_collectivite=${librecom_1_values["om_collectivite_libelle"]}
    Gerer le paramètre par WS  ${param_entite}
    # active l'option entité pour la collectivité/le service
    &{param_entite} =  Create Dictionary
    ...  libelle=option_om_collectivite_entity
    ...  valeur=true
    ...  om_collectivite=${librecom_2_values["om_collectivite_libelle"]}
    Gerer le paramètre par WS  ${param_entite}

    &{librecom_1_values_code_entite} =  Create Dictionary
    ...  libelle=code_entite
    ...  valeur=${librecom_1_values.code_entite}
    ...  om_collectivite=${librecom_1_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${librecom_1_values_code_entite}
    &{librecom_2_values_code_entite} =  Create Dictionary
    ...  libelle=code_entite
    ...  valeur=${librecom_2_values.code_entite}
    ...  om_collectivite=${librecom_2_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${librecom_2_values_code_entite}

    # ajouter le paramètre 'acteur' à la collectivité/au service
    &{platau_acteur_service_instructeur} =  Create Dictionary
    ...  libelle=platau_acteur_service_instructeur
    ...  valeur=${librecom_1_values["acteur"]}
    ...  om_collectivite=${librecom_1_values["om_collectivite_libelle"]}
    Gerer le paramètre par WS  ${platau_acteur_service_instructeur}
    &{platau_acteur_service_instructeur_2} =  Create Dictionary
    ...  libelle=platau_acteur_service_instructeur
    ...  valeur=${librecom_2_values["acteur"]}
    ...  om_collectivite=${librecom_2_values["om_collectivite_libelle"]}
    Gerer le paramètre par WS  ${platau_acteur_service_instructeur_2}


    # Rendre les PCI non transmissibles à Plat'AU (en activant uniquement les modificatifs)
    &{param_dit_filtre} =  Create Dictionary
    ...  libelle=dit_code__to_transmit__platau
    ...  valeur=M
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dit_filtre}

    ##
    ## Vérification de l'ajout d'un dossier d'instruction depuis Plat'AU
    ##

    # Récupère le payload de création DI
    ${di} =  Set Variable  PC0600402400001
    ${json_payload} =  Get File  ${EXECDIR}${/}binary_files${/}create_DI_for_consultation_payload_double_1.json
    ${json_payload} =  Replace String  ${json_payload}  PC0620402400005  ${di}
    ${json_payload} =  Replace String  ${json_payload}  L46-EMJ-5NO  ${librecom_1_values["acteur"]}
    ${json_payload} =  Replace String  ${json_payload}  L5G-GDW-Q1L  EEE-456-13
    ${json_payload} =  Replace String  ${json_payload}  LZY-Y76-M6O  13-EEE-456
    ${json_payload} =  Replace String  ${json_payload}  62510  ${librecom_1_values["insee"]}
    ${payload_dict} =  To Json  ${json_payload}
    ${task_values} =  Create Dictionary
    ...  type=create_DI_for_consultation
    ...  json_payload=${json_payload}
    ...  category=platau
    Ajouter la tâche par WS  ${task_values}

    # Récupère le payload de création DI
    ${json_payload_2} =  Get File  ${EXECDIR}${/}binary_files${/}create_DI_for_consultation_payload_double_2.json
    ${json_payload_2} =  Replace String  ${json_payload_2}  PC0620402400005  ${di}
    ${json_payload_2} =  Replace String  ${json_payload_2}  0K8-P4Z-PWK  ${librecom_2_values["acteur"]}
    ${json_payload_2} =  Replace String  ${json_payload_2}  L5G-GDW-Q1L  EEE-456-13
    ${json_payload_2} =  Replace String  ${json_payload_2}  LZY-Y76-M6O  13-EEE-456
    ${json_payload_2} =  Replace String  ${json_payload_2}  62510  ${librecom_2_values["insee"]}
    ${payload_dict_2} =  To Json  ${json_payload_2}
    ${task_values_2} =  Create Dictionary
    ...  type=create_DI_for_consultation
    ...  json_payload=${json_payload_2}
    ...  category=platau
    Ajouter la tâche par WS  ${task_values_2}

    ${msg} =  Déclencher le traitement des tâches par WS

    # En tant qu'admin
    Depuis la page d'accueil  admin  admin

    ${di_1} =  Set Variable  PC0600402400001LBCOM_6001
    &{seach_di_values} =  Create Dictionary
    ...  om_collectivite=${librecom_1_values["om_collectivite_libelle"]}
    Depuis le contexte du dossier d'instruction par la recherche avance  ${seach_di_values}  ${librecom_1_values["om_collectivite_libelle"]}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain Element  css=#dossier_libelle
    ${dossier_libelle} =  Get Text  css=#dossier_libelle
    ${di_created} =  Sans espace  ${dossier_libelle}
    Should Be Equal  ${di_1}  ${di_created}

    ${di_2} =  Set Variable  PC0600402400001LBCOM_6101
    &{seach_di_2_values} =  Create Dictionary
    ...  om_collectivite=${librecom_2_values["om_collectivite_libelle"]}
    Depuis le contexte du dossier d'instruction par la recherche avance  ${seach_di_2_values}  ${librecom_2_values["om_collectivite_libelle"]}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain Element  css=#dossier_libelle
    ${dossier_libelle_2} =  Get Text  css=#dossier_libelle
    ${di_2_created} =  Sans espace  ${dossier_libelle_2}
    Should Be Equal  ${di_2}  ${di_2_created}


Reset params - Vérification de l'ajout de deux consultation Plat'AU sur le même dossier dans le même traitement des tâches

    # Réactivation du suffixe P0 sur les PCI
    &{val_PCI} =  Create Dictionary
    ...  suffixe=true
    Modifier type de dossier d'instruction  PCI  P  ${val_PCI}

    # Ne plus restreindre les dossiers transmissibles à Plat'AU
    &{param} =  Create Dictionary
    ...  libelle=dit_code__to_transmit__platau
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param}