*** Settings ***
Documentation  Test la visualisation des pièces

Resource  resources/resources.robot

Suite Setup     Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données  
Suite Teardown  Run Keywords
    ...         Décomposition du jeu de données
    ...  AND    For Suite Teardown



*** Keywords ***

Composition du jeu de données
    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    &{option_miniature} =  Create Dictionary
    ...  libelle=option_miniature_fichier
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}

    # Création d'une demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Ature
    ...  particulier_prenom=Minnie
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di}

    # Variables communes
    ${now_yyyymmdd} =  Date du jour au format yyyymmdd
    Set Suite Variable  ${now_yyyymmdd}


Décomposition du jeu de données
    &{option_miniature} =  Create Dictionary
    ...  libelle=option_miniature_fichier
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}    

    &{option_miniature} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}


L'icone de prévisualisation est visible sur le fichier
    [Arguments]  ${nom_fichier}

    Page Should Contain Element  xpath=//*[normalize-space(text()) = "${nom_fichier}"]//ancestor::tr//*[contains(@title, "Prévisualiser")]


Le survol de l'icone de prévisualisation du fichier affiche la miniature
    [Arguments]  ${nom_fichier}

    Mouse Over  xpath=//*[normalize-space(text()) = "${nom_fichier}"]//ancestor::tr//*[contains(@title, "Prévisualiser")]
    Element Should be visible  xpath=//*[normalize-space(text()) = "${nom_fichier}"]//ancestor::tr/td[contains(@class, "icons")]//span[contains(@class, "tooltip-span")]/img



*** Test Cases ***

Affichage des miniatures sur les documents numérisées
    Depuis la page d'accueil  admin  admin

    # ajoute des pièces au dossier
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=20/09/2016
    ...  document_numerise_type=arrêté retour préfecture
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.jpg
    ...  date_creation=22/09/2016
    ...  document_numerise_type=arrêté retour préfecture
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    # revient sur le listing des pièces pour vérifier l'affichage dans le contexte du DI
    Click On Back Button In Subform
    
    # Vérifie que l'icone de prévisualisation est visible mais pas les images
    Wait Until Page Contains  20160920ART.pdf
    L'icone de prévisualisation est visible sur le fichier  20160920ART.pdf
    L'icone de prévisualisation est visible sur le fichier  20160922ART.jpg
    Element Should not be visible  css=span.tooltip-span img

    Le survol de l'icone de prévisualisation du fichier affiche la miniature  20160920ART.pdf
    Le survol de l'icone de prévisualisation du fichier affiche la miniature  20160922ART.jpg


# TODO ajouter un test case sur les miniatures sur les documents d'instruction générés


Affichage des miniatures sur les documents d'instruction importés
    Depuis la page d'accueil  admin  admin
    Depuis l'onglet des pièces du dossier d'instruction  ${di}
    Ouvrir le sous-onglet Docs. d'instruction

    # Ajouter un PDF et une image
    Cliquer sur le bouton d'ajout de document d'instruction importé
    &{doc_values} =  Create Dictionary
    ...  chemin_fichier_a_uploader=testImportManuel.pdf
    ...  document_type=Courrier (demande de prorogation)  # code 29
    Saisir le document d'instruction importé  ${doc_values}
    ${fichier_pdf}=  Set Variable  ${now_yyyymmdd}29.pdf  # Le fichier a été renommé en fonction de la date du jour et de son type
    Click On Submit Button In Subform
    Click On Back Button In Subform

    Cliquer sur le bouton d'ajout de document d'instruction importé
    &{doc_values} =  Create Dictionary
    ...  chemin_fichier_a_uploader=testImportManuel.jpg
    ...  document_type=Courrier (demande de prorogation)  # code 29
    Saisir le document d'instruction importé  ${doc_values}
    ${fichier_jpg}=  Set Variable  ${now_yyyymmdd}29.jpg  # Le fichier a été renommé en fonction de la date du jour et de son type
    Click On Submit Button In Subform


    Depuis l'onglet des pièces du dossier d'instruction  ${di}
    Ouvrir le sous-onglet Docs. d'instruction
    
    # Vérifie que l'icone de prévisualisation est visible mais pas les images
    L'icone de prévisualisation est visible sur le fichier  ${fichier_pdf}
    L'icone de prévisualisation est visible sur le fichier  ${fichier_jpg}
    Element Should not be visible  css=span.tooltip-span img

    Le survol de l'icone de prévisualisation du fichier affiche la miniature  ${fichier_pdf}
    Le survol de l'icone de prévisualisation du fichier affiche la miniature  ${fichier_jpg}


Affichage des miniatures sur les documents de travail
    Depuis la page d'accueil  admin  admin
    Depuis l'onglet des pièces du dossier d'instruction  ${di}
    Ouvrir le sous-onglet Docs. d'instruction

    # Ajouter un PDF et une image
    Click Element  id=action-soustab-document_numerise-corner-ajouter
    &{doc_travail_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=15/09/2025
    ${doc_travail} =  Ajouter un document de travail depuis le dossier d'instruction  ${di}  ${doc_travail_values}

    Click On Back Button In SubForm
    Click Element  id=action-soustab-document_numerise-corner-ajouter
    &{doc_travail_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.jpg
    ...  date_creation=15/09/2025
    ${doc_travail} =  Ajouter un document de travail depuis le dossier d'instruction  ${di}  ${doc_travail_values}

    Depuis l'onglet des pièces du dossier d'instruction  ${di}
    Ouvrir le sous-onglet Docs. d'instruction
    
    # Vérifie que l'icone de prévisualisation est visible mais pas les images
    L'icone de prévisualisation est visible sur le fichier  20250915DOCTRAV.jpg
    L'icone de prévisualisation est visible sur le fichier  20250915DOCTRAV.pdf
    Element Should not be visible  css=span.tooltip-span img

    Le survol de l'icone de prévisualisation du fichier affiche la miniature  20250915DOCTRAV.jpg
    Le survol de l'icone de prévisualisation du fichier affiche la miniature  20250915DOCTRAV.pdf