*** Settings ***
Documentation    Test le fonctionnement des écrans du menu Paramétrage Dossiers > Workflows > Événement
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown


*** Keywords ***
Ajouter l'action depuis le menu sans vérification
    [Arguments]  ${values}

    # On ouvre le tableau des événements
    Depuis le tableau des actions
    # On clique sur l'icone ajouter
    Click On Add Button
    # On remplit le formulaire
    Saisir l'action  ${values}
    # On valide
    Click On Submit Button


*** Test Cases ***
Vérification de l'unicité dans les regles
    [Documentation]  Teste l'interdiction des opérateurs multiples dans un champ limité en unicité'

    Depuis la page d'accueil  admin  admin

    &{args} =  Create Dictionary
    ...  action=test_unicite
    ...  libelle=Test unicite
    ...  regle_etat=etat + champ_errone
    Ajouter l'action depuis le menu sans vérification  ${args}
    La page ne doit pas contenir d'erreur
    Error Message Should Contain  Le champ règle etat ne peut pas avoir plus d'un opérande.

Vérification de la validation des null dans les regles
    [Documentation]  Test la gestion des null dans les Actions
    ...    Un NUll ou null doit être la seule opérande

    # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    # On ajoute une action avec NULL
    &{args_action} =  Create Dictionary
    ...  action=test_null
    ...  libelle=TEST NULL
    ...  regle_delai=NULL
    ...  regle_accord_tacite=null
    Ajouter l'action depuis le menu  ${args_action}
    # On test l'ajout valide
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajoute une action avec regle_accord_tacite NULL+truc
    &{args_action} =  Create Dictionary
    ...  action=test_null_fail
    ...  libelle=TEST NULL
    ...  regle_delai=NULL
    ...  regle_accord_tacite=null+truc
    Ajouter l'action depuis le menu sans vérification  ${args_action}
    # On test l'ajout en echec
    Error Message Should Contain  'NULL' losque est utilisé doit être la seule valeur du champ.
    Error Message Should Contain  accord_tacite

Vérification de la validation des boolean dans les regles
    [Documentation]  Test que les regles de type Boolean dans les Actions
    ...    ne contiennent que des valeurs boolean.

    # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    # On ajoute une action avec une regle Boolean vraie
    &{args_action} =  Create Dictionary
    ...  action=test_boolean_sucess
    ...  libelle=Test Boolean Success
    ...  regle_a_qualifier=true
    ...  regle_incompletude=true+false
    ...  regle_incomplet_notifie=false
    Ajouter l'action depuis le menu  ${args_action}

    # On ajoute une action avec les regles regle_a_qualifier fausse
    &{args_action} =  Create Dictionary
    ...  action=test_boolean_fail
    ...  libelle=Test Boolean Fail
    ...  regle_a_qualifier=true+1
    Ajouter l'action depuis le menu sans vérification  ${args_action}
    # On vérifie la présence du message d'erreur
    Error Message Should Contain  règle à qualifier
    Error Message Should Contain  1

Vérification de la validation des numériques dans les regles
    [Documentation]  Test que les regles de type Dates dans les Actions
    ...    ne contiennent que des valeurs XX mois, XX jour, ou XX jours.
    ...    On test aussi les cas  [champ_fusion] + XX mois/xxjours.

    # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    # On ajoute une action avec les regles regle_dossier_instruction_type true
    &{args_action} =  Create Dictionary
    ...  action=test_numeric_success
    ...  libelle=Test numéric Success
    ...  regle_dossier_instruction_type=3+1+5
    Ajouter l'action depuis le menu  ${args_action}

    # On ajoute une action avec les regles regle_dossier_instruction_type fausse
    &{args_action} =  Create Dictionary
    ...  action=test_numeric_fail
    ...  libelle=Test Numeric Fail
    ...  regle_dossier_instruction_type=true+1
    Ajouter l'action depuis le menu sans vérification  ${args_action}
    # On vérifie la présence du message d'erreur
    Error Message Should Contain  dossier d'instruction
    Error Message Should Contain  true

Vérification de la validation des dates dans les regles
    [Documentation]  Test que les regles de type Dates dans les Actions
    ...    ne contiennent que des valeurs XX mois, XX jour, ou XX jours.
    ...    On test aussi les cas  [champ_fusion] + XX mois/xxjours.

    # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    # On ajoute une action avec 
    &{args_action} =  Create Dictionary
    ...  action=test_action_ok
    ...  libelle=Test Action Date Success
    ...  regle_delai=archive_delai+delai+1mois
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=date_depot_mairie+archive_delai+delai+1mois
    Ajouter l'action depuis le menu  ${args_action}
    # On test l'ajout valide
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajoute une action avec les regles regle_date_limite et regle_delai fausse
    &{args_action} =  Create Dictionary
    ...  action=test_date_no_separator
    ...  libelle=Test Action Date NoSeparator Fail
    ...  regle_delai=archive_delai1
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=date_depot_mairie+archive_delai+delai1mois
    Ajouter l'action depuis le menu sans vérification  ${args_action}
    # On vérifie la présence du message d'erreur
    Error Message Should Contain  archive_delai1
    Error Message Should Contain  delai1mois
    Error Message Should Contain  delai
    Error Message Should Contain  date_limite, n'est pas une chaine 'x mois' ou 'x jours' valide

    # On ajoute une action avec les regles regle_delai fausse
    &{args_action} =  Create Dictionary
    ...  action=test_action_date_true
    ...  libelle=Test Action Date True Fail
    ...  regle_delai=true
    ...  regle_accord_tacite=accord_tacite
    Ajouter l'action depuis le menu sans vérification  ${args_action}

    # On vérifie la présence du message d'erreur
    Error Message Should Contain  delai.
    Error Message Should Contain  true