*** Settings ***
Documentation  Test les dépôts de demandes

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin

*** Test Cases ***
Création du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données

    @{etats_autorises} =    Create List
    ...    delai majore
    ...    delai de notification envoye
    ...    dossier sans notification de delai

    &{args_demande_type} =  Create Dictionary
    ...    code=TESTDOC
    ...    libelle=TESTDOC
    ...    groupe=Autorisation ADS
    ...    dossier_autorisation_type_detaille=PCA (Permis de construire comprenant ou non des démolitions)
    ...    demande_nature=Nouveau dossier
    ...    etats_autorises=@{etats_autorises}
    ...    dossier_instruction_type=PCA - Modificatif
    ...    evenement=Notification de delai
    ...    document_obligatoire=Doc1

    Ajouter un nouveau type de demande depuis le menu    ${args_demande_type}

Rechercher le pétitionnaire fréquent

    [Documentation]  Lors de l'ajout d'une demande, rechercher un pétitionnaire
    ...  fréquent.

    # Jeu de données
    ${pf1} =  Create Dictionary
    ...  particulier_nom=Dubois
    ...  particulier_prenom=Jean
    ...  particulier_civilite=Monsieur
    ...  frequent=true
    ...  om_collectivite=agglo

    ${pf2} =  Create Dictionary
    ...  particulier_nom=Dubois
    ...  particulier_prenom=Mireille
    ...  particulier_civilite=Madame
    ...  frequent=true
    ...  om_collectivite=agglo

    # On crée deux pétitionnaires fréquents
    Depuis la page d'accueil  admin  admin
    Ajouter le demandeur  ${pf1}
    Ajouter le demandeur  ${pf2}

    # On crée une nouvelle demande
    Depuis la page d'accueil  guichet  guichet
    Depuis le contexte de nouvelle demande via le tableau de bord
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire pour une maison individuelle et / ou ses annexes
    # On sélectionne le type de demande
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Select From List By Label  demande_type  Dépôt Initial
    # On ajoute le pétitionnaire principal
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Click Element  add_petitionnaire_principal

    # On saisit les 3 premières lettres du nom
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Input Text  particulier_nom  Dub*
    # On clique sur le bouton de recherche
    Click Element  css=.search-frequent-16
    # On vérifie la liste des éléments disponibles
    ${list} =  Create List  Dubois Jean  Dubois Mireille
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Select List Should Be  css=#select-petitionnaire  ${list}
    # On sélectionne un pétitionnaire
    Select From List By Label  css=#select-petitionnaire  Dubois Jean
    # On clique sur le bouton de validation
    Click Button    css=div.dialog-search-frequent-petitionnaire div.ui-dialog-buttonpane button.ui-button
    # On vérifie que la page ne contient pas d'erreur
    Page Should Not Contain Errors
    # On quitte le formulaire
    Click On Back Button In Subform
    # On vérifie le pétionnaire
    Page Should Contain  Monsieur Dubois Jean

Affichage de la date de dépôt par defaut
    [Documentation]  Permet de vérifier le bon fonctionnement de l'affichage de
    ...    la date de dépôt ou non

    # On ouvre le menu nouveau dossier
    Depuis le contexte de nouvelle demande via le menu
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire comprenant ou non des démolitions
    Select From List By Label  demande_type  Dépôt Initial
    ${date_du_jour} =  Date du jour FR
    Textfield Should Contain  date_demande  ${date_du_jour}

    Ajouter le paramètre depuis le menu  option_date_depot_demande_defaut  false  agglo

    # On ouvre le menu nouveau dossier
    Depuis le contexte de nouvelle demande via le menu
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire comprenant ou non des démolitions
    Select From List By Label  demande_type  Dépôt Initial
    Textfield Should Contain  date_demande  ${EMPTY}

    Modifier le paramètre   option_date_depot_demande_defaut  true  agglo

Ajout demande avec documents obligatoires
    [Documentation]  L'objet de ce 'Test Case' est de vérifier l'ajout d'une demande
    ...    avec des documents obligatoire

    # En tant que guichetier
    Depuis la page d'accueil  guichet  guichet
    # On ouvre le menu nouveau dossier
    Depuis le contexte de nouvelle demande via le tableau de bord
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire comprenant ou non des démolitions
    # On sélectionne le type de demande
    Select From List By Label  demande_type  TESTDOC
    # Vérification du chargement du dialog
    Wait Until Keyword Succeeds    ${TIMEOUT}    ${RETRY_INTERVAL}    Element Should Contain    css=#ui-dialog-title-liste_doc    Liste des documents obligatoires
    # Validation du dialog
    Click Button    Valider
    # Vérification de l'erreur
    ${alert} =  Get Alert Message
    Should Be Equal As Strings  ${alert}  Tous les documents doivent être présents. Dans le cas contraire, rejeter la demande.
    # Fermeture du dialog
    Click Element  css=.ui-dialog-titlebar-close
    # Vérification de l'erreur
    ${alert} =  Get Alert Message
    Should Be Equal As Strings  ${alert}  Tous les documents doivent être présents. Dans le cas contraire, rejeter la demande.
    # Rejet de la demande avec annulation
    Click Button    Rejeter la demande
    Choose Cancel On Next Confirmation
    ${message}=     Confirm Action
    Should Be Equal As Strings  ${message}  Êtes vous sur de vouloir rejeter la demande ?
    # Rejet de la demande
    Click Button    Rejeter la demande
    ${message}=     Confirm Action
    Should Be Equal As Strings  ${message}  Êtes vous sur de vouloir rejeter la demande ?
    # Vérification du rechargement de la page
    Wait Until Page Contains Element    css=#dossier_autorisation_type_detaille
    Element Should Not Be Visible    css=#demande_type
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire comprenant ou non des démolitions
    # On sélectionne le type de demande
    Select From List By Label  demande_type  TESTDOC
    # Vérification du chargement du dialog
    Wait Until Keyword Succeeds    ${TIMEOUT}    ${RETRY_INTERVAL}    Element Should Contain    css=#ui-dialog-title-liste_doc    Liste des documents obligatoires
    # check Doc 1
    Select Checkbox    0
    # Validation du dialog
    Click Button    Valider
    # vérification de la fermeture du dialog
    Element Should Not Be Visible    css=#ui-dialog-title-liste_doc
    # Ajout d'un pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Cole
    ...  particulier_prenom=Sarah
    ...  frequent=true
    Ajouter le pétitionnaire principal    ${args_petitionnaire}
    # On valide
    Click On Submit Button
    # Vérification qu'il n'y a aucune erreur
    Page Should Not Contain Errors


TNR Récupération de l'édition et logo
    [Documentation]  L'objet de ce 'Test Case' est de vérifier que la bonne édition
    ...  et le bon logo sont récupérés dans le récépissé de la demande

    # En tant qu'admin
    Depuis la page d'accueil    admingen    admingen

    # On crée une nouvelle demande via le tableau de bord
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Fistaul
    ...  particulier_prenom=Sarah
    ...  om_collectivite=ALLAUCH

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=ALLAUCH
    # On crée une nouvelle demande via le tableau de bord
    ${di_libelle} =  Ajouter la nouvelle demande depuis le menu  ${args_demande}  ${args_petitionnaire}

    # On ouvre le récépissé de la demande
    Click Element  css=#link_demande_recepisse
    # On ouvre le PDF
    Open PDF  form
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Commune : Allauch
    # On ferme le PDF
    Close PDF


TNR Récupération des paramètres de collectivité dans le récépissé de dépôt
    [Documentation]  L'objet de ce 'Test Case' est de vérifier que les paramètres
    ...    de la collectivité sont bien fusionné avec le récépissé de dépôt

    # En tant que guichet
    Depuis la page d'accueil    guichetsuivi    guichetsuivi
    ${date} =  Date du jour FR
    # On crée une nouvelle demande via le tableau de bord
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Crosh
    ...  particulier_prenom=Sarah

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial

    # On crée une nouvelle demande via le tableau de bord
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # On ouvre le récépissé de la demande
    Click Element  css=#link_demande_recepisse
    # On ouvre le PDF
    Open PDF  form
    # On va sur la seconde page
    Next Page PDF
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain   Marseille , le${SPACE}${SPACE}${date}
    # On ferme le PDF
    Close PDF


Ajout d'une demande avec création de répertoire de numérisation

    [Documentation]  Permet de vérifier la création du répertoire de
    ...  numérisation du dossier d'instruction.

    #
    Activer l'option de numérisation

    # En tant que guichet
    Depuis la page d'accueil    guichetsuivi    guichetsuivi
    ${date} =  Date du jour FR
    # On crée une nouvelle demande via le tableau de bord
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Fongemie
    ...  particulier_prenom=Christiane
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    # On crée une nouvelle demande via le tableau de bord
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    #
    Vérifier création répertoire du dossier  ${di_libelle}

    #
    Désactiver l'option de numérisation