*** Settings ***
Documentation  Fonctionnalités basiques sur les documents numérisés/pièces.

Resource  resources/resources.robot

Suite Setup     Run Keywords
    ...         For Suite Setup
    ...  AND    Composition du jeu de données  
Suite Teardown  Run Keywords
    ...         Décomposition du jeu de données
    ...  AND    For Suite Teardown


*** Keywords ***

Composition du jeu de données
    # Autoriser les pièces numérisées
    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    # Créer et remplir une demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Rivière
    ...  particulier_prenom=Coralie
    ...  om_collectivite=MARSEILLE
    #
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}


    Depuis la page d'accueil  instr  instr
    Ajouter une consultation depuis un dossier  ${di}  59.13 - Régie des Tranports de Marseille - DTP/CIP

    Depuis la page d'accueil  admin  admin

    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=20/09/2015
    ...  document_numerise_type=vues et coupes du projet dans le profil du terrain naturel
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel2.pdf
    ...  date_creation=10/09/2005
    ...  document_numerise_type=vues et coupes du projet dans le profil du terrain naturel
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    # Les dossiers sont accessibles dans la suite du test
    Set Suite Variable  ${di}

    # On ajoute un type de pièce non affiché sur les DA
    ${dntc_libelle} =  Set Variable  Non visible au public
    &{dntc_values} =  Create Dictionary
    ...  libelle=${dntc_libelle}
    Ajouter la catégorie de pièces  ${dntc_values}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    ${dnt_code} =  Set Variable  NVPLAN
    ${dnt_libelle} =  Set Variable  Plan non public*°6àâäéèëù~\\\/#^$µ§![(&@;?:!%
    ${instructeur_qualite} =  Create List
    ...  instructeur
    &{dnt_values} =  Create Dictionary
    ...  code=${dnt_code}
    ...  libelle=${dnt_libelle}
    ...  document_numerise_type_categorie=${dntc_libelle}
    ...  aff_da=false
    ...  instructeur_qualite=${instructeur_qualite}
    Ajouter le type de pièces  ${dnt_values}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajoute une pièce numérisée sur le DI vérifié
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=21/09/2015
    ...  document_numerise_type=${dnt_libelle}
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    # On récupère le numéro du dossier d'autorisation depuis le numéro du DI
    ${dossier_autorisation} =  Get Substring  ${di}  0  -2
    Set Suite Variable  ${dossier_autorisation}

Décomposition du jeu de données
    &{option_miniature} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${option_miniature}


Activer l'option de masquage des pièces refusées
    &{param_values_1} =  Create Dictionary
    ...  libelle=option_cache_piece_num_refuse_da
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values_1}

Désactiver l'option de masquage des pièces refusées
    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_cache_piece_num_refuse_da
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}



*** Test Cases ***

Vérification de l'affichage sur le dossier d'autorisation
    Depuis la page d'accueil  guichet  guichet
    Depuis l'onglet des pièces du dossier d'autorisation  ${dossier_autorisation}

    # On vérifie que le numéro du dossier d'instruction est affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di}
    # On vérifie que le nom du fichier est affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  20150920DGPA05.pdf
    # On vérifie que la pièce n'est pas affiché
    Page Should Not Contain  20150921NVPLAN.pdf
    
    # On clique pour visualiser le document
    Click Element  css=tr.col4 td.col-1 a.lienTable span.reqmo-16
    Open PDF  ${OM_PDF_TITLE}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  TEST IMPORT MANUEL 2
    Close PDF


Les pièces refusées ne sont pas affichées avec l'option option_cache_piece_num_refuse_da
    [Setup]  Activer l'option de masquage des pièces refusées    

    # Ajouter une instruction de refus
    Depuis la page d'accueil  admin  admin
    Ajouter une instruction au DI et la finaliser  ${di}  ARRÊTÉ DE REFUS
    &{args_instruction} =  Create Dictionary
    ...  date_retour_rar=${DATE_FORMAT_DD/MM/YYYY}
    Modifier le suivi des dates  ${di}  ARRÊTÉ DE REFUS  ${args_instruction}

    # Vérification de l'affichage
    Depuis la page d'accueil  guichet  guichet

    Depuis l'onglet des pièces du dossier d'autorisation  ${dossier_autorisation}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  20150920DGPA05.pdf

    # Suppression de l'instruction d'arrete de refus et suppression de l'option
    [Teardown]  Run Keywords  Depuis la page d'accueil  admin  admin
    ...  AND  Depuis l'instruction du dossier d'instruction  ${di}  Arrêté de Refus signé
    ...  AND  Click On SubForm Portlet Action  instruction  definaliser

    ...  AND  Supprimer l'instruction  ${di}  Arrêté de Refus signé
    ...  AND  Depuis l'instruction du dossier d'instruction  ${di}  ARRÊTÉ DE REFUS
    ...  AND  Click On SubForm Portlet Action  instruction  definaliser
    ...  AND  Supprimer l'instruction  ${di}  ARRÊTÉ DE REFUS

    ...  AND  Désactiver l'option de masquage des pièces refusées


Vérification de l'affichage sur la demande d'avis
    # On ajoute un type de pièce non affiché sur les demandes d'avis
    Depuis la page d'accueil  admin  admin
    ${dntc_libelle} =  Set Variable  Top secret
    &{dntc_values} =  Create Dictionary
    ...  libelle=${dntc_libelle}
    Ajouter la catégorie de pièces  ${dntc_values}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    ${dnt_code} =  Set Variable  TSPLAN
    ${dnt_libelle} =  Set Variable  Plan top secret
    ${instructeur_qualite} =  Create List
    ...  instructeur
    &{dnt_values} =  Create Dictionary
    ...  code=${dnt_code}
    ...  libelle=${dnt_libelle}
    ...  document_numerise_type_categorie=${dntc_libelle}
    ...  aff_service_consulte=false
    ...  instructeur_qualite=${instructeur_qualite}
    Ajouter le type de pièces  ${dnt_values}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajoute une pièce numérisée sur le DI vérifié
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=21/09/2015
    ...  document_numerise_type=${dnt_libelle}
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}

    #
    Depuis la page d'accueil  consu  consu
    #
    Depuis l'onglet des pièces de la demande d'avis en cours du dossier d'instruction  ${di}
    # On vérifie que le nom du fichier est affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  20150920DGPA05.pdf
    # On vérifie que la pièce n'est pas affiché
    Page Should Not Contain  20150921TSPLAN.pdf
    # On vérifie que la pièce n'est pas affiché
    Page Should Not Contain  20150921TSPLAN.pdf
    # On clique pour visualiser le document
    Click Element  css=tr.col3 td.firstcol a.lienTable span.reqmo-16
    Open PDF  ${OM_PDF_TITLE}
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  TEST IMPORT MANUEL 2
    # On ferme le PDF
    Close PDF


Téléchargement de l'intégralité des documents numerise

    [Documentation]  Contrôle que l'action "télécharger tous les documents" dans l'onglet
    ...  Documents(s) d'un dossier d'instruction produit bien une archive téléchargeable
    ...  contenant toutes les pièces.
    ...  On ajoute plusieurs fois le même type de pièce le même jour pour vérifier que les
    ...  fichiers sont bien suffixés.

    Depuis la page d'accueil  admin  admin

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Compagnon
    ...  particulier_prenom=Jean
    ...  om_collectivite=MARSEILLE

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Ajout d'un document d'instruction et de documents de travail de format différent
    &{document_travail_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.jpg
    ...  date_creation=31/03/2016
    ...  description_type=image
    Ajouter un document de travail depuis le dossier d'instruction  ${di_libelle}  ${document_travail_values}

    &{document_travail_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=31/03/2016
    ...  description_type=pdf
    Ajouter un document de travail depuis le dossier d'instruction  ${di_libelle}  ${document_travail_values}

    &{document_travail_values} =  Create Dictionary
    ...  uid_upload=fichier_1.odt
    ...  date_creation=30/03/2016
    ...  description_type=texte
    Ajouter un document de travail depuis le dossier d'instruction  ${di_libelle}  ${document_travail_values}

    # Récupération du nom des documents d'instruction
    Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${di_libelle}
    ${nom_fichier_doc_instr} =  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}   Get Text  css=#sousform-document_instruction .tab-data td.col-1 span
    # Utilisation de l'action de téléchargement des documents
    ${path_archive}  ${archive_name} =  Télécharger tous les documents

    # Composition du nom correct de l'archive zip
    ${di_libelle_spaceless} =  Sans espace  ${di_libelle}
    ${date_ddmmyyyy} =  Date du jour EN
    ${date_jour_sans_tirets} =  STR_REPLACE  -  ${EMPTY}  ${date_ddmmyyyy}
    ${correct_archive_name_di} =  Set Variable  ${di_libelle_spaceless}_${date_jour_sans_tirets}.zip

    # Vérification du nom de l'archive, qui doit commencer par le n° de DI
    Should Be Equal  ${correct_archive_name_di}  ${archive_name}
    # L'archive doit contenir les 3 documents de travail et le document d'instruction
    Archive Should Contain File  ${path_archive}  20160331DOCTRAV.pdf
    Archive Should Contain File  ${path_archive}  20160331DOCTRAV.jpg
    Archive Should Contain File  ${path_archive}  20160330DOCTRAV.odt
    # A mettre à jour suite à l'évolution des noms de fichier d'instruction
    Archive Should Contain File  ${path_archive}  ${nom_fichier_doc_instr}