*** Settings ***
Documentation  Teste le traitement des tâches de categorie 'portal'.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  Run Keywords
    ...  For Suite Setup
    ...  AND    Activation des options générales
    ...  AND    Activation de la configuration portal DS
Suite Teardown  Run Keywords
    ...  Désactivation de la configuration portal DS
    ...  AND    Désactivation des options générales
    ...  AND    For Suite Teardown


*** Test Cases ***
Constitution du jeu de données et du paramétrage dossiers
    [Documentation]  On se place dans un contexte SC pour simuler l'intégration de Consultations
    ...    Préalables provenant de Démarches Simplifiées dans l'instance du MC.

    # Isole le contexte du test (création d'une collectivité)
    &{librecom_multi_1_values} =  Create Dictionary
    ...  om_collectivite_libelle=305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  departement=017
    ...  commune=100
    ...  insee=17305
    ...  direction_code=DIR_305_002
    ...  direction_libelle=Direction de 305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  direction_chef=Chef DIR
    ...  division_code=DIV_305_002
    ...  division_libelle=Division de 305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  division_chef=Chef DIV
    ...  guichet_om_utilisateur_nom=Bobby Bob
    ...  guichet_om_utilisateur_email=bbob@openads-test.fr
    ...  guichet_om_utilisateur_login=bbob
    ...  guichet_om_utilisateur_pwd=bbob
    ...  instr_om_utilisateur_nom=Stevie Steve
    ...  instr_om_utilisateur_email=ssteve@openads-test.fr
    ...  instr_om_utilisateur_login=ssteve
    ...  instr_om_utilisateur_pwd=ssteve
    ...  code_entite=305_002_LBCOM_21
    ...  acteur=305_002_LIBRECOM-ACT-021
    Isolation d'un contexte  ${librecom_multi_1_values}
    Set Suite Variable  ${librecom_multi_1_values}

    # Ajoute un type de dossier d'autorisation
    &{args_type_dossier_autor} =  Create Dictionary
    ...  code=CP
    ...  libelle=Consultation préalable
    ...  groupe=Renseignement d'urbanisme
    Ajouter le type de dossier d'autorisation  ${args_type_dossier_autor}

    # Ajoute un type de dossier d'autorisation détaillé
    &{args_type_dossier_autor} =  Create Dictionary
    ...  code=CP
    ...  libelle=DS - CONSULTATION PREALABLE 
    ...  dossier_autorisation_type=CP (Consultation préalable)
    ...  cerfa=cerfa de test
    Ajouter type de dossier d'autorisation détaillé  ${args_type_dossier_autor}

    # Ajoute un type de dossier d'instruction
    &{args_type_dossier_instr} =  Create Dictionary
    ...  code=P
    ...  libelle=Consultation préalable DS (CP EP)
    ...  dossier_autorisation_type_detaille=CP (DS - CONSULTATION PREALABLE) 
    ...  mouvement_sitadel=SUPPRESSION
    ...  maj_da_etat=true
    ...  maj_da_demandeur=true
    ...  maj_da_dt=true
    Ajouter type de dossier d'instruction  ${args_type_dossier_instr}

    # Ajoute un état
    &{args_evenement} =  Create Dictionary
    ...    etat=305_002_nouveau_dossier
    ...    libelle=Nouveau dossier (305_002)
    ...    status=En cours
    Ajouter état  ${args_evenement}

    # Ajoute un type d'action
    &{args_action} =  Create Dictionary
    ...    action=initialisation_CP
    ...    libelle=Initialiser un dossier CP déposé au MC
    ...    regle_etat=etat
    ...    regle_delai=delai
    ...    regle_accord_tacite=accord_tacite
    Ajouter l'action depuis le menu  ${args_action}

    # Ajoute un type d'événement
    @{type_di} =  Create List  CP - P - Consultation préalable DS (CP EP)
    &{args_evenement} =  Create Dictionary
    ...    libelle=Nouveau dossier (CP DS)
    ...    notification=Notification automatique
    ...    dossier_instruction_type=${type_di}
    ...    action=Initialiser un dossier CP déposé au MC
    ...    etat=Nouveau dossier (305_002)
    Ajouter l'événement depuis le menu  ${args_evenement}
    Set Suite Variable  ${type_di}

    # Ajoute un type de demande
    &{args_demande_type} =  Create Dictionary
    ...    code=CPEP
    ...    libelle=Consultation préalable (CP EP) - dossier DS 
    ...    groupe=Renseignement d'urbanisme
    ...    dossier_autorisation_type_detaille=CP (DS - CONSULTATION PREALABLE)
    ...    demande_nature=Nouveau dossier
    ...    dossier_instruction_type=CP - Consultation préalable DS (CP EP)
    ...    evenement=Nouveau dossier (CP DS)
    Ajouter un nouveau type de demande depuis le menu  ${args_demande_type}

    # Définit les paramètres de type de demande
    &{platau_type_demande_initial} =  Create Dictionary
    ...  libelle=platau_type_demande_initial_CP
    ...  valeur=CPEP
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${platau_type_demande_initial}

    # En tant qu'admin
    Depuis la page d'accueil  admin  admin

    # Ajoute une commune
    &{com_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=17305
    ...  reg=17
    ...  dep=17
    ...  arr=100
    ...  tncc=0
    ...  ncc=305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  nccenr=305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  libelle=305_002_LIBRECOM_WS_CREATE_DI_PORTAL
    ...  can=17
    ...  comparent=
    ...  om_validite_debut=01/11/2020
    Ajouter commune avec dates validité  ${com_values}


Vérification du traitement de la tâche création DI dans un contexte SC
    [Documentation]  On ajoute une tâche de type create_DI provenant de Démarches-Simplifiées
    ...    afin de vérifier qu'un dossier Consultation Préalable est bien crée dans openADS.

    # Récupère le payload de création DI
    ${json_payload} =  Get File  ${EXECDIR}${/}binary_files${/}create_DI_portal_payload.txt
    ${json_payload} =  Replace String  ${json_payload}  13055  ${librecom_multi_1_values["insee"]}
    ${demande_external_id} =  Set Variable   RG9zc2llci0yNjgzMjAzMQ==
    ${json_payload} =  Replace String  ${json_payload}  id_portal_test  ${demande_external_id}
    ${payload_dict} =  To Json  ${json_payload}
    
    # Ajoute une tâche create_DI
    ${task_values} =  Create Dictionary
    ...  type=create_DI
    ...  category=portal
    ...  json_payload=${json_payload}
    Ajouter la tâche par WS  ${task_values}

    # Lance le taskmanager

    ${msg} =  Déclencher le traitement des tâches par WS

    # Vérification de la création du dossier

    Depuis la page d'accueil  bbob  bbob
    Depuis le listing  dossier_instruction

    # Récupération du numéro de dossier créé

    Click Link  ${librecom_multi_1_values["om_collectivite_libelle"]}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain Element  css=#dossier_libelle
    ${dossier_libelle_notrim} =  Get Text  css=#dossier_libelle
    ${dossier_libelle} =  Sans espace  ${dossier_libelle_notrim}
    Set Suite Variable  ${dossier_libelle_notrim}
    Set Suite Variable  ${dossier_libelle}


    # Vérification du traitement des tâches

    Depuis la page d'accueil  admin  admin
    Depuis le menu Moniteur IDE'AU

    # On vérifie qu'il y a une tâche Création demande dans l'état Terminé

    Element Should Contain  css=div#adv-search-adv-fields select#type  Création demande
    Select From List By Label  css=select#type  Création demande
    Input Text  css=div#adv-search-adv-fields input#object_id  ${dossier_libelle}
    Click On Search Button
    Element Should Contain  css=.tab-data  Terminé

    # On vérifie qu'il y a une tâche Notification récépissé dans l'état À Traiter

    Element Should Contain  css=div#adv-search-adv-fields select#type  Notification récépissé
    Select From List By Label  css=select#type  Notification récépissé
    Clear Element Text  css=div#adv-search-adv-fields input#object_id
    Input Text  css=div#adv-search-adv-fields input#dossier  ${dossier_libelle}
    Click On Search Button
    Element Should Contain  css=.tab-data  À Traiter

    # On vérifie que la tâche Notification récépissé contient les external_uids DS
    Click Link  Notification récépissé
    Click Element  css=#fieldset-form-task_portal-json_payload-calculee > .collapsible
    Element Should Contain  css=#fieldset-form-task_portal-json_payload-calculee #json_payload  ${demande_external_id}

    # On vérifie qu'aucune tâche platau de création DA n'est créée
    Depuis la page d'accueil  admin  admin
    Depuis le menu Moniteur Plat'AU
    ${passed} =  Run Keyword And Return Status  Element Should Not Contain  css=div#adv-search-adv-fields select#type  Création demande
    Run Keyword If  ${passed}==False  Select From List By Label  css=select#type  Création demande
    Run Keyword If  ${passed}==False  Input Text  css=div#adv-search-adv-fields input#dossier  ${dossier_libelle}
    Run Keyword If  ${passed}==False  Click On Search Button
    Run Keyword If  ${passed}==False  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=.tab-data  Aucun enregistrement.


Vérification des champs de fusion du dossier concernant les external_uids provenant de DS
    [Documentation]  On vérifie que les champs de fusion des identifiants externes soient bien
    ...    valués sur les éditions du dossier créé dans le testcase précédent.

    # Vérification du fonctionnement des champs de fusion liés aux external_uids 'demande' et 'code-suivi'
    # Ajout des champs de fusion sur une lettre type
    Depuis la page d'accueil  admin  admin
    &{args_lettretype} =  Create Dictionary
    ...  id=305_002_lettretype_test_merge_fields_external_uids
    ...  libelle=Lettre type test merge fields external uids
    ...  sql=Récapitulatif du dossier d'instruction / instruction (instruction)
    ...  titre=Titre
    ...  corps=[identifiant_externe_technique] [identifiant_externe_fonctionnel]
    ...  actif=true
    ...  collectivite=${librecom_multi_1_values["om_collectivite_libelle"]}
    Ajouter la lettre-type depuis le menu  &{args_lettretype}
    # Ajout d'une instruction liée à la lettre type
    Depuis la page d'accueil  admin  admin
    @{etat_source} =  Create List  Nouveau dossier (305_002)
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST_305_002_champs_fusion_external_uids
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=305_002_lettretype_test_merge_fields_external_uids Lettre type test merge fields external uids 
    ...  redirection_ajout=Listing des instructions (défaut)    
    Ajouter l'événement depuis le menu  ${args_evenement}
    # Ajout de l'instruction sur le dossier d'instruction
    Depuis le contexte du dossier d'instruction  ${dossier_libelle_notrim}
    Ajouter une instruction au DI  ${dossier_libelle_notrim}  TEST_305_002_champs_fusion_external_uids
    # Vérification de la présence des champs de fusion dans la lettre type
    Depuis l'instruction du dossier d'instruction  ${dossier_libelle_notrim}  TEST_305_002_champs_fusion_external_uids
    Click On SubForm Portlet Action  instruction  edition  new_window
    Open PDF  ${OM_PDF_TITLE}
    PDF Page Number Should Contain  1  26832031
    PDF Page Number Should Contain  1  RG9zc2llci0yNjgzMjAzMQ==
    Close PDF


*** Keywords ***
Activation des options générales
    # Active le paramètre option_dossier_saisie_numero_complet
    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}

    # Active le paramètreoption_dossier_commune
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}

    # Active le mode service consulté
    &{param_division} =  Create Dictionary
    ...  libelle=option_mode_service_consulte
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_division} 

    # Ajoute le paramètre option_notification
    &{param_notification} =  Create Dictionary
    ...  libelle=option_notification
    ...  valeur=mail,portal
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_notification}

    # Ajoute le paramètre parametre_notification_url_acces
    &{param_notification} =  Create Dictionary
    ...  libelle=parametre_notification_url_acces
    ...  valeur=http://localhost/openads/
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_notification}


Désactivation des options générales
    # Active le paramètre option_dossier_saisie_numero_complet
    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}

    # Active le paramètre option_dossier_commune
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}

    # Active le mode service consulté
    &{param_division} =  Create Dictionary
    ...  libelle=option_mode_service_consulte
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_division} 

    # Ajoute le paramètre option_notification
    &{param_notification} =  Create Dictionary
    ...  libelle=option_notification
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_notification}

    # Ajoute le paramètre parametre_notification_url_acces
    &{param_notification} =  Create Dictionary
    ...  libelle=parametre_notification_url_acces
    ...  delete=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_notification}

Activation de la configuration portal DS
    Run  sed -i '$ a\\$config\["type_portal_sve"\] = "ds";' ${EXECDIR}${/}..${/}dyn${/}config.inc.php

Désactivation de la configuration portal DS
    Run  sed -i '$d' ${EXECDIR}${/}..${/}dyn${/}config.inc.php