*** Settings ***
Documentation  Gestion des consultations.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Filtrage des tiers selon la collectivité/service de l'utilisateur
    [Documentation]  Vérifie que pour un utilisateur de la collectivité de niveau 2
    ...  la colonne "service" est visible dans le listing des tiers. Vérifie également
    ...  que la recherche avancé permet de filtrer par service.
    ...  En tant qu'administrateur d'une collectivité, vérifie que la colonne service et
    ...  la recherche par service ne sont plus visible tandis que le filtre par catégorie
    ...  ne propose que les catégories lié au service de l'utilisateur.
    ...  Vérifie qu'à l'ajout et la modification d'un tiers seule les catégories lié au
    ...  service de l'utilisateur apparaissent.

    # Ajout d'un nouveau tiers ayant une collectivité différentes
    Depuis la page d'accueil  admin  admin
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie ALLAUCH
    ...  abrege=TA
    ...  libelle=Tiers Allauch
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    &{lien_tiers_om_utilisateur} =  Create Dictionary
    ...  om_utilisateur=Service consulté 2
    ...  tiers_consulte=Tiers Allauch
    Ajouter lien utilisateur / tiers consulté  ${lien_tiers_om_utilisateur}

    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie MA
    ...  abrege=TMA
    ...  libelle=tiers M/A
    ...  ville=MARSEILLE
    ...  liste_diffusion=support@atreal.fr
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${args_tiers}

    Depuis le listing  tiers_consulte
    Wait until element contains  css=th.title.lastcol span.name  collectivité
    # Test du filtre de la recherche avancée par service
    Click Element  css=#toggle-advanced-display
    Wait Until Element Is Visible  css=div#adv-search-adv-fields select#om_collectivite
    Select From List By Label  css=div#adv-search-adv-fields select#om_collectivite  MARSEILLE
    Click On Search Button
    Element Should Contain  css=.tab-tab  MARSEILLE
    Element Should Contain  css=.tab-tab  Catégorie MA
    Element Should Not Contain  css=.tab-tab  ALLAUCH
    # Vérifie le contenu des select en ajout et en modification
    @{listeCategorie} =  Create List  Catégorie Marseille  Catégorie ALLAUCH  Catégorie MA
    Click On Add Button
    Select List Should Contain List  css=select#categorie_tiers_consulte  ${listeCategorie}
    Click On Back Button
    # Sélectionne le premier élément de la liste, accède à son formulaire de modification
    # et vérifie le contenu du select
    Click On Link  css=tbody > tr > td.col-1 > a.lienTable
    Wait until Page Contains Element  css=#tiers_consulte
    Click On Portlet Action  tiers_consulte  modifier
    Wait until Page Contains Element  css=select#categorie_tiers_consulte
    Select List Should Contain List  css=select#categorie_tiers_consulte  ${listeCategorie}

    # Vérification que pour le mode service consulté la colonne et le champs de recherche
    # s'appelle "service"
    # Activation du mode service consulté
    &{param_service_consulte} =  Create Dictionary
    ...  libelle=option_mode_service_consulte
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_service_consulte}

    Depuis la page d'accueil  admin  admin

    # Vérification des intitulé sur le listing des tiers
    Depuis le listing  tiers_consulte
    Wait until element contains  css=th.title.lastcol span.name  service
    Click Element  css=#toggle-advanced-display
    Wait Until Element Contains  css=div#adv-search-adv-fields label#lib-om_collectivite  Service
    # Désactivation du mode service consulté
    &{param_service_consulte} =  Create Dictionary
    ...  libelle=option_mode_service_consulte
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_service_consulte}

    # Connexion en tant qu'administrateur de Marseille
    Depuis la page d'accueil  admingenmars  admingenmars
    Depuis le listing  tiers_consulte
    Wait until page contains element  css=#tab-tiers_consulte
    # La colonne service n'est plus affichée
    Element Should Not Contain  css=th.title.lastcol span.name  collectivité
    # La recherche par service n'est plus affichée
    Click Element  css=#toggle-advanced-display
    Wait Until Element Is Visible  css=div#adv-search-adv-fields select#categorie_tiers_consulte
    Page Should Not Contain Element  css=div#adv-search-adv-fields select#om_collectivite
    # Seule les catégorie lié au service Marseille doivent pouvoir être sélectionnées
    @{listeCategorie} =  Create List  Catégorie Marseille  Catégorie MA
    @{list_value_unexpected} =  Create List  Catégorie ALLAUCH
    Select List Should Contain List  css=div#adv-search-adv-fields select#categorie_tiers_consulte  ${listeCategorie}
    Select List Should Not Contain List  css=div#adv-search-adv-fields select#categorie_tiers_consulte  ${list_value_unexpected}
    # Les tiers associé à d'autre service ne sont pas visible
    Element Should Not Contain  css=.tab-tab  ALLAUCH
    # Vérifie le contenu des select en ajout et en modification
    Click On Add Button
    Select List Should Contain List  css=select#categorie_tiers_consulte  ${listeCategorie}
    Select List Should Not Contain List  css=select#categorie_tiers_consulte  ${list_value_unexpected}
    Click On Back Button
    # Sélectionne le premier élément de la liste, accède à son formulaire de modification
    # et vérifie le contenu du select
    Click On Link  css=tbody > tr > td.col-1 > a.lienTable
    Wait until Page Contains Element  css=#tiers_consulte
    Click On Portlet Action  tiers_consulte  modifier
    Wait until Page Contains Element  css=select#categorie_tiers_consulte
    Select List Should Contain List  css=select#categorie_tiers_consulte  ${listeCategorie}
    Select List Should Not Contain List  css=select#categorie_tiers_consulte  ${list_value_unexpected}


Vérification du filtrage par libelle de catégorie de tiers consulté
    [Documentation]  Lorsque l'utilisateur se rend dans recherche avancée dans tiers consulté,
    ...  la recherche avancée doit filtrer correctement en retournant dans la liste
    ...  un filtrage par libelle.

    Depuis la page d'accueil  admin  admin

    # Ajout de catégories de tiers consulté
    &{args_cat_tiers} =  Create Dictionary
    ...  code=CW
    ...  description=Tiers de A
    ...  libelle=Catégorie A
    Ajouter la categorie de tiers consulte  ${args_cat_tiers}
    &{args_cat_tiers} =  Create Dictionary
    ...  code=CW
    ...  description=Tiers de B
    ...  libelle=Catégorie B
    Ajouter la categorie de tiers consulte  ${args_cat_tiers}
    &{args_cat_tiers} =  Create Dictionary
    ...  code=CW
    ...  description=Tiers de C
    ...  libelle=Catégorie C
    Ajouter la categorie de tiers consulte  ${args_cat_tiers}
    &{args_cat_tiers} =  Create Dictionary
    ...  code=CW
    ...  description=Tiers de D
    ...  libelle=Catégorie D
    Ajouter la categorie de tiers consulte  ${args_cat_tiers}

    # Ajout de tiers 
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie B
    ...  abrege=TNR_ACT
    ...  libelle=TNR ajout consultation tiers
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie A
    ...  abrege=TNR_ACT
    ...  libelle=TNR ajout consultation tiers
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie D
    ...  abrege=TNR_ACT
    ...  libelle=TNR ajout consultation tiers
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie C
    ...  abrege=TNR_ACT
    ...  libelle=TNR ajout consultation tiers
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    # Verifie que l'ordre est bien respecté 
    # en regardant que le premier element est bien celui attendu
    Depuis le listing  tiers_consulte
    Click Element  css=#toggle-advanced-display
    Element Should Contain  css=#categorie_tiers_consulte option:nth-of-type(2)  Catégorie A
    Element Should Contain  css=#categorie_tiers_consulte option:nth-of-type(2)  Catégorie A