*** Settings ***
Documentation     Évolutions du connecteur SIG

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Variables ***
${ref_cad_section_selector}  .reference_cadastrale_custom_fields .champ--ref-cadastrales__section
${ref_cad_fields_selector}   .champ--ref-cadastrales


*** Test Cases ***
Setup

    Copy File  ..${/}tests${/}binary_files${/}geoads_test${/}sig.inc.php  ..${/}dyn${/}

    ${test_id} =  Set Variable  026_03
    Set Suite Variable  ${test_id}

    Depuis la page d'accueil  admin  admin

    # Isolation du contexte
    &{collectivite_values} =  Create Dictionary
    ...  om_collectivite_libelle=Collectivité-TNR-sig
    ...  departement=026
    ...  commune=363
    ...  insee=26363
    ...  direction_code=TN
    ...  direction_libelle=Direction de Collectivité-TNR-sig
    ...  direction_chef=Chef
    ...  division_code=TN
    ...  division_libelle=Division TNR
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=guichet TNR
    ...  guichet_om_utilisateur_email=guichetTNR@openads-test.fr
    ...  guichet_om_utilisateur_login=guichetTNR
    ...  guichet_om_utilisateur_pwd=guichetTNR
    ...  instr_om_utilisateur_nom=instr TNR
    ...  instr_om_utilisateur_email=instrTNR@openads-test.fr
    ...  instr_om_utilisateur_login=instrTNR
    ...  instr_om_utilisateur_pwd=instrTNR
    ...  code_entite=TNR_sig
    ...  acteur=EV-SIG-0001
    Isolation d'un contexte  ${collectivite_values}
    Set Suite Variable  ${collectivite_values}

    Depuis le contexte de la collectivité  ${collectivite_values.om_collectivite_libelle}
    ${collectivite_id} =  Get Text  css=#om_collectivite
    Set Suite Variable  ${collectivite_id}

    # ajout le code entité et acteur
    &{collectivite_values_code_entite} =  Create Dictionary
    ...  libelle=code_entite
    ...  valeur=${collectivite_values.code_entite}
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${collectivite_values_code_entite}
    &{collectivite_values_platau_acteur_service_consulte} =  Create Dictionary
    ...  libelle=platau_acteur_service_consulte
    ...  valeur=${collectivite_values.acteur}
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    Gerer le paramètre par WS  ${collectivite_values_platau_acteur_service_consulte}

    # même comportement du test qu'il soit exécuté en runone ou runall
    &{param_division} =  Create Dictionary
    ...  libelle=option_afficher_division
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_division}

    # option_instructeur_division_numero_dossier
    &{param_option_instructeur_division_numero_dossier} =  Create Dictionary
    ...  libelle=option_instructeur_division_numero_dossier
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_option_instructeur_division_numero_dossier}

    # ajout paramètres SIG
    &{param_option_sig} =  Create Dictionary
    ...  libelle=option_sig
    ...  valeur=sig_externe
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_option_sig}
    &{param_code_direction} =  Create Dictionary
    ...  libelle=code_direction
    ...  valeur=0
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_code_direction}

    # Synchronisation des contraintes de géolocalisation
    Depuis la page d'accueil  admingen  admingen
    Synchroniser les contraintes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  3 contrainte(s)

    # Ajout d'une commune
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=${collectivite_values.insee}
    ...  reg=20
    ...  dep=26
    ...  arr=362
    ...  ncc=Commune-TNR-sig
    ...  nccenr=Commune-TNR-sig
    ...  libelle=Commune-TNR-sig
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}
    Set Suite Variable  ${commune_id}

Teste des références cadastrales erronées
    [Documentation]  Test sur la vérification d'une référence cadastrale mal saisie
    ...    qui passe les vérifications et n'entre pas dans les deux cas suivants : 
    ...    substr($parcelles, 8, 1) == '' || substr($parcelles, 8, 1) == "A" || substr($parcelles, 8, 1) == "/"
    ...    preg_match('/^[0-9]+$/', substr($parcelles, 8, 1)) == 1
    ...    donc 8888  A5  09BB99 au lieu de 8888  A5  0988 par exemple

    Depuis la page d'accueil  admin  admin

    # ajout d'un dossier
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=${test_id}_Ted
    ...  particulier_prenom=${test_id}_Talks
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    @{ref_cad} =  Create List  8888  A5  09BB99
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    ...  terrain_references_cadastrales=${ref_cad}
    ...  date_demande=10/12/2022
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis le contexte du dossier d'instruction  ${di_libelle}

    Click Link  css=#action-form-dossier_instruction-geolocalisation
    Click Element  css=input#verif_parcelle-button
    Wait Until Element Contains  css=div#verif_parcelle-message  Veuillez vérifier que les références cadastrales ont bien été saisies
    Click Element  css=input#calcul_emprise-button
    Wait Until Element Contains  css=div#calcul_emprise-message  L'emprise n'a pas pu être calculée.

    La page ne doit pas contenir d'erreur

Teste throw new geoads_exception
    [Documentation]  Test sur la vérification d'une référence cadastrale qui cause
    ...    geoads.class.php un throw new geoads_exception

    Depuis la page d'accueil  admin  admin

    # ajout d'un dossier
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=${test_id}_Ted
    ...  particulier_prenom=${test_id}_Talks
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    @{ref_cad} =  Create List  666 EE 066
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${collectivite_values.om_collectivite_libelle}
    ...  terrain_references_cadastrales=${ref_cad}
    ...  date_demande=10/12/2022
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Utilisation de l'action de geolocalisation après synchro des contraintes
    Depuis la page d'accueil  admingen  admingen
    Synchroniser les contraintes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  3 contrainte(s)
    Go To Submenu In Menu  administration  geocoder
    Click On Submit Button

    Depuis le contexte du dossier d'instruction  ${di_libelle}

    Click Link  css=#action-form-dossier_instruction-geolocalisation
    Click Element  css=input#verif_parcelle-button
    Wait Until Element Contains  css=div#verif_parcelle-message  Veuillez vérifier que les références cadastrales ont bien été saisies
    Click Element  css=input#calcul_emprise-button
    Wait Until Element Contains  css=div#calcul_emprise-message  L'emprise n'a pas pu être calculée.

    La page ne doit pas contenir d'erreur

Décomposition du jeu de données
    
    [Documentation]  Remise à zero de la configuration

    &{param_division} =  Create Dictionary
    ...  libelle=option_afficher_division
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_division}

   &{delete_param_values} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_sig
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${delete_param_values}
    &{param_values} =  Create Dictionary
    ...  libelle=option_instructeur_division_numero_dossier
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    Remove File  ..${/}dyn${/}sig.inc.php