*** Settings ***
Documentation  Tests relatifs au formulaire d'ajout d'une demande de nouveau dossier.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Initialisation du paramétrage - Suggestion par la saisie du Numéro de dossier.
    [Documentation]  Prépare le paramétrage nécessaires pour faire fonctionner le test case :
    ...  Active les options :  option_dossier_commune et option_dossier_saisie_numero_complet (agglo)

    &{param_saisie_complete} =  Create Dictionary
    ...  valeur=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_saisie_complete}

    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}


Création du jeu de données Commune_03
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données
    Run Keyword If   '${CONTEXT_COMMUNE_CREATED}' == 'False'   Initialisation du jeu de données Commune
    Set Global Variable  ${CONTEXT_COMMUNE_CREATED}  True


Suggestions commune en fonction des numéro de dossiers saisie
    [Documentation]  ...
    Depuis la page d'accueil  admin  admin

    # Jeux de tests des communes en 013
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13077
    ...  reg=13
    ...  dep=13
    ...  arr=133
    ...  ncc=TESTCITY013077
    ...  nccenr=TESTCITY013077
    ...  libelle=TESTCITY013077
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13177
    ...  reg=13
    ...  dep=13
    ...  arr=133
    ...  ncc=TESTCITY013177
    ...  nccenr=TESTCITY013177
    ...  libelle=TESTCITY013177
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13277
    ...  reg=13
    ...  dep=13
    ...  arr=133
    ...  ncc=TESTCITY013277
    ...  nccenr=TESTCITY013277
    ...  libelle=TESTCITY013277
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}
    # Jeux de tests des communes en 966
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=96601
    ...  reg=99
    ...  dep=966
    ...  arr=966
    ...  ncc=TESTLOIN96601
    ...  nccenr=TESTLOIN96601
    ...  libelle=TESTLOIN96601
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=96611
    ...  reg=99
    ...  dep=966
    ...  arr=966
    ...  ncc=TESTLOIN96611
    ...  nccenr=TESTLOIN96611
    ...  libelle=TESTLOIN96611
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}

    # Se connecter a l'application
    Depuis la page d'accueil  guichet  guichet

    # Se rendre au nouveau dossier.
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Attendre que le numéro de dossier soit afficher
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_complet
    Input Text until text is correct  css=#num_doss_complet  PC0130772200013
    Simulate Event  css=input#num_doss_complet  change

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # On vérifie qu'on as bien une commune suggerer
    Select From Chosen List Suggestions Should Contain  commune  13077 - TESTCITY013077

    # On vérifie qu'on as bien une commune proche non suggerer
    Select From Chosen List Should Contain  commune  13177 - TESTCITY013177
    Select From Chosen List Should Contain  commune  13277 - TESTCITY013277

    # Test des communes au numéro 966
    Input Text until text is correct  css=#num_doss_complet  PC96601122A0001
    Simulate Event  css=input#num_doss_complet  change

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # On vérifie qu'on as bien une commun suggerer
    Select From Chosen List Suggestions Should Contain  commune  96611 - TESTLOIN96611

    # On vérifie qu'on as bien une commune proche non suggerer
    Select From Chosen List Should Contain  commune  96601 - TESTLOIN96601


Suggestions dossier_autorisation_type_detaille en fonction des numéro de dossiers saisie
    [Documentation]  ...
    # Se connecter a l'application
    Depuis la page d'accueil  guichet  guichet

    # Se rendre au nouveau dossier.
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Attendre que le numéro de dossier soit afficher
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_complet
    Input Text until text is correct  css=#num_doss_complet  PC0131772200013
    Simulate Event  css=input#num_doss_complet  change

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # On vérifie que le 1er suggestion est présente
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  PCA - Permis de construire comprenant ou non des démolitions

    # On vérifie que la 2eme suggestion est présente
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  PCI - Permis de construire pour une maison individuelle et / ou ses annexes
   
    # On vérifie qu'on as bien une commun suggerer
    Select From Chosen List Suggestions Should Contain  commune  13177 - TESTCITY013177
    
    # Se connecter a l'application
    Depuis la page d'accueil  admin  admin

    # Se rendre au nouveau dossier.
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Saisir un deuxième numéro de dossier
    Input Text until text is correct  css=#num_doss_complet  IN0131772200013
    Simulate Event  css=input#num_doss_complet  change

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # Vérifier que les suggestions changent
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  IN - Infraction
    Select From Chosen List Suggestions Should Contain  commune  13177 - TESTCITY013177


Réinitialisation du paramétrage - Gestion de la commune associée au dossier
    [Documentation]  Désactive les options qui ont été activées pour faire fonctionner
    ...  le test case : Gestion de la commune associée au dossier.

    # désactiver l'option dossier_commune
    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}

    # Suppression de l'option
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}