*** Settings ***
Documentation  Test la visualisation des pièces

Resource  resources/resources.robot

Suite Setup     Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données  
Suite Teardown  Run Keywords
    ...         Décomposition du jeu de données
    ...  AND    For Suite Teardown



*** Keywords ***

Composition du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...  données cohérent pour les scénarios fonctionnels qui suivent.

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}


Décomposition du jeu de données
    &{option_miniature} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}


Désactiver l'option de miniature des fichiers
    &{option_miniature} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_miniature_fichier
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}    


Cliquer sur l'icone de prévisualisation du fichier
    [Arguments]  ${nom_fichier}

    # clique sur le lien de prévisualisation (attends la fenêtre modale)
    # le lien de prévisualisation est reconnaissable par sa balise title="Prévisualiser", présent sur la ligne du libellé
    Click Element Until New Element
    ...  xpath=//*[normalize-space(text()) = "${nom_fichier}"]//ancestor::tr//*[contains(@title, "Prévisualiser")]/ancestor::a
    ...  css=.ui-widget-overlay



*** Test Cases ***


Test d'affichage prévisualisation - pièces

    [Documentation]  Vérifie l'affichage de la prévisualisation des pièces pour un pdf
    ...  et une image et un type de document non prévisualisable.

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Cloutier
    ...  particulier_prenom=Agate
    ...  om_collectivite=MARSEILLE
    #
    ${di_preview} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  admin  admin

    # ajoute une pièce au dossier
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=10/09/2016
    ...  document_numerise_type=arrêté retour préfecture
    Ajouter une pièce depuis le dossier d'instruction  ${di_preview}  ${document_numerise_values}

    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.jpg
    ...  date_creation=11/09/2016
    ...  document_numerise_type=arrêté retour préfecture
    Ajouter une pièce depuis le dossier d'instruction  ${di_preview}  ${document_numerise_values}

    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=fichier_1.odt
    ...  date_creation=12/09/2016
    ...  document_numerise_type=arrêté retour préfecture
    Ajouter une pièce depuis le dossier d'instruction  ${di_preview}  ${document_numerise_values}



    # reviens sur le listing des pièces pour vérifier l'affichage dans le contexte du DI
    Click On Back Button In Subform

    # vérifie que la pièce a bien été ajoutée
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=#sousform-document_numerise  20160910ART.pdf
    Element Should Contain  css=#sousform-document_numerise  20160911ART.jpg
    Element Should Contain  css=#sousform-document_numerise  20160912ART.odt

    # Test prévisualisation du pdf
    Cliquer sur l'icone de prévisualisation du fichier  20160910ART.pdf

    # vérifie que l'iframe PDF est bien chargée dans la fenêtre modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf

    # sélectionne l'iframe PDF
    Select Frame  frame_pdf

    # vérifie que le PDF contient la bonne valeur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  TEST IMPORT MANUEL 1

    # désélectionne l'iframe PDF
    Unselect Frame

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # Test prévisualisation de l'image
    Cliquer sur l'icone de prévisualisation du fichier  20160911ART.jpg

    # vérifie que l'image est bien affiché dans l'overlay
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog img

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # Test prévisualisation pour un type de document non prévisualisable
    Cliquer sur l'icone de prévisualisation du fichier  20160912ART.odt
    # vérifie que le message d'information et le lien de téléchargement sont bien affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div.text-info  Le format de ce fichier ne permet pas de le prévisualiser.
    Element Should Be Visible  css=a.lien-info

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # On ajoute une consultation pour vérifier le contexte d'une demande d'avis
    Ajouter une consultation depuis un dossier  ${di_preview}  59.01 - Direction de l'Eau et de l'Assainissement
    Depuis la page d'accueil  consu  consu
    Depuis l'onglet des pièces de la demande d'avis en cours du dossier d'instruction  ${di_preview}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=#sousform-document_numerise  20160910ART.pdf
    Element Should Contain  css=#sousform-document_numerise  20160911ART.jpg
    Element Should Contain  css=#sousform-document_numerise  20160912ART.odt

    # Test PDF
    Cliquer sur l'icone de prévisualisation du fichier  20160910ART.pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf
    Select Frame  frame_pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  TEST IMPORT MANUEL 1
    Unselect Frame
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay
    # Test image
    Cliquer sur l'icone de prévisualisation du fichier  20160911ART.jpg
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog img
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay
    # Test Autre
    Cliquer sur l'icone de prévisualisation du fichier  20160912ART.odt
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div.text-info  Le format de ce fichier ne permet pas de le prévisualiser.
    Element Should Be Visible  css=a.lien-info
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # Vérifie l'affichage dans le contexte du DA
    Depuis la page d'accueil  guichet  guichet
    ${da_preview} =  Get Substring  ${di_preview}  0  -2
    Depuis l'onglet des pièces du dossier d'autorisation  ${da_preview}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=#sousform-document_numerise  20160910ART.pdf
    Element Should Contain  css=#sousform-document_numerise  20160911ART.jpg
    Element Should Contain  css=#sousform-document_numerise  20160912ART.odt
    # Test PDF
    Cliquer sur l'icone de prévisualisation du fichier  20160910ART.pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf
    Select Frame  frame_pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  TEST IMPORT MANUEL 1
    Unselect Frame
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay
    # Test Image
    Cliquer sur l'icone de prévisualisation du fichier  20160911ART.jpg
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog img
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay
    # Test Autre
    Cliquer sur l'icone de prévisualisation du fichier  20160912ART.odt
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div.text-info  Le format de ce fichier ne permet pas de le prévisualiser.
    Element Should Be Visible  css=a.lien-info
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-document_numerise_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # supprime les pièces du dossier
    Depuis la page d'accueil  admin  admin
    Supprimer une pièce depuis le dossier d'instruction  ${di_preview}  arrêté retour préfecture
    Supprimer une pièce depuis le dossier d'instruction  ${di_preview}  arrêté retour préfecture
    Supprimer une pièce depuis le dossier d'instruction  ${di_preview}  arrêté retour préfecture


Test d'affichage prévisualisation - documents d'instruction

    [Documentation]  Vérifie l'affichage de la prévisualisation des documents d'instruction
    ...  et du rapport d'instruction

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Cloutier
    ...  particulier_prenom=Jeanne
    ...  om_collectivite=MARSEILLE
    #
    ${di_preview} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  instr  instr

    # Récupère le nom d'un document d'instruction existe
    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${di_preview}
    ${nom_fichier_doc_instr} =  Get Text  css=#sousform-document_instruction .tab-data td.col-1 span

    # clique sur le lien de prévisualisation (attends la fenêtre modale)
    Click Element Until New Element  css=div[data-view="document_numerise_dossier_final"]  css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]

    # On clique sur la prévisualisation du document
    Click Element    css=span[title="Prévisualiser"]

    # vérifie que l'iframe PDF est bien chargée dans la fenêtre modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf

    # sélectionne l'iframe PDF
    Select Frame  frame_pdf

    # vérifie que le PDF contient la bonne valeur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  RECEPISSE DE DEPOT

    # désélectionne l'iframe PDF
    Unselect Frame

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-instruction_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay


    Depuis la page d'accueil  admin  admin
    Ajouter le droit depuis le menu  storage  INSTRUCTEUR
    # Ajout et finalisation (x2) du rapport d'instruction
    Depuis la page d'accueil  instr  instr
    &{args_ri} =  Create Dictionary
    ...  description_projet_om_html=Description du projet v1
    Ajouter et finaliser le rapport d'instruction  ${di_preview}  ${args_ri}
    # Definaliser
    Depuis le contexte du rapport d'instruction  ${di_preview}
    Click On SubForm Portlet Action  rapport_instruction  definalise
    Wait Until Page Contains  La définalisation du document s'est effectuée avec succès.
    # Re-finalise pour avoir 2 versions
    &{args_ri} =  Create Dictionary
    ...  description_projet_om_html=Description du projet v2
    Modifier le rapport d'instruction  ${di_preview}  ${args_ri}
    Finaliser le rapport d'instruction  ${di_preview}

    # clique sur le lien de prévisualisation (attends la fenêtre modale)
    Depuis l'onglet des pièces du dossier d'instruction  ${di_preview}

    Click Element Until New Element  css=div[data-view="document_numerise_dossier_final"]  css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]
    Element Should Contain  css=#sousform-document_numerise table.tab-tab  rapport_instruction_1.pdf
    Element Should Contain  css=#sousform-document_numerise tr.dossier_final_piece_recommandee  rapport_instruction_2.pdf
    # Teste la prévisualisation du rapport d'instruction
    Cliquer sur l'icone de prévisualisation du fichier  rapport_instruction_1.pdf
    # vérifie que l'iframe PDF est bien chargée dans la fenêtre modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf

    # sélectionne l'iframe PDF
    Select Frame  frame_pdf

    # vérifie que le PDF contient la bonne valeur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  Description du projet v1

    # désélectionne l'iframe PDF
    Unselect Frame

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-storage_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    # Teste la prévisualisation du rapport d'instruction historisé
    Cliquer sur l'icone de prévisualisation du fichier  rapport_instruction_2.pdf
    # vérifie que l'iframe PDF est bien chargée dans la fenêtre modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf

    # sélectionne l'iframe PDF
    Select Frame  frame_pdf

    # vérifie que le PDF contient la bonne valeur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  Description du projet v2

    # désélectionne l'iframe PDF
    Unselect Frame

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-rapport_instruction_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay

    [Teardown]  Run Keywords
        ...         Depuis la page d'accueil  admin  admin
        ...  AND    Supprimer le droit depuis le contexte du profil  storage  INSTRUCTEUR   


Test d'affichage prévisualisation - documents de consultation
    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Cloutier
    ...  particulier_prenom=Marc
    ...  om_collectivite=MARSEILLE
    #
    ${di_preview} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Ajout d'une consultation
    Ajouter une consultation depuis un dossier  ${di_preview}  59.01 - Direction de l'Eau et de l'Assainissement

    Depuis la page d'accueil  instrpolycomm  instrpolycomm
    # clique sur le lien de prévisualisation (attends la fenêtre modale)
    Depuis l'onglet des pièces du dossier d'instruction  ${di_preview}
    Ouvrir le sous-onglet Dossier final

    Cliquer sur l'icone de prévisualisation du fichier  consultation_pour_conformite
    # vérifie que l'iframe PDF est bien chargée dans la fenêtre modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=.ui-dialog iframe#frame_pdf

    # sélectionne l'iframe PDF
    Select Frame  frame_pdf

    # vérifie que le PDF contient la bonne valeur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=div#viewer .page .textLayer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div#viewer .page .textLayer  Direction de l'Eau et de l'Assainissement

    # désélectionne l'iframe PDF
    Unselect Frame

    # ferme la fenêtre modale en cliquant sur le bouton retour
    Click Element Until No More Element
    ...  css=.ui-dialog div#sousform-consultation_preview_edition .retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Not Be Visible  css=.ui-widget-overlay