*** Settings ***
Documentation  L'historisation d'une pièce numérisée consiste à conserver les anciennes
    ...  versions quand on rajoute la version signée d'un document
    ...  Dans ce cas, seule la dernière version est ressortie dans les exports,
    ...  mais la version précédente reste disponible.

Resource  resources/resources.robot

Suite Setup     Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données  
Suite Teardown  Run Keywords
    ...         Décomposition du jeu de données
    ...  AND    For Suite Teardown



*** Keywords ***


Composition du jeu de données
    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Histo
    ...  particulier_prenom=Rie
    ...  om_collectivite=MARSEILLE

    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Les dossiers sont accessibles dans la suite du test
    Set Suite Variable  ${di}


Décomposition du jeu de données
    &{param} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param}


Le PDF est présent sur la page et contient sur la première page
    [Arguments]  ${nom_partiel_fichier}  ${contenu}

    Page Should Contain  ${nom_partiel_fichier}
    Click Element  partial link: ${nom_partiel_fichier}
    Open PDF  ${OM_PDF_TITLE}
    PDF Page Number Should Contain  1  ${contenu}
    Close PDF


*** Test Cases ***

Le fichier est correctement historisé lors de l'import d'un document signé
    [Documentation]  Quand on importe un nouveau document signé, la version précédente
    ...  du fichier est "historisée", en rajoutant "_remplace_le_DATEHEURE"
    ...  Ce document historisé n'apparait plus dans dossier final ou téléchargement
    ...  mais est disponible dans la liste des documents d'instruction

    Depuis la page d'accueil  admin  admin    
    Depuis l'onglet instruction du dossier d'instruction  ${di}

    # Accéder à l'instruction
    Click On Link  Notification du delai legal maison individuelle

    # Ajout du document signé via la modale de modification du document
    Click On SubForm Portlet Action  instruction  modale_selection_document_signe  modale
    Wait Until Page Contains Element  css=input#modale_date_retour_signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Input Datepicker  modale_date_retour_signature  ${date_retour_sign}
    Add File  document_signe  testImportManuel.pdf
    Click On Submit Button In Subform
    Valid Message Should Contain  Le document a bien été mis à jour.
    # On ferme la modale
    Click Element Until No More Element  css=.ui-dialog-titlebar-close

    # On vérifie que la date de retour signature s'est bien mise à jour
    Wait Until Element Contains  css=#date_retour_signature  ${date_retour_sign}

    # Vérification des pièces
    Depuis l'onglet des pièces du dossier d'instruction  ${di}

    # Vérifier que c'est bien le nouveau document qui est dans les téléchargements, 
    # et pas le document historisé
    Ouvrir le sous-onglet Téléchargements
    Page Should Not Contain  _remplace_le_
    Le PDF est présent sur la page et contient sur la première page  recepisse_1.pdf  TEST IMPORT MANUEL 1

    # Vérifier que c'est bien le nouveau document qui est dans le dossier final, 
    # et pas le document historisé
    Ouvrir le sous-onglet Dossier final
    Page Should Not Contain  _remplace_le_
    Le PDF est présent sur la page et contient sur la première page  recepisse_1.pdf  TEST IMPORT MANUEL 1


    # Vérifier que les deux sont bien dans les documents d'instruction
    Ouvrir le sous-onglet Docs. d'instruction
    Le PDF est présent sur la page et contient sur la première page  _remplace_le_  Permis de construire pour une maison individuelle et / ou ses annexes
    Le PDF est présent sur la page et contient sur la première page  recepisse_1.pdf  TEST IMPORT MANUEL 1