*** Settings ***
Documentation     Notification des demandeurs

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données

    Définition des variables - Notification Service consultant

    Run Keyword If  '${CONTEXT_NOTIFICATION_TIERS_CREATED}' == 'False'  Constitution du jeu de données - Notification Service consultant
    Set Global Variable  ${CONTEXT_NOTIFICATION_TIERS_CREATED}  True

    Construction du PARAMETRAGE - Notification Tiers

Affichage dynamique des champs sur le formulaire d'ajout d'un événement
    [Documentation]  Cas d'usage
    ...    En tant qu'administrateur, depuis l'écran de configuration d'un événement A, je sélectionne la valeur "Notification automatique" depuis le paramètre" Notification des tiers.
    ...        En plus du champ Notification par type d’habilitation, une nouvelle case à cocher Notification du tiers service consultant m'est présenté, je la coche.
    ...    En tant qu'instructeur, sur mon dossier, j'ai préalablement identifié l'acteur "Service urbanisme" acteur en tant que service consultant.
    ...        Depuis le menu Instruction j'ajoute une instruction A, je la finalise et l'envoi en signature. Au retour de signature, le document est notifié automatiquement à l'acteur service consultant.
    ...        Sur l'instruction A, au niveau du suivi de notification, une ligne présente les informations correspondantes.
 
    Depuis la page d'accueil  admin  admin
    Depuis le formulaire d'ajout de l'événement
    Wait Until Page Contains Element  css=#notification_tiers
    Select From List By Label  css=#notification_tiers  Notification automatique

    Click On Submit Button
    La page ne doit pas contenir d'erreur


    # Création d'un dossier
    Depuis la page d'accueil  admin  admin
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=test onglet
    ...  particulier_prenom=acteur
    ...  om_collectivite=${collectivite}
    &{args_demande} =  Create Dictionary
    ...  om_collectivite=${collectivite}
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  commune=${code_commune} - ${lib_commune}
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    ${di_libelle_ns} =  Sans espace  ${di_libelle}


    # Cas 2 : ajout de 4 catégories (3 auto et 3 manuelle avec 2 identique dont 1 qui ne sera pas affiché sur le DI) au PCI initial.
    # Un tableau doit être affiché pour chaque catégorie sans doublon,
    @{categorie_tiers_dossier} =  Create List  ${cat_tiers}  ${cat_tiers_3}  ${cat_tiers_autre_colle}
    @{categorie_tiers_dossier_auto} =  Create List  ${cat_tiers}  ${cat_tiers_2}  ${cat_tiers_autre_colle}
    &{val_PCI} =  Create Dictionary
    ...  categories_tiers=${categorie_tiers_dossier}
    ...  categories_tiers_ajout_auto=${categorie_tiers_dossier_auto}
    Modifier type de dossier d'instruction  PCI  P  ${val_PCI}

    # AFFICHAGE DU LISTING DES ACTEURS
    Depuis l'onglet acteur du dossier d'instruction  ${di_libelle}
    # Test du fonctionnement du formulaire d'ajout d'acteur
    ${id_cat_tiers_2} =  Depuis le contexte de la categorie de tiers consulte  ${code_cat_tiers_2}
    Depuis le formulaire d'ajout des acteurs d'une catégorie au dossier  ${di_libelle}  ${id_cat_tiers_2}

    # Ajout de deux acteurs et vérification de l'affichage trier par ordre alphabétique
    # dans le tableau correspondant
    @{acteurs} =  Create List  ${tiers_notif_man}
    Saisir des acteurs  ${acteurs}
    Click On Submit Button Until Message  L'acteurs ${tiers_notif_man} a été ajouté au dossier.

    # SERVICE CONSULTANT
    Cliquer sur le bouton de consultation de l'acteur  ${tiers_notif_man}
    # Marquer comme service consultant
    Click On SubForm Portlet Action  lien_dossier_tiers  marquer_comme_service_consultant
    Element Should Contain  css=div.message.ui-state-valid p span.text  L'acteur a été marqué comme service consultant.
    # Présence de l'action de portlet 'Dé-marquer comme service consultant'
    Element Should Be Visible   id=action-sousform-lien_dossier_tiers-demarquer_comme_service_consultant
    Click On Back Button In SubForm

    # Vérification de la présence du service consultant sur le formulaire du DI
    Depuis le contexte du dossier d'instruction  ${di_libelle}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  service_consultant  ${tiers_notif_man}

    # Présence de la mention '(service consultant)' sur le Tiers concerné,
    # dans le cadre de la notification manuelle d'une instruction
    ${instruction} =  Ajouter une instruction au DI et la finaliser   ${di_libelle}  ${evenement_notif_auto_tc}

    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_ddmmyyyy}
    Click On Submit Button In Subform

    Go To  ${PROJECT_URL}/app/index.php?module=tab&obj=instruction_notification
    Use Simple Search  Instruction  ${di_libelle_ns}
    Page Should Contain  1 enregistrement(s) sur 1

    # Reset de l'instruction
    Depuis l'instruction du dossier d'instruction  ${di_libelle}  ${evenement_notif_auto_tc}
    Click On SubForm Portlet Action  instruction  definaliser
    Supprimer l'instruction  ${di_libelle}  ${evenement_notif_auto_tc}

    Go To  ${PROJECT_URL}/app/index.php?module=tab&obj=instruction_notification
    Use Simple Search  Instruction  ${di_libelle_ns}
    Page Should Contain  0 enregistrement(s) sur 0

    # On ajoute un événement avec notification automatique des tiers consultant
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    ${lib_habilitation_tiers_consultant} =  Set Variable  TEST_NOTIF_Consultant
    @{type_habilitation_tiers_consultant} =  Create List  ${lib_habilitation_tiers_consultant}
    &{args_evenement} =  Create Dictionary
    ...  libelle=${type_habilitation_tiers_consultant}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=${args_lettretype.id} ${args_lettretype.libelle}
    ...  redirection_ajout=Modification de l'instruction
    ...  notification_tiers=Notification automatique
    Ajouter l'événement depuis le menu  ${args_evenement}
    Click On Form Portlet Action  evenement  modifier
    Wait Until Page Contains Element  css=#notification_automatique_tiers_consultant
    Select Checkbox  css=#notification_automatique_tiers_consultant
    Click On Submit Button

    # 
    Ajouter une instruction au DI et la finaliser  ${di_libelle}  ${lib_habilitation_tiers_consultant}

    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_ddmmyyyy}
    Click On Submit Button In Subform

    Go To  ${PROJECT_URL}/app/index.php?module=tab&obj=instruction_notification
    Use Simple Search  Instruction  ${di_libelle_ns}
    Page Should Contain  1 enregistrement(s) sur 1

    Depuis l'instruction du dossier d'instruction  ${di_libelle}  ${lib_habilitation_tiers_consultant}
    Click On SubForm Portlet Action  instruction  definaliser
    Supprimer l'instruction  ${di_libelle}  ${lib_habilitation_tiers_consultant}

    Go To  ${PROJECT_URL}/app/index.php?module=tab&obj=instruction_notification
    Use Simple Search  Instruction  ${di_libelle_ns}
    Page Should Contain  0 enregistrement(s) sur 0

    # On ajoute les service consultant à l'événement
    Depuis le contexte de l'événement  ${evenement_notif_auto_tc}
    Click On Portlet Action  evenement  modifier
    Wait Until Page Contains Element  css=#notification_automatique_tiers_consultant
    Select Checkbox  css=#notification_automatique_tiers_consultant
    Click On Submit Button

    # 
    ${instruction} =  Ajouter une instruction au DI et la finaliser   ${di_libelle}  ${evenement_notif_auto_tc}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_ddmmyyyy}
    Click On Submit Button In Subform

    Go To  ${PROJECT_URL}/app/index.php?module=tab&obj=instruction_notification
    Use Simple Search  Instruction  ${di_libelle_ns}
    Page Should Contain  1 enregistrement(s) sur 1

Décomposition du jeu de données

    Décomposition PARAMETRAGE - Notification Tiers