*** Settings ***
Documentation   Actions spécifiques au sous-onglet "Docs. instruction" de "Pièces & documents",
    ...         gérant les documents d'instruction générés, importés et les documents de travail

*** Keywords ***

L'onglet documents d'instruction est visible
    [Documentation]  On se base sur la présence de l'onglet actif.
    ...  On ne peut pas se baser sur le contenu car les tableaux changent
    ...  en fonction des permissions

    Wait Until Page Contains Element  css=.switcher__label.onglet_active[data-view="document_instruction"]


Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction
    [Arguments]  ${dossier_instruction}

    Depuis l'onglet des pièces du dossier d'instruction  ${dossier_instruction}
    Ouvrir le sous-onglet Docs. d'instruction


Depuis le contexte des documents de travail par le dossier d'instruction

    [Documentation]  Permet d'accéder à l'écran de visualisation du document de travail.

    [Arguments]  ${dossier_instruction}  ${document_travail}
    
    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${dossier_instruction}
    # Sélectionne le document de travail cherché
    Click Element Until No More Element  xpath=//div[@id="sousform-document_numerise"]/descendant::div[@id="sousform-container"]/descendant::div[@id="sousform-document_travail"]/descendant::a[text()[contains(.,"${document_travail}")]]


Ouvrir le sous-onglet Docs. d'instruction
    [Documentation]  Attendre que tous les tableaux de cet onglet "Docs. d'instruction" soient chargés

    Click Element Until New Element  
    ...    css=div[data-view="document_instruction"]
    ...    css=div.switcher__label.onglet_active[data-view="document_instruction"]
    
    # Attente du premier appel Ajax qui récupère les listes à charger dans les documents
    Wait Until Element Is Visible  id=switch-toutes_les_pieces-pieces_deposees

    # Attente des 2èmes appels Ajax pour charger chaque tableau
    # Ces tableaux ne sont pas toujours présents, en fonction des permissions. 
    # On ne les attend que si le script pour les charger est présent
    ${exists}=  Run Keyword And Return Status  Page Should Contain Element  id=tab_document_instruction_href
    Run Keyword If  ${exists}  Wait Until Element Is Visible  css=#sousform-document_instruction table  timeout=10s

    ${exists}=  Run Keyword And Return Status  Page Should Contain Element  id=tab_document_instruction_importe_href
    Run Keyword If  ${exists}  Wait Until Element Is Visible  css=#sousform-document_instruction_importe table  timeout=10s
    
    ${exists}=  Run Keyword And Return Status  Page Should Contain Element  id=tab_document_travail_href
    Run Keyword If  ${exists}  Wait Until Element Is Visible  css=#sousform-document_travail table  timeout=10s

    Wait Until Loading Spinner Is Gone
    La page ne doit pas contenir d'erreur


Ouvrir le sous-onglet Dossier final
    Click Element Until New Element  
    ...    css=div[data-view="document_numerise_dossier_final"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]

    Wait Until Loading Spinner Is Gone
    La page ne doit pas contenir d'erreur


Ouvrir le sous-onglet Téléchargements
    Click Element Until New Element  
    ...    css=div[data-view="document_numerise_telechargement"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_telechargement"]

    Wait Until Loading Spinner Is Gone
    La page ne doit pas contenir d'erreur


# -----------------------------------------------------------------------------
#                     Documents  de travail
# -----------------------------------------------------------------------------

Ajouter un document de travail depuis le dossier d'instruction
    [Arguments]  ${dossier_instruction}  ${document_numerise_values}  ${message}=null

    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction    ${dossier_instruction}

    Click Element  id=action-soustab-document_numerise-corner-ajouter

    Saisir la pièce  ${document_numerise_values}
    # On valide le formulaire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Submit Button In Subform
    # On vérifie le message de validation
    Run Keyword If  '${message}' != 'null'  Message Should Contain In Subform  ${message}
    Run Keyword If  '${message}' == 'null'  Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.
    # Retourne l'identifiant du message de notification
    ${dossier_message_id} =  Get Value  dossier_message_id
    [Return]  ${dossier_message_id}


Modifier un document de travail depuis le dossier d'instruction

    [Documentation]  Permet de modifier un document de travail sur un dossier d'instruction.

    [Arguments]  ${dossier_instruction}  ${document_travail}  ${document_numerise_values}  ${message}=null

    #
    Depuis le contexte des documents de travail par le dossier d'instruction  ${dossier_instruction}  ${document_travail}
    # On clique sur l'action modifier
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  document_numerise  modifier
    #
    Saisir la pièce  ${document_numerise_values}
    # On valide le formulaire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Submit Button In Subform
    # On vérifie le message de validation
    Run Keyword If  '${message}' != 'null'  Message Should Contain In Subform  ${message}
    Run Keyword If  '${message}' == 'null'  Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.


Supprimer un document de travail depuis le dossier d'instruction

    [Documentation]  Permet de supprimer un document de travail sur un dossier d'instruction.

    [Arguments]  ${dossier_instruction}  ${document_travail}  ${message}=null

    #
    Depuis le contexte des documents de travail par le dossier d'instruction  ${dossier_instruction}  ${document_travail}
    # On clique sur laction supprimer
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  document_numerise  supprimer
    # On valide le formulaire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Submit Button In Subform
    # On vérifie le message de validation
    Run Keyword If  '${message}' != 'null'  Message Should Contain In Subform  ${message}
    Run Keyword If  '${message}' == 'null'  Valid Message Should Contain In Subform  La suppression a été correctement effectuée.