*** Settings ***
Documentation     Page d'affichage des dossiers d'autorisation

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown


*** Test Cases ***
Constitution d'un jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...  données cohérent pour les scénarios fonctionnels qui suivent.

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Rivière
    ...  particulier_prenom=Coralie
    ...  om_collectivite=MARSEILLE
    #
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    ${da} =  Get Substring  ${di}  0  -2

    # Les dossiers sont accessibles dans la suite du test
    Set Suite Variable  ${di}
    Set Suite Variable  ${da}

TNR - Affichage de la page des dossier d'autorisations
    [Documentation]  Vérification de l'accès a la page des dossiers d'autorisations suir une URL fausse

    Depuis la page d'accueil  admin  admin

    # On supprime les éventuels espaces du libellé
    ${libelle_sans_espace} =  Sans espace  ${di}
    # On accède directement au tableau de tous les dossiers d'instruction
    Go To  ${PROJECT_URL}${OM_ROUTE_FORM}&obj=dossier_autorisation&action=3&idx=${libelle_sans_espace}

    Page Should Not Contain  Notice:
    Page Should Contain  Dossier '${libelle_sans_espace}' innexistant.