*** Settings ***
Documentation     Actions spécifiques aux documents d'instruction importés.

*** Keywords ***


Cliquer sur le bouton d'ajout de document d'instruction importé
    Click Element  id=action-soustab-document_instruction_importe-corner-ajouter
    Wait Until Page Contains Element  css=#fieldset-sousform-document_instruction_importe-document-d_instruction-importe


Ajouter un document d'instruction importé depuis le dossier d'instruction
    [Arguments]  ${dossier_instruction}  ${values}

    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction    ${dossier_instruction}
    Cliquer sur le bouton d'ajout de document d'instruction importé

    Saisir le document d'instruction importé  ${values}
    
    Click On Submit Button In Subform
    Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.

    ${id} =  Get Value  document_instruction_importe
    
    [Return]  ${id}


Saisir le document d'instruction importé
    [Documentation]  Remplit le formulaire. Surcharge le mot-clé généré "Saisir document_instruction_importe"

    [Arguments]  ${values}

    Si "chemin_fichier_a_uploader" existe dans "${values}" on execute "Add File" sur "uid"
    Si "document_type" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    
    # Workaround car deux fois l'élément #description sur la page : on cible le bon sous-form à la place d'utiliser le mot clé existant
    # Si "description" existe dans "${values}" on execute "Input Text" dans le formulaire
    ${exist} =  Run Keyword And Return Status  Dictionary Should Contain Key  ${values}  description
    Run Keyword If  ${exist}  Input Text  css=#sousform-document_instruction_importe #description  ${values.description}


Consulter le document d'instruction importé depuis la liste
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element Until No More Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Consulter"]]


Prévisualiser le document d'instruction importé depuis la liste
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Prévisualiser"]]


Télécharger le document d'instruction importé depuis la liste
    [Arguments]
    ...  ${document_instruction_importe_nom}

    Click Element  xpath=//div[@id="sousform-document_instruction_importe"]/descendant::tr[descendant::*[contains(text(), "${document_instruction_importe_nom}")]]/descendant::a[span[@title="Télécharger"]]