*** Settings ***
Documentation  Tests relatifs aux listings des dossiers d'instruction.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Variables ***
${NUM_TEST}      035
${NUM_SS_TEST}   040

${COLLECTIVITE}  NATURALCITY
${INSEE}         13088

# Nom, login et mdp des profils associes a la collectivite
${INSTRUCTEUR}   yjitae
${GUICHET}       jdoohong

*** Test Cases ***
SETUP - Preparation du jeu de donnees
    [Documentation]  Isolation d'un contexte specifique aux tests 035

    Depuis la page d'accueil  admin  admin

    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=${COLLECTIVITE}
    ...  departement=013
    ...  commune=088
    ...  insee=${INSEE} 
    ...  direction_code=T
    ...  direction_libelle=Direction de NATURALCITY
    ...  direction_chef=Chef
    ...  division_code=T
    ...  division_libelle=Division T
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Jung Doo-hong
    ...  guichet_om_utilisateur_email=${GUICHET}@openads-test.fr
    ...  guichet_om_utilisateur_login=${GUICHET}
    ...  guichet_om_utilisateur_pwd=${GUICHET}
    ...  instr_om_utilisateur_nom=Yoo Ji-tae
    ...  instr_om_utilisateur_email=${INSTRUCTEUR}@openads-test.fr
    ...  instr_om_utilisateur_login=${INSTRUCTEUR}
    ...  instr_om_utilisateur_pwd=${INSTRUCTEUR}
    Isolation du contexte si non existant  ${isolation_values}  


BUG - Listing - Doublon de dossier ayant plusieurs petitionnaires principaux

    # Ajout d'un dossier ayant plusieurs types de demandeurs principaux
    &{args_bailleur} =  Create Dictionary
    ...  particulier_nom=${NUM_TEST}
    ...  particulier_prenom=${NUM_SS_TEST} bailleur
    ...  om_collectivite=${COLLECTIVITE}
    &{args_demandeurs} =  Create Dictionary
    ...  bailleur_principal=${args_bailleur}

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=${NUM_TEST}
    ...  particulier_prenom=${NUM_SS_TEST} demandeur
    ...  om_collectivite=${COLLECTIVITE}


    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Fonds de commerce
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${COLLECTIVITE}

    ${dossier_bailleur} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}  ${args_demandeurs}

    Depuis la page d'accueil  ${INSTRUCTEUR}  ${INSTRUCTEUR}
    Depuis le listing  dossier_instruction
    Le dossier ne doit pas être en doublon sur le listing  ${dossier_bailleur}