*** Settings ***
Documentation  Tests relatifs au formulaire d'ajout d'une demande de nouveau dossier.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Constitue le jeu de données.
    # Mise en place du paramétrage nécessaire pour la suite des tests
    # On est dans un contexte MC

    # Activation du mode service consulté
    Activer le mode service consulté

    # Activation de l'option de saisie complete des numéros de dossier
    &{om_param_option_saisie_num_dossier} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param_option_saisie_num_dossier}

    # Activation de l'option code entité
    &{param_entite} =  Create Dictionary
    ...  libelle=code_entite
    ...  valeur=DOC
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS  ${param_entite}

    &{param_entite} =  Create Dictionary
    ...  libelle=option_om_collectivite_entity
    ...  valeur=true
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS  ${param_entite}

    Depuis la page d'accueil  admin  admin
    # Ajout d'un premier pétitionnaire
    &{args_petitionnaire_01} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Loco
    ...  particulier_prenom=Mautiv
    # Ajout d'un premier DI
    &{args_demande_01} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=01/12/2021
    ${libelle_di}=  Ajouter la demande par WS  ${args_demande_01}  ${args_petitionnaire_01}

    # Suppression du code entité du numéro de dossier et du suffixe "P0"
    @{libelle_di_splited}=  Split String  ${libelle_di}
    ${code_entity}=  Evaluate  len(${libelle_di_splited}) - 1
    Remove From List  ${libelle_di_splited}  ${code_entity}
    ${libelle_di_sans_espace} =  Evaluate  ''.join(${libelle_di_splited})
    # On enlève le suffixe 'P0'
    ${libelle_di_sans_espace} =  Get Substring  ${libelle_di_sans_espace}  0  -2
    Set Suite Variable  ${libelle_di_sans_espace}

    # Ajout d'un deuxième pétitionnaire
    &{args_petitionnaire_02} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Plopi
    ...  particulier_prenom=Tamago
    ...  particulier_date_naissance=01/01/1952
    ...  particulier_commune_naissance=LILLE
    ...  particulier_departement_naissance=NORD
    ...  numero=12
    ...  voie=RUE DE LA VOIX
    ...  complement=APPT 13
    ...  localite=MARSEILLE
    ...  code_postal=13002
    Set Suite Variable  ${args_petitionnaire_02}
    # Ajout d'un deuxième DI (associé au même DA)
    &{args_demande_02} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  date_demande=01/12/2023
    ...  num_dossier_complet=${libelle_di_sans_espace}
    ${libelle_di_avec_espace}=  Ajouter la nouvelle demande  ${args_demande_02}  ${args_petitionnaire_02}
    Set Suite Variable  ${libelle_di_avec_espace}

    # Ajout d'un troisième pétitionnaire
    &{args_petitionnaire_03} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Togo
    ...  particulier_prenom=Poly
    # Ajout d'un troisième DI (associé au même DA)
    &{args_demande_03} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  date_demande=01/12/2022
    ...  num_dossier_complet=${libelle_di_sans_espace}
    ${libelle_di}=  Ajouter la nouvelle demande  ${args_demande_03}  ${args_petitionnaire_03}

    # Ajout (sans validation du formulaire) d'un troisième pétitionnaire
    &{args_petitionnaire_without_validation} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Amphibo
    ...  particulier_prenom=Logie
    Set Suite Variable  ${args_petitionnaire_without_validation}
    # Ajout (sans validation du formulaire) d'un troisième DI (associé au même DA)
    &{args_demande_without_validation} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  date_demande=01/10/2022
    ...  num_dossier_complet=${libelle_di_sans_espace}DOC02
    Set Suite Variable  ${args_demande_without_validation}

    # INFRACTION
    # Ajout de plusieurs demandeurs principaux (contrevenant et plaignant)
    &{args_contrevenant_princ} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Taha
    ...  particulier_prenom=Rachid
    ...  particulier_date_naissance=01/01/1972
    ...  particulier_commune_naissance=LILLE
    ...  particulier_departement_naissance=NORD
    ...  numero=12
    ...  voie=RUE DE LA VOIX
    ...  complement=APPT 13
    ...  localite=MARSEILLE
    ...  code_postal=13002
    Set Suite Variable  ${args_contrevenant_princ}
    &{args_plaignant_princ} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Madame
    ...  particulier_nom=Barba
    ...  particulier_prenom=Clothilde
    ...  particulier_date_naissance=01/01/1982
    ...  particulier_commune_naissance=LILLE
    ...  particulier_departement_naissance=NORD
    ...  numero=13
    ...  voie=RUE DE LA COUCHE
    ...  complement=APPT 14
    ...  localite=MARSEILLE
    ...  code_postal=13005
    Set Suite Variable  ${args_plaignant_princ}
    &{args_autre_demandeurs} =  Create Dictionary
    ...  contrevenant_principal=${args_contrevenant_princ}
    ...  plaignant_principal=${args_plaignant_princ}
    # Ajout d'un dossier contentieux (Infraction)
    &{args_demande_04} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=IN - Infraction
    ...  date_demande=01/12/2023
    ...  num_dossier_complet=${libelle_di_sans_espace}
    ${libelle_di_infraction_avec_espace}=  Ajouter la nouvelle demande  ${args_demande_04}  ${EMPTY}  ${args_autre_demandeurs}  menu=infraction
    Set Suite Variable  ${libelle_di_infraction_avec_espace}

    # Suppression du code entité du numéro de dossier
    @{libelle_di_splited}=  Split String  ${libelle_di}
    ${code_entity}=  Evaluate  len(${libelle_di_splited}) - 1
    Remove From List  ${libelle_di_splited}  ${code_entity}
    ${libelle_di_infraction_sans_espace} =  Evaluate  ''.join(${libelle_di_splited})
    Set Suite Variable  ${libelle_di_infraction_sans_espace}


Gestion du contenu du message d'information sur l'existance d'un DI lors d'un nouvelle demande
    [Documentation]  On vérifie que la gestion de la checkbox "saisir le numéro de dossier" se
    ...  fait correctement et que le contenu du message est conforme à ce que l'on attend.
    ...  On vérifie que le message s'il existe contient bien :
    ...  - le message "Un dossier avec le même numéro de dossier a été trouvé",
    ...  - Ouvrir dans un nouvel onglet
    ...  - le Nom Prénom (type de demandeur) (exemple : Togo Poly (Demandeur principal))
    ...  - une url de redirection vers la fiche de consultation du DI trouvé,
    ...  - un bouton "utiliser les informations de ce dossier", qui permet de copier les données.
    ...  On vérifie que l'url de redirection, nous redirige bien au bon endroit (dossier_instruction) 
    ...  la fiche de consultation du DI correspond bien aux informations du DI trouvé.
    ...  Et pour finir on vérifie qu'en selectionnant->deselectionnant->reselection la checkbox (qui sera au final à true),
    ...  les données étant saisie la première fois dans le champ de saisie du numéro de dossier, ainsi que le message
    ...  d'information sur l'existance d'un DI avec le même numéro de dossier sont bien supprimées.
    Depuis la page d'accueil  admin  admin

    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_without_validation}  ${args_petitionnaire_without_validation}
    # On vérifie qu'on est dans le bon contexte de la vérification
    Le titre de la page doit contenir  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    # On attend que le message soit bien visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # Vérification du contenu du message et de la présence du bouton de copie des données du demandeur
    # ainsi que de l'url (dernier DI déposé -> DOC02)
    Form Value Should Contain  css=#num_doss_complet  ${args_demande_without_validation.num_dossier_complet}
    Element Should Be Visible  css=#display_message_di_exist
    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${libelle_di_avec_espace} Ouvrir dans un nouvel onglet\nDemandeur :\n ${args_petitionnaire_02.particulier_nom} ${args_petitionnaire_02.particulier_prenom} (Demandeur principal)\nUTILISER LES INFORMATIONS DE CE DOSSIER
    ${url_DI_exist}=  Set Variable  http://localhost/openads/app/index.php?module=form&obj=dossier_instruction&action=3&idx=${libelle_di_sans_espace}DOC02
    # On vérifie que le href du lien redirige bien sur le DOC02 (dernier DI ajouté) de l'objet dossier_instruction en mode consultation
    ${href_value} =  Get Element Attribute  css:#link_to_di  href
    Should Be Equal  ${href_value}  ${url_DI_exist}
    Element Should Contain  css=.button_copy_data_demandeur  UTILISER LES INFORMATIONS DE CE DOSSIER

    # Vérification du contenu de l'onglet ouvert via le lien "Ouvrir dans un nouvel onglet" (url de redirection)
    Click Link  css=#link_to_di
    Sleep  2
    # Récupération des handles (id unique pour chaque onglet)
    ${handles} =  Wait Until Keyword Succeeds  20s  5s  Get Window Handles
    # On bascule sur le nouvel onglet (DI en consultation)
    Select Window  ${handles[1]}
    # On vérifie qu'on est dans le bon contexte de la vérification
    # Le DI est le dernier dossier déposé (date_depot) des DI lié au DA, lui même lié au numéro de DI saisie par l'utilisateur 
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Le titre de la page doit contenir  Instruction > Dossiers D'instruction > PC 013055 21 00001 DOC02 PLOPI TAMAGO
    ${current_url} =  Get Location
    # On vérifie que l'url correspond bien à ce qui est attendu
    Should Be Equal  ${href_value}  ${url_DI_exist}
    # On ferme l'onglet
    Close Window

    # On reviens sur la fenêtre principale (nouvelle demande en cours de saisie)
    Select Window  ${handles[0]}
    # On vérifie qu'on est dans le bon contexte de la vérification
    Le titre de la page doit contenir  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    
    # Vérification de la gestion du passage de true à false et false à true de la checkbox "saisir le numéro de dossier"
    # On selectionne la checkbox d'annulation de saisie du numéro de dossier (true)
    Click Element Until New Element  css=#no_num_doss_complet  css=#no_num_doss_complet[value="Oui"]
    #On vérifie que le numéro de dossier n'est plus saissisable
    Wait Until Element Is Visible  css=#num_doss_complet[disabled="disabled"]
    # et que le message d'information est supprimé
    Wait Until Element Is Not Visible  css=#display_message_di_exist

    # On selectionne à nouveau la checkbox de saisie du numéro de dossier (true)
    Click Element Until New Element  css=#no_num_doss_complet  css=#no_num_doss_complet[value=""]
    # Le message d'information est toujours affiché (car le numéro de dossier est toujours saisie dans le champs correspondant)
    Wait Until Element Is Visible  css=#display_message_di_exist


Gestion de l'affichage du message d'information sur l'existance d'un DI lors d'un nouvelle demande (Infraction)
    [Documentation]  On vérifie que l'affichage du message ainsi que son contenu, est correctement saisie
    ...  dans le contexte d'une infraction (il peu y avoir plusieurs demandeur principaux).
    ...  On vérifie que le message s'il existe contient bien :
    ...  - le message "Un dossier avec le même numéro de dossier a été trouvé",
    ...  - Ouvrir dans un nouvel onglet
    ...  - le Nom Prénom (type de demandeur) (exemple : Togo Poly (Contrevenant principal))
    ...  - une url de redirection vers la fiche de consultation du DI trouvé,
    ...  - un bouton "utiliser les informations de ce dossier", qui permet de copier les données.
    ...  On vérifie que les données des deux demandeurs (contrevenant et plaignant) sont bien saisie, 
    ...  et que la copie de leurs données se fait correctement et dans les bon fieldset.
    ...  On vérifie également que si l'on souhaite ajouter un autre contrevenant et un autre plaignant, 
    ...  ils ne seront pas des demandeurs principaux, car ces demandeurs là sont déjà saisie.
    Depuis la page d'accueil  admin  admin

    # Collectivité non lié au DI & numéro de dossier mal renseigné
    &{args_demande} =  Create Dictionary
    ...  om_collectivite=agglo
    ...  dossier_autorisation_type_detaille=IN - Infraction
    ...  date_demande=01/10/2022
    ...  num_dossier_complet=13055

    # Saisie du numéro de dossier mal renseigné ( + collectivité non lié au DI) -> aucun message
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${EMPTY}
    # On vérifie qu'on est dans le bon contexte de la vérification
    Le titre de la page doit contenir  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    # Le message n'est pas visible
    Element Should Not Be Visible  css=#display_message_di_exist

    # Saisie du numéro de dossier correctement renseigné ( + collectivité non lié au DI) -> aucun message
    Input Text  css=#num_doss_complet  ${libelle_di_infraction_sans_espace}DOC04
    # Le message n'est pas visible
    Wait Until Element Is Not Visible  css=#display_message_di_exist

    # Saisie du numéro de dossier correctement renseigné (sur DOC04) ( + collectivité lié au DI) -> message affiché (avec dernier DI trouvé DOC04)
    Select From List By Label  css=#om_collectivite  MARSEILLE
    # On attend que le message soit bien visible
    Sleep  2
    # Vérification du contenu du message et de la présence du bouton de copie des données du demandeur
    # ainsi que de l'url (dernier DI déposé -> DOC04)
    Form Value Should Contain  css=#num_doss_complet  ${libelle_di_infraction_sans_espace}DOC04
    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${libelle_di_infraction_avec_espace} Ouvrir dans un nouvel onglet\nDemandeurs :\n ${args_plaignant_princ.particulier_nom} ${args_plaignant_princ.particulier_prenom} (Plaignant principal)\n ${args_contrevenant_princ.particulier_nom} ${args_contrevenant_princ.particulier_prenom} (Contrevenant principal)\nUTILISER LES INFORMATIONS DE CE DOSSIER

    # Gestion du bouton de copie des données du demandeur
    Click Button  css=.button_copy_data_demandeur
    # On vérifie que les données on bien été récupérées et insérées dans les blocs des demandeurs correspondants
    # Contrevanant
    Wait Until Element Is Visible  css=#contrevenant_principal
    Element Should Contain  css=#contrevenant_principal  ${args_contrevenant_princ.particulier_civilite} ${args_contrevenant_princ.particulier_nom} ${args_contrevenant_princ.particulier_prenom}\n ${args_contrevenant_princ.numero} ${args_contrevenant_princ.voie} ${args_contrevenant_princ.complement}\n ${args_contrevenant_princ.code_postal} ${args_contrevenant_princ.om_collectivite}
    # Plaignant
    Wait Until Element Is Visible  css=#plaignant_principal
    Element Should Contain  css=#plaignant_principal  ${args_plaignant_princ.particulier_civilite} ${args_plaignant_princ.particulier_nom} ${args_plaignant_princ.particulier_prenom}\n ${args_plaignant_princ.numero} ${args_plaignant_princ.voie} ${args_plaignant_princ.complement}\n ${args_plaignant_princ.code_postal} ${args_plaignant_princ.om_collectivite}

    # On vérifie que les boutons d'ajout des demandeurs ne font plus référence à des demandeurs principaux car
    # le contrevenant principal et plaignant principal sont déjà ajouté
    Element Should Not Be Visible  css=#add_contrevenant_principal
    Element Should Not Be Visible  css=#add_plaignant_principal
    # A contrario l'ajout des demandeurs 'classique' doit être possible
    Element Should Be Visible  css=#add_contrevenant
    Element Should Be Visible  css=#add_plaignant


Gestion de l'affichage du message d'information sur l'existance d'un DI lors d'un nouvelle demande
    [Documentation]  On vérifie que l'affichage du message ainsi que son contenu, est correctement saisie
    ...  et s'affiche dans le bon contexte (via les différents triggers) et au bon endroit.
    ...  Si la collectivité, la checkbox "saisir le numéro de dossier" ou encore le champs de saisie du numéro de
    ...  dossier sont modifiés, alors le message d'informations est réactualisé.
    ...  Si aucune correspondance avec un DI existant, aucune message affiché.
    ...  Si correspondance, message d'information affiché avec : 
    ...  - Le message "Un dossier avec le même numéro de dossier a été trouvé",
    ...  - Ouvrir dans un nouvel onglet
    ...  - le Nom Prénom (type de demandeur) (exemple : Togo Poly (Demandeur principal))
    ...  - une url de redirection vers la fiche de consultation du DI trouvé,
    ...  - un bouton "utiliser les informations de ce dossier", qui permet de copier les données
    ...  du demandeur (ce bouton est n'est pas encore implémenté dans le fonctionnement, donc non testé).
    ...  Le DI remonté devra être le dernier DI déposé en lien avec le DA courant (lui même lié au DI saisie par l'utilisateur).
    ...  3 DI on été crée en lien avec le même DA pour vérifier que le DI retrouvé correspond bien au dernier DI déposé (date_depot).
    ...  On vérifie également le bon fonctionnement du bouton de copie des informations du demandeur.
    ...  Et pour finir on vérifie que pour le profil 'juriste' et dans le cas d'un contentieux, le message d'information
    ...  s'affiche bien et avec les bonnes données.

    Depuis la page d'accueil  admin  admin

    # Collectivité non lié au DI & numéro de dossier mal renseigné
    &{args_demande} =  Create Dictionary
    ...  om_collectivite=agglo
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  date_demande=01/10/2022
    ...  num_dossier_complet=PC0130550000DOC02

    # Saisie du numéro de dossier mal renseigné ( + collectivité non lié au DI) -> aucun message
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire_02}
    # On vérifie qu'on est dans le bon contexte de la vérification
    Le titre de la page doit contenir  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    # Le message n'est pas visible
    Element Should Not Be Visible  css=#display_message_di_exist

    # Saisie du numéro de dossier correctement renseigné ( + collectivité non lié au DI) -> aucun message
    Input Text  css=#num_doss_complet  ${libelle_di_sans_espace}DOC02
    # Le message n'est pas visible
    Wait Until Element Is Not Visible  css=#display_message_di_exist

    # Saisie du numéro de dossier correctement renseigné (sur DOC02) ( + collectivité lié au DI) -> message affiché (avec dernier DI trouvé DOC02)
    # Étrangement il faut selectionner une autre collectivité avec de selectionner celle désiré, sinon le message ne s'affiche pas
    # problématique uniquement présent dans les tests, mais pas en manuelle
    Select From List By Label  css=#om_collectivite  ALLAUCH
    Select From List By Label  css=#om_collectivite  MARSEILLE
    # On attend que le message soit bien visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # On vérifie également que lorsque le type de demande n'est pas choisi, le message d'information ne s'affiche pas
    Select From List By Label  css=#demande_type  Choisir type de demande
    # On attend que le message soit bien visible
    Sleep  2
    # Le message ne doit pas être visible
    Wait Until Element Is Not Visible  css=#display_message_di_exist
    # On renseigne à nouveau le type de demande
    Select From List By Label  css=#demande_type  Demande d'ouverture de chantier
    # On attend que le message soit bien visible (wait until génère un fail -> Element is no longer attached to the DOM)
    Sleep  2
    # Le message doit pas être visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # Vérification du contenu du message et de la présence du bouton de copie des données du demandeur
    # ainsi que de l'url (dernier DI déposé -> DOC02)
    Form Value Should Contain  css=#num_doss_complet  ${libelle_di_sans_espace}DOC02
    Wait Until Element Is Visible  css=#display_message_di_exist

    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${libelle_di_avec_espace} Ouvrir dans un nouvel onglet\nDemandeur :\n ${args_petitionnaire_02.particulier_nom} ${args_petitionnaire_02.particulier_prenom} (Demandeur principal)\nUTILISER LES INFORMATIONS DE CE DOSSIER

    ${url_DI_exist}=  Set Variable  http://localhost/openads/app/index.php?module=form&obj=dossier_instruction&action=3&idx=${libelle_di_sans_espace}DOC02
    # On vérifie que le href du lien redirige bien sur le DOC02 (dernier DI ajouté) de l'objet dossier_instruction en mode consultation
    ${href_value} =  Get Element Attribute  css:#link_to_di  href
    Should Be Equal  ${href_value}  ${url_DI_exist}
    Element Should Contain  css=.button_copy_data_demandeur  UTILISER LES INFORMATIONS DE CE DOSSIER

    # Gestion du bouton de copie des données du demandeur
    Click Button  css=.button_copy_data_demandeur
    # On vérifie que les données on bien été récupérées et insérées dans le bloc du demandeur
    Element Should Contain  css=.demande__demandeur--nom-adresse  ${args_petitionnaire_02.particulier_civilite} ${args_petitionnaire_02.particulier_nom} ${args_petitionnaire_02.particulier_prenom}\n ${args_petitionnaire_02.numero} ${args_petitionnaire_02.voie} ${args_petitionnaire_02.complement}\n ${args_petitionnaire_02.code_postal} ${args_petitionnaire_02.om_collectivite}

    # On vérifie que pour le profil 'juriste', le message d'information 
    # sur l'existence d'un DI est bien affiché
    Depuis la page d'accueil  juriste  juriste

    &{args_demande} =  Create Dictionary
    ...  num_dossier_complet=${libelle_di_sans_espace}DOC02
    ...  date_demande=01/10/2022
    ...  dossier_autorisation_type_detaille=IN - Infraction

    Go To Dashboard via Link
    Go To Submenu In Menu  contentieux  nouveau-dossier
    Le titre de la page doit contenir  Contentieux > Nouvelle Demande > Nouveau Dossier

    Saisir la demande  ${args_demande}
    # On attend que le message soit bien visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # Vérification du contenu du message et de la présence du bouton de copie des données du demandeur
    # ainsi que de l'url (dernier DI déposé -> DOC02)
    Form Value Should Contain  css=#num_doss_complet  ${libelle_di_sans_espace}DOC02
    Wait Until Element Is Visible  css=#display_message_di_exist
    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${libelle_di_avec_espace} Ouvrir dans un nouvel onglet\nDemandeur :\n ${args_petitionnaire_02.particulier_nom} ${args_petitionnaire_02.particulier_prenom} (Demandeur principal)\nUTILISER LES INFORMATIONS DE CE DOSSIER

    ${url_DI_exist}=  Set Variable  http://localhost/openads/app/index.php?module=form&obj=dossier_instruction&action=3&idx=${libelle_di_sans_espace}DOC02
    # On vérifie que le href du lien redirige bien sur le DOC02 (dernier DI ajouté) de l'objet dossier_instruction en mode consultation
    ${href_value} =  Get Element Attribute  css:#link_to_di  href
    Should Be Equal  ${href_value}  ${url_DI_exist}
    Element Should Contain  css=.button_copy_data_demandeur  UTILISER LES INFORMATIONS DE CE DOSSIER


Gestion de l'affichage du message d'information sur l'existance d'un DI lors d'un nouvelle demande (consultation démat via plat'au)
    [Documentation]  On vérifie que l'affichage du message ainsi que son contenu, sont correctement saisis
    ...  et que le dossier est bien remonté dans l'affichage du message, dans le contexte d'une consultation (tâche plat'au lié au service consulté)
    Depuis la page d'accueil  admin  admin

    # Paramétrage pour l'ajout d'un dossier via plat'au
    &{platau_type_demande_initial} =  Create Dictionary
    ...  libelle=platau_type_demande_initial_PCI
    ...  valeur=DI
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${platau_type_demande_initial}
    
    &{om_param} =  Create Dictionary
    ...  libelle=platau_acteur_service_consulte
    ...  valeur=TST_TAC_CON
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS  ${om_param}

    # On ajoute un dossier via plat'au
    &{payload_values} =  Create Dictionary
    ...  enga_decla_date=0220101
    ...  particulier_date_naissance=980-04-13
    ...  date_depot_mairie=2022-02-01
    ...  date_demande=2022-01-30
    ...  acteur=TST_TAC_CON
    ...  insee=13014
    ...  service_consultant_insee=13014
    ...  particulier_nom=Rico
    ...  particulier_prenom=Pipo
    Créer une tâche de type create_di_for_consultation  ${payload_values}
    # Traitement de la tâche
    ${msg} =  Déclencher le traitement des tâches par WS
    # Vérification de l'existence du dossier
    &{advs_searc_di} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  particulier=Pipo
    Depuis le contexte du dossier d'instruction par la recherche avance  ${advs_searc_di}  MARSEILLE

    ${di_avec_espace} =  Get Text  css=#dossier_libelle
    ${libelle_di_sans_espace} =  Sans espace  ${di_avec_espace}

    # On vérifie que le dossier provenent de plat'au est bien remonté dans le message d'information
    &{args_demande_without_validation} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  date_demande=01/10/2022
    ...  num_dossier_complet=${libelle_di_sans_espace}
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_without_validation}  ${args_petitionnaire_without_validation}
    # On vérifie qu'on est dans le bon contexte de la vérification
    Le titre de la page doit contenir  Guichet Unique > Nouvelle Demande > Nouveau Dossier
    # On attend que le message soit bien visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # On vérifie le contenu du message
    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${di_avec_espace} Ouvrir dans un nouvel onglet\nDemandeur :\n ${payload_values.particulier_nom} ${payload_values.particulier_prenom} (Demandeur principal)\nUTILISER LES INFORMATIONS DE CE DOSSIER

    ${url_DI_exist}=  Set Variable  http://localhost/openads/app/index.php?module=form&obj=dossier_instruction&action=3&idx=${libelle_di_sans_espace}
    # On vérifie que le href du lien redirige bien sur le DOC02 (dernier DI ajouté) de l'objet dossier_instruction en mode consultation
    ${href_value} =  Get Element Attribute  css:#link_to_di  href
    Should Be Equal  ${href_value}  ${url_DI_exist}
    Element Should Contain  css=.button_copy_data_demandeur  UTILISER LES INFORMATIONS DE CE DOSSIER


Gestion de l'affichage du message d'information sur l'existance d'un DI lors d'un dossier avec sous dossiers
    [Documentation]  Vérification de l'affichage des listings de sous dossier
    Depuis la page d'accueil  admin  admin

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Test Message
    ...  particulier_prenom=Sous Dossier
    ...  om_collectivite=MARSEILLE
    ...  particulier_date_naissance=20/01/1976
    ...  particulier_commune_naissance=MULHOUSE
    ...  particulier_departement_naissance=HAUT-RHIN
    ...  particulier_pays_naissance=FRANCE
    ...  numero=89
    ...  voie=rue des Coudriers
    ...  complement=cplmt
    ...  lieu_dit=Lieu_dit
    ...  localite=MULHOUSE
    ...  code_postal=68100
    ...  bp=1
    ...  cedex=2
    ...  pays=FRANCE
    ...  division_territoriale=div
    ...  telephone_fixe=0447129800
    ...  telephone_mobile=0336018799
    ...  indicatif=+33
    ...  fax=fax
    ...  courriel=cdaubigne@test.test
    ...  notification=t
    @{ref_cad} =  Create List  000  0A  0001
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ...  terrain_adresse_voie_numero=24
    ...  terrain_adresse_voie=rue des marmottons
    ...  terrain_adresse_lieu_dit=Le pré des marmottons
    ...  terrain_adresse_code_postal=13333
    ...  terrain_adresse_localite=Marmotte Vallée
    ...  terrain_references_cadastrales=${ref_cad}
    ${dossier_parent} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Parametrage des sous dossier 
    # Paramétrage un type de sous-dossier
    ${codeSsDossier} =  Set Variable  SDMDI
    @{di_compatibles} =    Create List
    ...    PCI - P - Permis de construire pour une maison individuelle et / ou ses annexes - Initial
    &{args_type_di} =  Create Dictionary
    ...  code=${codeSsDossier}
    ...  libelle=Sous Dossier Test Message DI
    ...  sous_dossier=true
    ...  suffixe=true
    ...  lien_sous_dossier_type_di=@{di_compatibles}
    ...  maj_da_localisation=false
    ${idSsDossierSDMDI} =  Ajouter type de dossier d'instruction  ${args_type_di}

    &{args_demande_type} =  Create Dictionary
    ...    code=TEST${codeSsDossier}
    ...    libelle=Test Message DI
    ...    groupe=Autorisation ADS
    ...    dossier_autorisation_type_detaille=PCI (Permis de construire pour une maison individuelle et / ou ses annexes)
    ...    demande_nature=Dossier existant
    ...    dossier_instruction_type=Sous Dossier Test Message DI
    ...    evenement=Notification de delai
    Ajouter un nouveau type de demande depuis le menu  ${args_demande_type}

    Depuis l'onglet des sous_dossiers du dossier d'instruction  ${dossier_parent}
    Ajouter le sous-dossier au dossier  ${idSsDossierSDMDI}
    Depuis l'onglet des sous_dossiers du dossier d'instruction  ${dossier_parent}
    Ajouter le sous-dossier au dossier  ${idSsDossierSDMDI}

    # Vérifie que le sous-dossier est bien visible dans la liste des sous-dossier du DI
    ${dossier_parent_se} =  Sans espace  ${dossier_parent}
    Depuis l'onglet des sous_dossiers du dossier d'instruction  ${dossier_parent}
    Wait Until Page Contains  ${dossier_parent_se}${args_type_di.code}01
    Wait Until Page Contains  ${dossier_parent_se}${args_type_di.code}02

    # On vérifie que le dossier provenent de plat'au est bien remonté dans le message d'information
    &{args_demande_without_validation} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Demande d'ouverture de chantier
    ...  om_collectivite=MARSEILLE
    ...  num_dossier_complet=${dossier_parent_se}

    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_without_validation}  ${args_petitionnaire_without_validation}

    # On attend que le message soit bien visible
    Wait Until Element Is Visible  css=#display_message_di_exist

    # On vérifie le contenu du message
    Element Should Contain  css=#display_message_di_exist  Un dossier avec le même numéro de dossier a été trouvé\n${dossier_parent}
    Element Should Not Contain  css=#display_message_di_exist  ${dossier_parent} ${args_type_di.code}01
    Element Should Not Contain  css=#display_message_di_exist  ${dossier_parent} ${args_type_di.code}02


Désactivation du paramétrage
    [Documentation]  Désactivation du paramétrage mis en place dans ce test
    # Suppression du paramètrage
    Désactiver le mode service consulté

    &{om_param_option_saisie_num_dossier} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param_option_saisie_num_dossier}

    &{param_entite} =  Create Dictionary
    ...  delete=true
    ...  libelle=code_entite
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS   ${param_entite}
    
    &{param_entite} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_om_collectivite_entity
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS   ${param_entite}

    &{platau_type_demande_initial} =  Create Dictionary
    ...  delete=true
    ...  libelle=platau_type_demande_initial_PCI
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${platau_type_demande_initial}
    
    &{om_param} =  Create Dictionary
    ...  delete=true
    ...  libelle=platau_acteur_service_consulte
    ...  om_collectivite=MARSEILLE
    Gerer le paramètre par WS   ${om_param}