*** Settings ***
Documentation  Tests relatifs au formulaire d'ajout d'une demande de nouveau dossier.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Initialisation du paramétrage - Vérifier les désactivation des champs de la page de validation

    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}

    # pour l'admin via l'agglo
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}

    Depuis la page d'accueil  admin  admin
    # Ajouter commune Aubagne
    &{aubagne_commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13400
    ...  reg=13
    ...  dep=13
    ...  libelle=AUBAGNE
    Ajouter commune avec dates validité  ${aubagne_commune}

Vérifier les désactivation des champs de la page de validation
    # En tant que guichetier
    Depuis la page d'accueil  guichet  guichet

    # On clique sur l'entrée de menu dédiée et on vérifie l'intégration
    # - ouverture du menu
    # - titre de la page
    # - titre de l'onglet
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    First Tab Title Should Be  Demande

    # Informations à saisir
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  commune=13400 - AUBAGNE
    ...  demande_type=Dépôt Initial
    ...  num_dossier_complet=PC00000024TST032
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Testing
    ...  particulier_prenom=AIDE
    ...  particulier_date_naissance=22/11/1988
    ...  particulier_commune_naissance=IPSwitch
    ...  numero=888
    ...  voie=Prom P B 
    ...  localite=AUBAGNE
    ...  telephone_fixe=0404040404

    # On remplit les champs de la demande
    Saisir la demande  ${args_demande}

    # On ajoute le pétitionnaire
    Ajouter le demandeur  petitionnaire_principal  ${args_petitionnaire}

    # On vérifie que le nom du pétitionnaire saisi est bien affiché dans le
    # formulaire de la demande
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=#petitionnaire_principal_delegataire  Testing AIDE
    
    # On valide
    Click On Submit Button

    # Vérification du message de validation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # Vérifier si le numéro de dossier complet est invisible
    Element Should Not Be Visible  css=#num_doss_complet

    # Vérifier si le numéro de dossier est utilisable
    Element Should Not Be Visible  css=#num_doss_division
    Element Should Not Be Visible  css=#num_doss_sequence

    # Vérifier si la comune est utilisable 
    Element Should Be Visible  css=#dossier_autorisation_type_detaille_chosen.chosen-disabled

    # Vérifier si la comune est utilisable 
    Element Should Be Visible  css=#demande_type[disabled="disabled"]

    # Vérifier si la comune est utilisable 
    Element Should Be Visible  css=#commune_chosen.chosen-disabled
    
    # Vérifier si la date de demande as un date picker
    Element Should Be Visible  css=#date_demande[disabled="disabled"]

    # Vérifier si la date de demande as un date picker
    Element Should Not Be Visible  css=#date_demande.champFormulaire.datepicker.hasDatepicker



Désactiver les paramètres
    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}

    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_dossier_commune
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}