*** Settings ***
Documentation  Consultation et utilisation des actions relatives a un dossier de reprise.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Variables ***
${NUM_TEST}      027
${NUM_SS_TEST}   001

${COLLECTIVITE}  COLLECTIVITE_${NUM_TEST}
${INSEE}         27${NUM_SS_TEST} 

# Nom, login et mdp des profils associes a la collectivite
${INSTRUCTEUR}   ${NUM_TEST}_instructeur
${GUICHET}       ${NUM_TEST}_guichet

${DOSSIER}       PD 0${INSEE} 07 D0001

*** Test Cases ***
SETUP - Preparation du jeu de donnees
    [Documentation]  Isole une collectivite et importe un dossier via l'import ads2007 (dossier de reprise).

    Depuis la page d'accueil  admin  admin

    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=${COLLECTIVITE}
    ...  departement=${NUM_TEST}
    ...  commune=${NUM_SS_TEST}
    ...  insee=${INSEE}
    ...  direction_code=Dir_${NUM_TEST}
    ...  direction_libelle=Direction de ${COLLECTIVITE}
    ...  direction_chef=Chef
    ...  division_code=D${NUM_TEST}
    ...  division_libelle=Division ${NUM_TEST}
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=${GUICHET}
    ...  guichet_om_utilisateur_email=${GUICHET}@openads-test.fr
    ...  guichet_om_utilisateur_login=${GUICHET}
    ...  guichet_om_utilisateur_pwd=${GUICHET}
    ...  instr_om_utilisateur_nom=${INSTRUCTEUR}
    ...  instr_om_utilisateur_email=${INSTRUCTEUR}@openads-test.fr
    ...  instr_om_utilisateur_login=${INSTRUCTEUR}
    ...  instr_om_utilisateur_pwd=${INSTRUCTEUR}
    Isolation du contexte si non existant  ${isolation_values}

    # TODO : remplacer l'utilisation du fichier par un KW permettant de parametrer un dossier de reprise
    #        puis de l'importer
    Importer les dossiers a partir du fichier  027_001_dossier_reprise.csv
    Résultat de l'import doit contenir  2 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 1 ligne(s) importée(s)


FEAT - Listing - Affichage des dossiers de reprise

    Depuis la page d'accueil  ${INSTRUCTEUR}  ${INSTRUCTEUR}
    Depuis le listing  dossier_instruction
    Le dossier doit etre affiche dans le listing  ${DOSSIER}

FEAT - Listing - Recherche avancee

    Depuis la page d'accueil  ${INSTRUCTEUR}  ${INSTRUCTEUR}
    Depuis le listing  dossier_instruction
    &{critere_recherche} =  Create Dictionary
    ...  dossier=${DOSSIER}
    Filtrer les dossier  ${critere_recherche}
    Le dossier doit etre affiche dans le listing  ${DOSSIER}