*** Settings ***
Documentation     Notification des demandeurs via le portail citoyen avec annexe -
...  Tests dédiés aux validations du message de confirmation lorsqu'on
...  clique sur l'action de notification.

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données
    Run Keyword If  '${CONTEXT_NOTIFICATION_CREATED}' == 'False'  Constitution du jeu de données - Notification
    Set Global Variable  ${CONTEXT_NOTIFICATION_CREATED}  True

    Construction du Parametrage - Notification

Activation de la notification par le portail citoyen
    [Documentation]  Activation de la notification par le portail citoyen

    # Modification du paramétrage de notification
    &{param_args} =  Create Dictionary
    ...  libelle=option_notification
    ...  valeur=mail
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Gerer le paramètre par WS  ${param_args}

    Set Suite Variable  ${message_confirmation}  Si vous le souhaitez, vous pouvez ajouter jusqu'à 5 annexes.
    Set Suite Variable  ${message_confirmation_2}  Sinon cliquez directement sur "Valider" pour notifier le pétitionnaire.
    Set Suite Variable  ${message_confirmation_hors_delai}  Vous êtes sur le point de notifier un document alors que la date limite d’instruction est dépassée. Êtes-vous sûr de vouloir effectuer cette action ?

Notification manuelle via portal avec annexe - Demande de confirmation - Date limite d'instruction non dépassée
    [Documentation]  Avec un profil instructeur, depuis le contexte d'un dossier en cours,
    ...   lors de la notification d'une instruction via le portail citoyen, vérifie le
    ...   contenu du message de demande de confirmation.

    # Ajout d'un dossier et d'une instruction notifiable
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=145_03_01
    ...  particulier_prenom=MSG_CONF_DATE_LIM_INSTR_OK
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mail@notif.fr
    ...  notification=t
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_msg_conf_1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # finalisation et ajout d'une date de retour signature sur une instruction
    # pour pouvoir la choisir comme annexe
    Depuis la page d'accueil  admin  admin
    Depuis l'instruction du dossier d'instruction  ${di_msg_conf_1}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  modifier_suivi

    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform

    # Ajout de l'instruction de notification
    Depuis la page d'accueil  mpaulet  mpaulet
    ${inst_notif_man_annexe} =  Ajouter une instruction au DI  ${di_msg_conf_1}  TEST_NOTIF_MAN_ANNEXE
    Click On Link  ${inst_notif_man_annexe}
    # L'action ne doit être dans le portlet
    Portlet Action Should Be In SubForm  instruction  overlay_notification_manuelle
    # Clique sur l'action de notification et vérifie le contenu du message
    Click On SubForm Portlet Action  instruction  overlay_notification_manuelle  modale
    # Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Wait Until Page Contains Element  css=#sousform-instruction_notification_manuelle
    # Vérifie le contenu du message
    Element Should Not Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation_hors_delai}
    Element Should Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation}
    Element Should Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation_2}
    # Le message de demande de confirmation doit contenir  ${message_confirmation_2}
    La page ne doit pas contenir d'erreur

    # Clique sur confirmer pour fermer la modale et ne pas risquer d'impacter les
    # autre test. Vérifie également que le déclenchement du traitement n'entraine
    # pas d'erreur.
    Click Element  css=.ui-dialog #sousform-instruction_notification_manuelle .formControls input.boutonFormulaire

Notification manuelle via portal avec annexe - demande de confirmation - Date limite d'instruction dépassée
    [Documentation]  Avec un profil instructeur, depuis le contexte d'un dossier dont la date
    ...  limite d'instruction est dépassé, lors de la notification d'une instruction via
    ...  le portail citoyen, vérifie le contenu du message de demande de confirmation.
    
    # Ajout d'un dossier et d'une instruction notifiable
    # La date de dépôt du dossier fait que sa date limite d'instruction est déjà dépassée
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=145_03_02
    ...  particulier_prenom=MSG_CONF_DATE_LIM_INSTR__PAS_OK
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=email@notif.fr
    ...  notification=t
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ...  date_demande=01/01/2024
    ${di_msg_conf_2} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Ajout de l'instruction de notification

    Depuis la page d'accueil  mpaulet  mpaulet
    ${inst_notif_man_annexe} =  Ajouter une instruction au DI  ${di_msg_conf_2}  TEST_NOTIF_MAN_ANNEXE
    Click On Link  ${inst_notif_man_annexe}
    # L'action ne doit être dans le portlet
    Portlet Action Should Be In SubForm  instruction  overlay_notification_manuelle
    # Clique sur l'action de notification et vérifie le contenu du message
    Click On SubForm Portlet Action  instruction  overlay_notification_manuelle  modale
    # Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Wait Until Page Contains Element  css=#sousform-instruction_notification_manuelle
    # Vérifie le contenu du message
    Element Should Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation_hors_delai}
    Element Should Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation}
    Element Should Contain  css=#sousform-instruction_notification_manuelle  ${message_confirmation_2}
    La page ne doit pas contenir d'erreur

    # Clique sur confirmer pour fermer la modale et ne pas risquer d'impacter les
    # autre test. Vérifie également que le déclenchement du traitement n'entraine
    # pas d'erreur.
    Click Element  css=.ui-dialog #sousform-instruction_notification_manuelle .formControls input.boutonFormulaire

Reset Params - TNR Message lorsque la notification n'est pas possible

    Destruction du Parametrage - Notification

    # Suppression du paramètre de notification
    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Gerer le paramètre par WS   ${param_args}