*** Settings ***
Documentation     Actions spécifiques aux documents d'instruction importés.

*** Keywords ***


La liste des documents d'instruction importés est visible avec les autres listes
    # Attente car il y a des 2èmes appels Ajax pour charger chaque tableau
    Wait Until Page Does Not Contain Element  class=spinner_container
    Wait Until Page Contains Element  css=#sousform-document_instruction table
    Wait Until Page Contains Element  css=#sousform-document_instruction_importe table
    Wait Until Page Contains Element  css=#sousform-document_numerise table

    Element Should Contain  css=#sousform-document_instruction  Documents d'instruction générés
    Page Should Contain Element  css=#sousform-document_instruction table

    Element Should Contain  css=#sousform-document_instruction_importe  Documents d'instruction importés
    Page Should Contain Element  css=#sousform-document_instruction_importe table

    Element Should Contain  css=#sousform-document_numerise  Documents de travail
    Page Should Contain Element  css=#sousform-document_numerise table


Cliquer sur le bouton d'ajout de document d'instruction importé
    Click Element  id=action-soustab-document_instruction_importe-corner-ajouter
    Wait Until Page Does Not Contain Element  class=spinner_container
    Wait Until Page Contains Element  css=#fieldset-sousform-document_instruction_importe-document-d_instruction-importe


Saisir le document d'instruction importé
    [Documentation]  Remplit le formulaire. Surcharge le mot-clé généré "Saisir document_instruction_importe"

    [Arguments]  ${values}

    Si "chemin_fichier_a_uploader" existe dans "${values}" on execute "Add File" sur "uid"
    Si "document_type" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    
    # Workaround car deux fois l'élément #description sur la page : on cible le bon sous-form à la place d'utiliser le mot clé existant
    # Si "description" existe dans "${values}" on execute "Input Text" dans le formulaire
    ${exist} =  Run Keyword And Return Status  Dictionary Should Contain Key  ${values}  description
    Run Keyword If  ${exist}  Input Text  css=#sousform-document_instruction_importe #description  ${values.description}

    ${id_document_instruction_importe} =  get element attribute  css=#document_instruction_importe  value

    [Return]  ${id_document_instruction_importe}

Consulter le document d'instruction importé
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element Until No More Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Consulter"]]


Prévisualiser le document d'instruction importé
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Prévisualiser"]]


Télécharger le document d'instruction importé
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Télécharger"]]