*** Settings ***
Documentation  Tests relatifs aux listings des dossiers d'instruction.

Resource  resources/resources.robot

Suite Setup     Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données
Suite Teardown  For Suite Teardown


*** Variables ***
${NUM_TEST}      035
${NUM_SS_TEST}   040

${COLLECTIVITE}  NATURALCITY
${INSEE}         13088

# Nom, login et mdp des profils associes a la collectivite
${INSTRUCTEUR}   yjitae
${GUICHET}       jdoohong


*** Test Cases ***

N'afficher qu'une fois un dossier ayant plusieurs pétitionnaires principaux
    [Tags]    regression

    # Ajout d'un dossier ayant plusieurs types de demandeurs principaux
    &{args_bailleur} =  Create Dictionary
    ...  particulier_nom=${NUM_TEST}
    ...  particulier_prenom=${NUM_SS_TEST} bailleur
    ...  om_collectivite=${COLLECTIVITE}
    &{args_demandeurs} =  Create Dictionary
    ...  bailleur_principal=${args_bailleur}

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=${NUM_TEST}
    ...  particulier_prenom=${NUM_SS_TEST} demandeur
    ...  om_collectivite=${COLLECTIVITE}


    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Fonds de commerce
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${COLLECTIVITE}

    ${dossier_bailleur} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}  ${args_demandeurs}

    Depuis la page d'accueil  ${INSTRUCTEUR}  ${INSTRUCTEUR}
    Depuis le listing  dossier_instruction

    Le dossier ne doit pas être en doublon sur le listing  ${dossier_bailleur}

    # On affiche seulement le nom du demandeur de type pétitionnaire, pas du bailleur
    La colonne X du tableau pour la ligne Y contient  ${dossier_bailleur}  col-4    ${NUM_TEST} ${NUM_SS_TEST} demandeur
    La colonne X du tableau pour la ligne Y ne contient pas  ${dossier_bailleur}  col-4    ${NUM_TEST} ${NUM_SS_TEST} bailleur


Afficher une fois un dossier n'ayant pas de pétitionnaire principal
    [Tags]    regression
    [Documentation]  Pour un dossier importé depuis Plat'AU, il est possible que le dossier n'ai pas de pétionnaire.
    ...              Dans ce cas, il faut tout de même l'afficher dans le listing pour pouvoir le traiter.

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${COLLECTIVITE}

    ${dossier_sans_petitionnaire_principal} =  Ajouter la demande par WS  ${args_demande}  null

    Depuis la page d'accueil  ${INSTRUCTEUR}  ${INSTRUCTEUR}
    Depuis le listing  dossier_instruction
    Le dossier doit etre affiche dans le listing  ${dossier_sans_petitionnaire_principal}


*** Keywords ***

Composition du jeu de données
    Depuis la page d'accueil  admin  admin

    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=${COLLECTIVITE}
    ...  departement=013
    ...  commune=088
    ...  insee=${INSEE}
    ...  direction_code=T
    ...  direction_libelle=Direction de NATURALCITY
    ...  direction_chef=Chef
    ...  division_code=T
    ...  division_libelle=Division T
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Jung Doo-hong
    ...  guichet_om_utilisateur_email=${GUICHET}@openads-test.fr
    ...  guichet_om_utilisateur_login=${GUICHET}
    ...  guichet_om_utilisateur_pwd=${GUICHET}
    ...  instr_om_utilisateur_nom=Yoo Ji-tae
    ...  instr_om_utilisateur_email=${INSTRUCTEUR}@openads-test.fr
    ...  instr_om_utilisateur_login=${INSTRUCTEUR}
    ...  instr_om_utilisateur_pwd=${INSTRUCTEUR}
    Isolation du contexte si non existant  ${isolation_values}


La colonne X du tableau pour la ligne Y contient
    [Arguments]
        ...  ${id_ligne}
        ...  ${class_colonne}
        ...  ${contenu_attendu}

    # La première colonne (avec .col-0) contient l'ID de l'objet dans openMairie
    # Ensuite on remonte au niveau du <tr> pour la ligne
    # Puis on sélectionne la colonne demandée via sa classe

    Element Should Contain
    ...  xpath=//td[contains(@class, "col-0")][//text()[contains(., "${id_ligne.replace(" ", "")}")]]/ancestor::tr/td[contains(@class, "${class_colonne}")]
    ...  ${contenu_attendu}

La colonne X du tableau pour la ligne Y ne contient pas
    [Arguments]
        ...  ${id_ligne}
        ...  ${class_colonne}
        ...  ${contenu_attendu}

    # La première colonne (avec .col-0) contient l'ID de l'objet dans openMairie
    # Ensuite on remonte au niveau du <tr> pour la ligne
    # Puis on sélectionne la colonne demandée via sa classe

    Element Should Not Contain
    ...  xpath=//td[contains(@class, "col-0")][//text()[contains(., "${id_ligne.replace(" ", "")}")]]/ancestor::tr/td[contains(@class, "${class_colonne}")]
    ...  ${contenu_attendu}