*** Settings ***
Documentation     Actions navigation

*** Keywords ***
Depuis la page d'accueil avec widget de redirection
    [Arguments]    ${username}=null    ${password}=null
    [Documentation]    L'objet de ce 'Keyword' est de positionner l'utilisateur
    ...    sur la page de login ou son tableau de bord si on le fait se connecter.
    ...    De plus on vérifie qu'il n'y a qu'une seule fenetre d'ouverte.

    # On récupère le nombre de fenetres ouvertes
    ${listeFenetres} =    Get Window Titles
    ${nb_fenetres} =    Get Length    ${listeFenetres}
    # On ouvre la page d'accueil
    Go To    ${PROJECT_URL}
    Page Should Not Contain Errors
    # On teste si on est connecté
    Wait Until Element Is Visible    css=#title h2
    ${titre} =    Get Text    css=#title h2
    # Si tableau de bord, donc user déjà logué
    # on se reconnecte sauf si c'est l'user désiré qui est connecté
    # sinon on se connecte si spécifié
    Se déconnecter
    S'authentifier avec widget de redirection    ${username}    ${password}


S'authentifier avec widget de redirection
    [Arguments]    ${username}=${ADMIN_USER}    ${password}=${ADMIN_PASSWORD}
    Input Username    ${username}
    Input Password    ${password}
    #
    Click Button    login.action.connect
    #
    Sleep  1
    Wait Until Element Is Visible    css=#actions a.actions-logout
    Element Should Contain    css=#actions a.actions-logout    Déconnexion
    #
    Page Should Not Contain Errors


Se déconnecter avec widget de redirection
    Click Link    css=#actions a.actions-logout
    Wait Until Element Is Visible    css=#title h2
    Element Text Should Be    css=#title h2    Veuillez Vous Connecter
    Page Should Not Contain Errors


Reconnexion avec widget de redirection
    [Arguments]    ${username}=null    ${password}=null
    ${connected_login} =    Get Text    css=#actions ul.actions-list li.action-login
    # On se déconnecte si user logué différent
    Run Keyword If   '${username}' != '${connected_login}'    Se déconnecter
    # On se reconnecte si user spécifié et différent du logué
    Run Keyword If   '${username}' != 'null' and '${password}' != 'null' and '${username}' != '${connected_login}'    S'authentifier avec widget de redirection    ${username}    ${password}


Modifier la lettre-type XXX
    [Documentation]  Redéfinition temporaire du Keyword openMairie, à cause d'un nom de
    ...  colonne différent dans le listing des lettres-types  (id sur openADS, identifiant
    ...  sur openMairie). Permet de redéfinir une lettre-type en lui passant les données.
    [Arguments]  ${id}  ${libelle}=null  ${titre}=null  ${corps}=null  ${sql}=null  ${actif}=null  ${collectivite}=null

    # On ouvre le tableau des lettres-types
    Depuis le tableau des lettres-types
    # On recherche la lettre-type
    Run Keyword If    '${id}' != 'null'    Use Simple Search    id    ${id}    ELSE IF    '${libelle}' != 'null'    Use Simple Search    libellé    ${libelle}    ELSE    Fail
    # On clique sur la lettre-type
    Run Keyword If    '${id}' != 'null'    Click On Link    ${id}    ELSE IF    '${libelle}' != 'null'    Click On Link    ${libelle}    ELSE    Fail
    # On clique sur le bouton modifier
    Click On Form Portlet Action  om_lettretype  modifier
    # On remplit le formulaire
    Saisir la lettre-type  ${id}  ${libelle}  ${titre}  ${corps}  ${sql}  ${actif}  ${collectivite}
    # On valide le formulaire
    Click On Submit Button
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.