*** Settings ***
Documentation  Test les dépôts de demandes - Vérifie le bon fonctionnement de la saisie manuelle
    ...  du numéro de dossier et de division, lors d'une nouvelle demande.


# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Keywords ***
Activer la saisie du numéro de dossier
    [Documentation]  Permet d'activer la saisie du numéro de dossier par sections sur le formulaire
    ...  d'ajout d'une nouvelle demande
    Click Element  css=#num_doss_manuel  
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#num_doss_sequence[disabled="disabled"]


Désactiver la saisie du numéro de dossier
    [Documentation]  Permet de désactiver la saisie du numéro de dossier sur le formulaire
    ...  d'ajout d'une nouvelle demande
    Click Element Until New Element  css=#num_doss_manuel  css=#num_doss_manuel[value=""]
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_sequence[disabled="disabled"]


*** Test Cases ***
Création du jeu de données Demande_030_020
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données
    Run Keyword If  '${CONTEXT_DEMANDE_CREATED}' == 'False'  Initialisation du jeu de données Demande_03
    Set Global Variable  ${CONTEXT_DEMANDE_CREATED}  True

Création du contexte d'isolation
    [Documentation]  L'objet de ce 'Test Case' est de crée le contexte pour tester la 
    ...    Saisie du numéro de dossier sur le formulaire d'ajout d'une nouvelle demande

    # Isolation du contexte pour vérifier le fonctionnement de la numérotation
    # manuelle
    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=FREECITY030SMND
    ...  departement=013
    ...  commune=077
    ...  insee=13077
    ...  direction_code=Z
    ...  direction_libelle=Direction de FREECITY030SMND
    ...  direction_chef=Chef
    ...  division_code=Z
    ...  division_libelle=Division Z
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Alice Langlais
    ...  guichet_om_utilisateur_email=alicelanglais@openads-test.fr
    ...  guichet_om_utilisateur_login=alanglais
    ...  guichet_om_utilisateur_pwd=alanglais
    ...  instr_om_utilisateur_nom=Eliot Levasseur
    ...  instr_om_utilisateur_email=eliotlevasseur@openads-test.fr
    ...  instr_om_utilisateur_login=elevasseur
    ...  instr_om_utilisateur_pwd=elevasseur
    Set Suite Variable  ${isolation_values}

    Isolation d'un contexte  ${isolation_values}
    # Ajout des affectations automatiques en plus
    Ajouter la division depuis le menu  R  Division R  null  ${isolation_values.division_chef}  null  null  ${isolation_values.direction_libelle}
    Ajouter l'utilisateur depuis le menu  Étienne Gamelin  etiennegamelin@openads-test.fr  egamelin  egamelin  INSTRUCTEUR POLYVALENT COMMUNE  ${isolation_values.om_collectivite_libelle}
    Ajouter l'instructeur depuis le menu  Étienne Gamelin  Division R  instructeur  ${isolation_values.instr_om_utilisateur_nom}
    Ajouter la division depuis le menu  W30  Division W30  null  ${isolation_values.division_chef}  null  null  ${isolation_values.direction_libelle}
    Ajouter l'utilisateur depuis le menu  Renée Pinette  renéepinette@openads-test.fr  rpinette  rpinette  INSTRUCTEUR POLYVALENT COMMUNE  ${isolation_values.om_collectivite_libelle}
    Ajouter l'instructeur depuis le menu  Renée Pinette  Division W30  instructeur  ${isolation_values.instr_om_utilisateur_nom}
    &{arrondissement_values} =  Create Dictionary
    ...  libelle=77
    ...  code_postal=13077
    ...  code_impots=277
    Ajouter l'arrondissement  ${arrondissement_values}
    &{quartier_values} =  Create Dictionary
    ...  arrondissement=77
    ...  code_impots=977
    ...  libelle=Quartier de ${isolation_values.om_collectivite_libelle}
    Ajouter le quartier  ${quartier_values}
    &{args_affectation} =  Create Dictionary
    ...  instructeur=Étienne Gamelin (R)
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    ...  dossier_autorisation_type_detaille=DP - Déclaration préalable
    Ajouter l'affectation depuis le menu  ${args_affectation}
    &{args_affectation} =  Create Dictionary
    ...  instructeur=Renée Pinette (W30)
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    ...  dossier_autorisation_type_detaille=DP - Déclaration préalable
    ...  arrondissement=${arrondissement_values.libelle}
    ...  quartier=${quartier_values.libelle}
    Ajouter l'affectation depuis le menu  ${args_affectation}

    # Ajout d'un dossier pour vérifier la séquence de la numérotation forcée
    # plus loin dans le test
    &{args_demande_auto} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    &{args_petitionnaire_auto} =  Create Dictionary
    ...  particulier_nom=Garnier
    ...  particulier_prenom=Arlette
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    ${di_auto} =  Ajouter la demande par WS  ${args_demande_auto}  ${args_petitionnaire_auto}

    Set Suite Variable  ${di_auto}


Setter des dates du jour
    ${date_jour} =  Date du jour au format dd/mm/yyyy
    Set Suite Variable  ${date_jour}
    ${date_annee_yyyy} =  Get Time  year
    ${date_annee_yy} =  Get Substring  ${date_annee_yyyy}  -2
    Set Suite Variable  ${date_annee_yy}


Activer les parametres pour le test
    [Documentation]  L'objet de ce 'Test Case' est d'activer les parametres pour tester la 
    ...    Saisie du numéro de dossier sur le formulaire d'ajout d'une nouvelle demande
    # Active l'option de numérotation forcée
    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    # Désactive l'option de saisie de la date de demande à la date courante
    # Permet de vérifier le contenu du champ de l'année composant la
    # numérotation du dossier
    &{param_values} =  Create Dictionary
    ...  libelle=option_date_depot_demande_defaut
    ...  valeur=false
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${param_values}

Test Saisie du numéro de dossier - Sans date par défaut
    [Documentation]  Vérifie le bon fonctionnement de la saisie manuelle
    ...  du numéro de dossier et de division, lors d'une nouvelle demande sans date par défaut.

    # On crée une nouvelle demande avec le profil de guichet unique
    Depuis la page d'accueil  alanglais  alanglais
    # Informations à saisir
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TOLIN
    ...  particulier_prenom=PATRICK
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire}
    # On vérifie que le nom du pétitionnaire saisi est bien affiché dans le
    # formulaire de la demande
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK

    # Présence du bloc "Numéro dossier" après celui de "Date de la demande", et des différents
    # éléments: type DA, code DEP, code COM, année, division, dossier, checkbox
    Element Should Be Visible  css=#formulaire div#form-content div.bloc_numero_dossier
    Element Should Be Visible  css=#num_doss_type_da[readonly="readonly"]
    Element Should Be Visible  css=#num_doss_code_depcom[readonly="readonly"]
    Element Should Be Visible  css=#num_doss_annee[readonly="readonly"]
    Element Should Be Visible  css=#num_doss_division
    Element Should Be Visible  css=#num_doss_sequence
    Element Should Be Visible  css=#num_doss_manuel
    Wait Until Form Value Should Be  css=#num_doss_type_da  PC
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${isolation_values.departement}${isolation_values.commune}

    # L'année ne peut pas être récupérée tant que la date de la demande n'est
    # pas saisie
    Wait Until Form Value Should Be  css=#num_doss_annee  ${EMPTY}
    # La division est récupéré directement de l'instructeur affecté
    # automatiquement si l'option option_instructeur_division_numero_dossier est
    # activée
    Wait Until Form Value Should Be  css=#num_doss_division  0
    # Le numéro de dossier proposé est la valeur suivante de la séquence
    # qui ne peut pas être récupérée sans la date
    Wait Until Form Value Should Be  css=#num_doss_sequence  ${EMPTY}

Changement des options 
    [Documentation]  Réactivation de la date de demande par défaut à la date courante et
    ...  Activation de l'option de récupération de la division dans la numérotation

    # Vérification du comportement de chaque champs à la modification des champs
    # du formulaire de demande
    &{param_division} =  Create Dictionary
     ...  libelle=option_date_depot_demande_defaut
     ...  delete=true
     ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${param_division}


    &{param_values} =  Create Dictionary
    ...  libelle=option_instructeur_division_numero_dossier
    ...  valeur=true
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${param_values}


Test la division récupéré directement de l'instructeur affecté
    [Documentation]  Test la division récupéré directement de l'instructeur affecté
    ...  automatiquement si l'option option_instructeur_division_numero_dossier est
    ...  activée

    # Préparation des params
    &{args_demande_suite} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DP - Déclaration préalable
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Set Suite Variable  ${args_demande_suite}
    &{args_petitionnaire_suite} =  Create Dictionary
    ...  particulier_nom=TOLIN
    ...  particulier_prenom=PATRICK
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Set Suite Variable  ${args_petitionnaire_suite}

    Depuis la page d'accueil  admin  admin
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_suite}  ${args_petitionnaire_suite}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_type_da  DP
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${isolation_values.departement}${isolation_values.commune}

    # La division est récupéré directement de l'instructeur affecté
    # automatiquement si l'option option_instructeur_division_numero_dossier est
    # activée
    Wait Until Form Value Should Be  css=#num_doss_division  R
    Wait Until Form Value Should Be  css=#num_doss_sequence  1

    Activer la saisie du numéro de dossier
    # Saisie de la référence cadastrales pour modifier la division
    @{ref_cad} =  Create List  977  A  0001
    Saisir les références cadastrales  ${ref_cad}

    Désactiver la saisie du numéro de dossier
    Wait Until Form Value Should Be  css=#num_doss_division  W30
    Wait Until Form Value Should Be  css=#num_doss_sequence  1

Vérification des événements JS au changement du type détaillé de DA et de l'année
    [Documentation]   Vérification des événements JS (la division et la séquence ne doivent pas
    ...  être recalculées) au changement du type détaillé de DA : type DA
    ...  au changement de la date de demande : année

    Depuis la page d'accueil  admin  admin
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_suite}  ${args_petitionnaire_suite}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_type_da  DP
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${isolation_values.departement}${isolation_values.commune}

    # Vérification des événements JS (la division et la séquence ne doivent pas
    # être recalculées)
    # au changement du type détaillé de DA : type DA
    Select From Chosen List  dossier_autorisation_type_detaille  PCA - Permis de construire comprenant ou non des démolitions
    Sleep  2  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde

    Wait Until Element Is Visible  css=#demande_type
    Select From List By Label  css=#demande_type  Dépôt Initial
    Wait Until Form Value Should Be  css=#num_doss_type_da  PC
    Select From Chosen List  dossier_autorisation_type_detaille  PD - Permis de démolir
    Sleep  2  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde

    Wait Until Form Value Should Be  css=#num_doss_type_da  PD

    # au changement de la date de demande : année
    Wait Until Element Is Visible  css=input#date_demande
    Input text  css=#date_demande  01/01/2018
    Simulate Event  css=#date_demande  change
    Wait Until Form Value Should Be  css=#num_doss_annee  18
    Input text  css=#date_demande  ${EMPTY}
    Simulate Event  css=#date_demande  change
    Wait Until Form Value Should Be  css=#num_doss_annee  ${EMPTY}
    # au changement de la collectivité : code depcom
    Select From List By Label  css=#om_collectivite  choisir Collectivité
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${EMPTY}

Test message d'erreurs et non recalcul au rechargement
    [Documentation]  Vide les valeurs pour vérifier les messages d'erreur et 
    ...  Vérifie que les valeurs postées ne sont pas recalculées au chargement de
    ...  la page

    Depuis la page d'accueil  admin  admin
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_suite}  ${args_petitionnaire_suite}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_type_da  DP
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${isolation_values.departement}${isolation_values.commune}

    Activer la saisie du numéro de dossier

    # Vide les valeurs pour vérifier les messages d'erreur
    Input text  css=#num_doss_sequence  ${EMPTY}
    Input text  css=#num_doss_division  0
    Click On Submit Button Until Message  Numéro de dossier : le numéro est obligatoire.

    Input text until text is correct  css=#num_doss_sequence  99
    Input text  css=#num_doss_division  ${EMPTY}
    Click On Submit Button Until Message  Numéro de dossier : le caractère réservé au service instructeur (division) est obligatoire.
    # Vérifie que les valeurs postées ne sont pas recalculées au chargement de
    # la page
    Wait Until Form Value Should Be  css=#num_doss_sequence  99

Vérification des événements JS avec activation/désactivation de la numérotation forcée
    [Documentation]   Vérification des événements JS (avec activation/désactivation de la
    ...    numérotation forcée) et au changement du type détaillé de DA :
    ...     type DA, division, séquence

    Depuis la page d'accueil  admin  admin
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_suite}  ${args_petitionnaire_suite}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK
    Select From Chosen List  dossier_autorisation_type_detaille  PCA - Permis de construire comprenant ou non des démolitions
    Sleep  2  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde
    Wait Until Element Is Visible  css=#demande_type
    Select From List By Label  css=#demande_type  Dépôt Initial
    Sleep  0.2  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde
    Wait Until Form Value Should Be  css=#num_doss_type_da  PC
    # Même numérotation mais pas même division car l'affectation auto ne concerne
    # que les PCI et non les PCA
    Wait Until Form Value Should Be  css=#num_doss_division  0
    Wait Until Form Value Should Be  css=#num_doss_sequence  2
    Select From Chosen List Should Contain  dossier_autorisation_type_detaille  PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    Select From Chosen List  dossier_autorisation_type_detaille  PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    Sleep  2  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde
    Wait Until Element Is Visible  css=input#date_demande
    Wait Until Form Value Should Be  css=#num_doss_type_da  PC
    Wait Until Form Value Should Be  css=#num_doss_division  ${isolation_values.division_code}
    Wait Until Form Value Should Be  css=#num_doss_sequence  2
    # au changement de la date de demande : année, séquence (ne change pas la
    # valeur s'il manque des données pour la calculer)
    Input text  css=#date_demande  01/01/2018
    Simulate Event  css=#date_demande  change
    Wait Until Form Value Should Be  css=#num_doss_annee  18
    Wait Until Form Value Should Be  css=#num_doss_sequence  1
    Input text  css=#date_demande  ${EMPTY}
    Simulate Event  css=#date_demande  change
    Wait Until Form Value Should Be  css=#num_doss_annee  ${EMPTY}
    # au changement de la collectivité : code depcom (ne
    # change pas la valeur s'il manque des données pour la calculer)
    Select From List By Label  css=#om_collectivite  choisir Collectivité
    Wait Until Element Is Visible  css=input#date_demande
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${EMPTY}
    Wait Until Form Value Should Be  css=#num_doss_division  ${EMPTY}
    Wait Until Form Value Should Be  css=#num_doss_sequence  ${EMPTY}

Ajoute une demande automatique et vérifie le message d'erreur car la numérotation maximale est dépassée
    [Documentation]  Ajoute une demande automatique et vérifie le message d'erreur car la
    ...    numérotation maximale est dépassée

    Depuis la page d'accueil  admin  admin
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_suite}  ${args_petitionnaire_suite}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  TOLIN PATRICK
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_type_da  DP
    Wait Until Form Value Should Be  css=#num_doss_code_depcom  ${isolation_values.departement}${isolation_values.commune}

    # On saisi des valeurs valides pour ajouter le dossier
    Input text  css=#date_demande  ${date_jour}
    Select From Chosen List  dossier_autorisation_type_detaille  PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    Sleep  1  # obligation d'attendre car lors d'un changement de type de dossier il y a une temporisation JS d'une seconde

    Select From List By Label  css=#om_collectivite  ${isolation_values.om_collectivite_libelle}
    Wait Until Element Is Visible  css=input#date_demande
    Wait Until Element Is Visible  css=#num_doss_division
    Activer la saisie du numéro de dossier
    Input text  css=#num_doss_division  ${isolation_values.division_code}
    Input text  css=#num_doss_sequence  9999
    Click On Submit Button Until Message  Création du dossier d'instruction n
    La page ne doit pas contenir d'erreur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain
    ...  Vos modifications ont bien été enregistrées.
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain
    ...  Attention vous avez atteint le dernier numéro de dossier possible pour ce type de dossier d'autorisation de cette collectivité pour l'année sélectionnée.
    # Vérifie le numero de dossier de la demande
    Element Should Contain  css=#new_da  PC ${isolation_values.departement}${isolation_values.commune} ${date_annee_yy} ${isolation_values.division_code}9999

    # Ajoute une demande automatique et vérifire le message d'erreur car la
    # numérotation maximale est dépassée
    Depuis la page d'accueil  alanglais  alanglais
    &{args_demande_auto} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    &{args_petitionnaire_auto} =  Create Dictionary
    ...  particulier_nom=Aupry
    ...  particulier_prenom=Clothilde
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_auto}  ${args_petitionnaire_auto}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Aupry Clothilde
    # La séquence de la numérotation forcée ne doit pas être renseigné
    Wait Until Form Value Should Be  css=#num_doss_sequence  ${EMPTY}
    Click On Submit Button Until Message  Vous ne pouvez pas saisir un dossier dont la numérotation dépasse 9999.

Vérification du changement de la séquence après un ajout d'un dossier par numérotation forcée

    Depuis la page d'accueil  alanglais  alanglais
    &{args_demande_verif} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DP - Déclaration préalable
    &{args_petitionnaire_verif} =  Create Dictionary
    ...  particulier_nom=Bonneville
    ...  particulier_prenom=Zacharie
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_verif}  ${args_petitionnaire_verif}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Bonneville Zacharie

    Activer la saisie du numéro de dossier
    Wait Until Form Value Should Be  css=#num_doss_division  R
    Wait Until Form Value Should Be  css=#num_doss_sequence  1
    Input text  css=#num_doss_division  S
    Input text  css=#num_doss_sequence  777
    Click On Submit Button Until Message  Création du dossier d'instruction n
    La page ne doit pas contenir d'erreur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain
    ...  Vos modifications ont bien été enregistrées.
    Element Should Contain  css=#new_da  DP ${isolation_values.departement}${isolation_values.commune} ${date_annee_yy} S0777
    
    # Ajout du dossier avec numérotation auto
    &{args_demande_auto} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Déclaration préalable
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    &{args_petitionnaire_auto} =  Create Dictionary
    ...  particulier_nom=Vaillancour
    ...  particulier_prenom=Yves
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    ${di_auto} =  Ajouter la demande par WS  ${args_demande_auto}  ${args_petitionnaire_auto}
    Should Be Equal  ${di_auto}  DP ${isolation_values.departement}${isolation_values.commune} ${date_annee_yy} R0778P0

    # Vérification que l'ajout auto reste à la valeur la plus haute de la
    # séquence
    &{args_petitionnaire_verif_auto} =  Create Dictionary
    ...  particulier_nom=Bonneville
    ...  particulier_prenom=Zacharie
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande_verif}  ${args_petitionnaire_verif_auto}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Bonneville Zacharie
    Wait Until Form Value Should Be  css=#num_doss_division  R
    Wait Until Form Value Should Be  css=#num_doss_sequence  779
    Activer la saisie du numéro de dossier
    Input text  css=#num_doss_division  S
    Input text  css=#num_doss_sequence  555
    Click On Submit Button Until Message  Création du dossier d'instruction n
    La page ne doit pas contenir d'erreur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain
    ...  Vos modifications ont bien été enregistrées.
    Element Should Contain  css=#new_da  DP ${isolation_values.departement}${isolation_values.commune} ${date_annee_yy} S0555

    # Ajout du dossier avec numérotation auto
    &{args_petitionnaire_verif_auto_2} =  Create Dictionary
    ...  particulier_nom=Vaillancour
    ...  particulier_prenom=Yves
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    ${di_auto} =  Ajouter la demande par WS  ${args_demande_auto}  ${args_petitionnaire_verif_auto_2}
    Should Be Equal  ${di_auto}  DP ${isolation_values.departement}${isolation_values.commune} ${date_annee_yy} R0779P0

Saisie du numéro de dossier sur le formulaire d'ajout d'une nouvelle demande
    [Documentation]  Ajoute une demande automatique et vérifire le message d'erreur car la
    ...    numérotation maximale est dépassée

    # Active l'option de suppression des dossiers dont le comportement de la
    # fonctionnalité est modifié par la saisie de la numérotation.
    # Il n'y a plus la condition sur le dernier numéro de dossier d'autorisation
    # Ajout de deux DI, un ayant le numéro 888 et l'autre ayant le numéro 999,
    # les deux non instruits.
    # La suppression est possible sur les deux dossiers, en cas de suppression
    # du 999 alors le prohcian numéro automatique est le 889 (888+1).
    # Ajout d'un nouveau DI 7777 et suppression du 888, le prochain automatique
    # devrait rester le 7778.

    &{om_param} =  Create Dictionary
    ...  libelle=option_suppression_dossier_instruction
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    Depuis la page d'accueil  alanglais  alanglais
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DP - Déclaration préalable
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Lacharité
    ...  particulier_prenom=Juliette
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Lacharité Juliette
    Activer la saisie du numéro de dossier
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Input text until text is correct  css=#num_doss_sequence  888
    Input text until text is correct  css=#num_doss_division  Z
    Click On Submit Button Until Message  Création du dossier d'instruction n
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Pomeroy
    ...  particulier_prenom=Mathieu
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Pomeroy Mathieu
    Activer la saisie du numéro de dossier
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Input text until text is correct  css=#num_doss_sequence  999
    Input text until text is correct  css=#num_doss_division  Z
    Click On Submit Button Until Message  Création du dossier d'instruction n

    ${current_year} =  Get Current Date    result_format=%y

    Depuis la page d'accueil  egamelin  egamelin
    Depuis le contexte du dossier d'instruction  DP 013077 ${current_year} Z0888P0
    Portlet Action Should Be In Form  dossier_instruction  supprimer
    Depuis le contexte du dossier d'instruction  DP 013077 ${current_year} Z0999P0
    Portlet Action Should Be In Form  dossier_instruction  supprimer
    Supprimer le dossier d'instruction  DP 013077 ${current_year} Z0999P0
    Depuis la page d'accueil  alanglais  alanglais
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Chrétien
    ...  particulier_prenom=Arnaud
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Chrétien Arnaud
    Activer la saisie du numéro de dossier
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_sequence  889
    Input text until text is correct  css=#num_doss_sequence  7777
    Input text until text is correct  css=#num_doss_division  Z
    Click On Submit Button Until Message  Création du dossier d'instruction n
    Depuis la page d'accueil  egamelin  egamelin
    Supprimer le dossier d'instruction  DP 013077 ${current_year} Z0888P0
    Depuis la page d'accueil  alanglais  alanglais
    Ajouter la nouvelle demande depuis le menu sans validation du formulaire  ${args_demande}  ${args_petitionnaire}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain
    ...  css=#petitionnaire_principal_delegataire  Chrétien Arnaud
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}
    Wait Until Form Value Should Be  css=#num_doss_sequence  7778

Suppression des paramètres
    [Documentation]  Désactivation de l'option de numérotation forcée et de la récupération de 
    ...   la division dans la numérotation du dossier

    &{om_param} =  Create Dictionary
    ...  libelle=option_suppression_dossier_instruction
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    &{param_args} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}

    &{param_args} =  Create Dictionary
    ...  libelle=option_instructeur_division_numero_dossier
    ...  delete=true
    ...  om_collectivite=${isolation_values.om_collectivite_libelle}
    Gerer le paramètre par WS   ${param_args}