*** Settings ***
Documentation  Tests des suggestions pour un dossier de type Infraction.

Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Initialisation du paramétrage
    [Documentation]  Configure les paramètres via WS pour :
    ...  - option_dossier_saisie_numero_complet : permet de saisir les numéros au format complet (ex: PC0131772200013)
    ...  - option_dossier_commune : active les suggestions de commune
    ...  Les deux sont configurés pour la collectivité "agglo"

    &{param_saisie_complete} =  Create Dictionary
    ...  valeur=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_saisie_complete}

    &{param_dossier_commune} =  Create Dictionary
    ...  valeur=true
    ...  libelle=option_dossier_commune
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}

Création de la commune
    [Documentation]  Crée la commune pour le test de suggestion
    
    Depuis la page d'accueil  admin  admin
    
    Run Keyword If   '${CONTEXT_COMMUNE_CREATED}' == 'False'   Initialisation du jeu de données Commune
    Set Global Variable  ${CONTEXT_COMMUNE_CREATED}  True


Vérification des suggestions
    [Documentation]  Vérifie les suggestions pour un dossier Infraction

    # Vérification de la structure du formulaire
    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Vérifier que le champ numéro de dossier est présent et interactif
    Wait Until Element Is Visible    css=input#num_doss_complet    timeout=${TIMEOUT}
    Wait Until Element Is Enabled    css=input#num_doss_complet    timeout=${TIMEOUT}

    # Saisir le numéro et simuler le changement
    Input Text until text is correct  css=#num_doss_complet  IN0131772200013

    Wait Until Element Is Visible    css=div#commune_chosen    timeout=${TIMEOUT}
    Wait Until Element Is Enabled    css=div#commune_chosen    timeout=${TIMEOUT}
    Simulate Event  css=input#num_doss_complet  change

    ${status} =  Run Keyword And Return Status  Page Should Contain Element  css=div#commune_loader_div.loader
    Run Keyword If  '${status}' == 'False'  Simulate Event  css=input#num_doss_complet  change
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # Vérifier la suggestion du type de dossier
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  IN - Infraction

    Select From Chosen List Suggestions Should Contain  commune  13177 - TESTCITY013177

Réinitialisation du paramétrage
    [Documentation]  Désactive via WS les paramètres :
    ...  - option_dossier_saisie_numero_complet : désactive la saisie au format complet
    ...  - option_dossier_commune : désactive les suggestions de commune
    ...  Les deux sont configurés pour la collectivité "agglo"

    # Désactivation des options
    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}
    # Désactiver les suggestions de commune
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}