*** Settings ***
Documentation     Actions spécifiques aux utilisateurs.

*** Keywords ***
Rechercher des utilisateurs
    [Documentation]  Accède au formulaire de recherche avancée des om_utilisateur. Dans
    ...  le formulaire, on saisie les valeurs fourni et clique sur recherche.
    [Arguments]  ${values}

    # On accède au tableau
    Depuis le listing des utilisateurs
    # Ouvre la recherche avancée
    Click Element  css=#toggle-advanced-display
    Wait Until Element Is Visible  css=div#adv-search-adv-fields input#om_utilisateur
    # Saisie les valeurs
    Saisir les paramètres de recherche avancée des utilisateurs  ${values}
    # Valide la recherche
    Click On Search Button

Saisir les paramètres de recherche avancée des utilisateurs
    [Documentation]  Entre les valeurs fournies dans le formulaire de saisie de la recherche.
    [Arguments]  ${values}

    Si "om_utilisateur" existe dans "${values}" on execute "Input Text"" dans le formulaire
    Si "nom" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "email" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "login" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "om_type" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "om_profil" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "om_collectivite" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "utilisateur_princ" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "utilisateurs_lies" existe dans "${values}" on execute "Select From List By Label" dans le formulaire

Depuis l'onglet groupe de l'utilisateur
    [Arguments]  ${login}

    Depuis le contexte de l'utilisateur  ${login}
    On clique sur l'onglet  lien_om_utilisateur_groupe  Groupe


Ajouter le groupe depuis l'onglet groupe de l'utilisateur
    [Tags]
    [Documentation]  Permet d'ajouter un utilisateur en accédant directement au formulaire
    [Arguments]  ${groupe_libelle}  ${confidentiel}=null  ${enregistrement_demande}=null

    Wait Until Element Is Visible  action-soustab-lien_om_utilisateur_groupe-corner-ajouter
    Click Element  action-soustab-lien_om_utilisateur_groupe-corner-ajouter
    # On remplit le formulaire
    Saisir le groupe  ${groupe_libelle}  ${confidentiel}  ${enregistrement_demande}
    # On valide le formulaire
    Click On Submit Button In Subform
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    Click On Back Button In Subform


Saisir le groupe
    [Tags]
    [Documentation]  Permet de remplir le formulaire d'un utilisateur.
    [Arguments]  ${groupe_libelle}  ${confidentiel}=null  ${enregistrement_demande}=null

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Be Visible  css=select#groupe
    # On sélectionne le groupe
    Run Keyword If  "${groupe_libelle}" != "null"  Select From List By Label  groupe  ${groupe_libelle}
    # On coche actif si spécifié
    Run Keyword If  "${confidentiel}" == "true"  Select Checkbox  confidentiel
    # On décoche confidentiel si spécifié
    Run Keyword If  "${confidentiel}" == "false"  Unselect Checkbox  confidentiel
    # On coche enregistrement_demande si spécifié
    Run Keyword If  "${enregistrement_demande}" == "true"  Select Checkbox  enregistrement_demande
    # On décoche enregistrement_demande si spécifié
    Run Keyword If  "${enregistrement_demande}" == "false"  Unselect Checkbox  enregistrement_demande


Modifier l'utilisateur depuis le menu
    [Arguments]  ${om_utilisateur}  ${values}

    Depuis le contexte de l'utilisateur  ${om_utilisateur}
    Click On Form Portlet Action  om_utilisateur  modifier
    Saisir l'utilisateur depuis le formulaire  ${values}
    Click On Submit Button

Supprimer l'utilisateur depuis le menu
    [Arguments]  ${om_utilisateur}

    Depuis le contexte de l'utilisateur  ${om_utilisateur}
    Click On Form Portlet Action  om_utilisateur  supprimer
    Click On Submit Button

Saisir l'utilisateur depuis le formulaire
    [Arguments]  ${values}

    Si "nom" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "email" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "login" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "pwd" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "om_collectivite" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "om_profil" existe dans "${values}" on execute "Select From List By Label" dans le formulaire

Saisir l'utilisateur lié depuis l'utilisateur principal
    [Arguments]  ${values}

    Si "nom" existe dans "${values}" on execute "Input Text" dans "om_utilisateur"
    Si "login" existe dans "${values}" on execute "Input Text" dans "om_utilisateur"
    Si "om_collectivite" existe dans "${values}" on execute "Select From List By Label" dans "om_utilisateur"
    Si "om_profil" existe dans "${values}" on execute "Select From List By Label" dans "om_utilisateur"

Depuis l'onglet des utilisateurs liés
    [Documentation]  Permet d'accéder à l'onglet des utilisateurs liés
    ...  dans le contexte d'un utilisateur.
    [Arguments]  ${user_login}

    Depuis le contexte de l'utilisateur  ${user_login}
    On clique sur l'onglet  lien_om_utilisateur_om_utilisateur  Utilisateur Lié

Depuis l'onglet des services liés
    [Documentation]  Permet d'accéder à l'onglet des utilisateurs liés
    ...  dans le contexte d'un utilisateur.
    [Arguments]  ${user_login}

    Depuis le contexte de l'utilisateur  ${user_login}
    On clique sur l'onglet  lien_service_om_utilisateur  Lien Service/utilisateur

Depuis le contexte de l'utilisateur lié
    [Documentation]  Permet d'accéder à la fiche de l'utilisateurs liés
    ...  dans le contexte d'un utilisateur.
    [Arguments]  ${user_login}  ${user_linked_login}

    Depuis l'onglet des utilisateurs liés  ${user_login}
    Input Text  recherchedyn  ${user_linked_login}
    Click On Link  ${user_linked_login}

Ajouter l'utilisateur lié
    [Documentation]  Permet d'ajouter un utilisateur lié dans le contexte
    ...  d'un utilisateur
    [Arguments]  ${user_login}  ${user_linked_values}

    Depuis l'onglet des utilisateurs liés  ${user_login}
    Click On Add Button
    Saisir l'utilisateur lié depuis l'utilisateur principal  ${user_linked_values}
    Click On Submit Button In Subform

Gerer l'utilisateur par WS via Paramètres
    [Tags]  utilisateur
    [Arguments]  ${nom}  ${email}  ${login}  ${pwd}  ${om_collectivite}=agglo  ${om_profil}=INSTRUCTEUR  ${delete}=false

    &{args} =  Create Dictionary
    ...  nom=${nom}
    ...  email=${email}
    ...  login=${login}
    ...  pwd=${pwd}
    ...  om_collectivite=${om_collectivite}
    ...  om_profil=${om_profil}
    ...  delete=${delete}
    ${resp} =  Gerer l'utilisateur par WS  ${args}
    [Return]  ${resp}


Gerer l'utilisateur par WS
    [Tags]  utilisateur
    [Arguments]  ${args}
    [Documentation]  Gerer l'ajout, modification ou suppression d'un événement via un webservice
    ...    Arguements attentdus :
    ...    - nom (string)  nom de l'utilisateur a renseigner
    ...    - email (string) email de l'utilisateur a renseigner
    ...    - login (string) login de l'utilisateur a renseigner
    ...    - pwd (string) mot de passe de l'utilisateur a renseigner
    ...    - om_collectivite (string) libelle de l'om_collectivite a liée à l'utilisateur
    ...    - om_profil (string) libelle de l'om_profil a liée à l'utilisateur
    ...    - delete (boolean) true si l'utilisateur doit être supprimé

    ${session} =  Catenate  http${PROJECT_NAME}
    Create Session  ${session}  ${PROJECT_URL}tests_services/rest_entry.php
    ${headers} =  Create Dictionary  Content-Type=application/json

    # Convertion de dictionnaire enshaine JSON
    ${json_string}=  evaluate  json.dumps(${args})  json

    ${resp}  Post Request  ${session}  /om_utilisateurs  data=${json_string}  headers=${headers}

    # On verifie s'il y a eu une erreur
    ${status} =  Run Keyword And Return Status  To Json  ${resp.content}
    Run Keyword If  '${status}' != 'True'  Log  ${resp.content}  WARN

    # Convertion de chaine JSON en dict python
    ${resp} =  To Json  ${resp.content}

    Run Keyword If  '${resp["http_code"]}' != '200'  Log  ${resp["message"]["message"]}  WARN
    Should be Equal  '${resp["http_code"]}'  '200'

    [Return]  ${resp["message"]["om_utilisateur"]}