*** Settings ***

Documentation  Vérification des droits sur les sous-onglets de Pièces & Documents

Resource  resources/resources.robot

Suite Setup  Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données
Suite Teardown  Run Keywords
    ...         Décomposition du jeu de données
    ...  AND    For Suite Teardown


*** Keywords ***

Composition du jeu de données
    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    # Créer et remplir une demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Rivière
    ...  particulier_prenom=Coralie
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di}


Décomposition du jeu de données
    &{option_miniature} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}


Aller sur l'onglet Pièces & Documents en tant qu'instructeur sur le DI
    [Arguments]  ${di}

    Depuis la page d'accueil  instr  instr
    Depuis le contexte du dossier d'instruction  ${di}
    On clique sur l'onglet  document_numerise  Pièces & Documents

*** Test Cases ***

L'onglet documents d'instruction ne s'affiche pas quand on a pas les droits
    [Setup]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Supprimer le droit depuis le contexte du profil  document_numerise_telechargement  INSTRUCTEUR
    
    # Vérifier que le toggle ne contienne pas l'onglet
    Aller sur l'onglet Pièces & Documents en tant qu'instructeur sur le DI  ${di}
    Element Should Not Be Visible  css=div[data-view="document_numerise_telechargement"]

    [Teardown]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Ajouter le droit depuis le menu  document_numerise_telechargement  INSTRUCTEUR
  

Vérification de la non présence du sous onglet Document d'instruction que si les deux permissions sont supprimées
    [Setup]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Supprimer le droit depuis le contexte du profil  document_instruction  INSTRUCTEUR
    ...  AND  Supprimer le droit depuis le contexte du profil  document_travail  INSTRUCTEUR

    # Vérifier que le toggle ne contienne pas l'onglet
    Aller sur l'onglet Pièces & Documents en tant qu'instructeur sur le DI  ${di}
    Element Should Not Be Visible  css=div[data-view="document_instruction"]

    # Si on remet le droit document_instruction...
    Depuis la page d'accueil  admin  admin
    Ajouter le droit depuis le menu  document_instruction  INSTRUCTEUR
    
    # ... vérifier qu'on peut voir l'onglet et seulement les bons tableaux
    Depuis la page d'accueil  instr  instr
    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${di}
    Page Should Contain  Documents d'instruction générés
    Page Should Contain  Documents d'instruction importés
    Page Should Not Contain  Documents de travail

    # Si on ne met que le droit document_travail...
    Depuis la page d'accueil  admin  admin
    Supprimer le droit depuis le contexte du profil  document_instruction  INSTRUCTEUR
    Ajouter le droit depuis le menu  document_travail  INSTRUCTEUR

    # ... vérifier qu'on peut voir l'onglet et seulement les bons tableaux
    Depuis la page d'accueil  instr  instr
    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${di}
    Page Should Not Contain  Documents d'instruction générés
    Page Should Not Contain  Documents d'instruction importés
    Page Should Contain  Documents de travail

    [Teardown]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Ajouter le droit depuis le menu si il n'existe pas  document_instruction  INSTRUCTEUR
    ...  AND  Ajouter le droit depuis le menu si il n'existe pas  document_travail  INSTRUCTEUR


L'onglet dossier final ne s'affiche pas quand on a pas les droits
    [Setup]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Supprimer le droit depuis le contexte du profil  document_numerise_dossier_final  INSTRUCTEUR

    # Vérifier que le toggle ne contienne pas l'onglet
    Aller sur l'onglet Pièces & Documents en tant qu'instructeur sur le DI  ${di}
    Element Should Not Be Visible  css=div[data-view="document_numerise_dossier_final"]

    [Teardown]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Ajouter le droit depuis le menu  document_numerise_dossier_final  INSTRUCTEUR


On affiche pas le toggle si on a seulement les droits sur les pièces pétitionnaires
    [Setup]  Run Keywords  Depuis la page d'accueil  admin  admin
    # On ne garde que les droits sur les pièces pétitionnaires
    ...  AND  Supprimer le droit depuis le contexte du profil  document_numerise_telechargement  INSTRUCTEUR
    ...  AND  Supprimer le droit depuis le contexte du profil  document_instruction  INSTRUCTEUR
    ...  AND  Supprimer le droit depuis le contexte du profil  document_travail  INSTRUCTEUR
    ...  AND  Supprimer le droit depuis le contexte du profil  document_numerise_dossier_final  INSTRUCTEUR

    # Le toggle complet ne devrait pas être visible
    Aller sur l'onglet Pièces & Documents en tant qu'instructeur sur le DI  ${di}
    Element Should Not Be Visible  css=#switch-toutes_les_pieces-pieces_deposees

    [Teardown]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Ajouter le droit depuis le menu  document_numerise_dossier_final  INSTRUCTEUR
    ...  AND  Ajouter le droit depuis le menu  document_travail  INSTRUCTEUR
    ...  AND  Ajouter le droit depuis le menu  document_instruction  INSTRUCTEUR
    ...  AND  Ajouter le droit depuis le menu  document_numerise_telechargement  INSTRUCTEUR