*** Settings ***
Documentation  Test du Module Example AddField
Force Tags  modules  exclude

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Variables ***
${code}  613
${name}  addfield
${libelle_evenement}  TEST_Evement_${code}_${name}

*** Test Cases ***
Installation du module
    [Documentation]  Le module documents_specifique instal une ligne dans la table lien_module
    ...    pour permetre l'ajoute à la volée de l'acteur platau dans la payload.

    [Tags]  modules  exclude

    Run  php ../deploy/deploy_modules.php install admin admin ${name}

Présence du module et ajout
    [Documentation]  Avec un profil administrateur, depuis le menu paramétrage dossiers > workflows > événement
    ...    Nous choissisons un événement et vérifions que dans l'onglet Modules nous pouvons ajouter le Module à un événement

    [Tags]  modules  exclude

    Depuis la page d'accueil  admin  admin

    # Création d'un événement de workflow de test pour le module
    @{etat_source} =  Create List
    ...    dossier accepter
    ...    dossier accepté tacitement
    ...    dossier rejeter manque de pieces
    ...    delai de notification envoye
    ...    dossier incomplet
    @{type_di} =  Create List
    ...    PCI - P - Initial
    ...    PA - P - Initial
    ...    DP - P - Initiale
    ...    IN - P - Initiale
    &{args_evenement} =  Create Dictionary
    ...  libelle=${libelle_evenement}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}

    Ajouter l'événement depuis le menu  ${args_evenement}

    Depuis le contexte de l'événement  ${libelle_evenement}

    Click Element Until New Element  css=#lien_module  css=.add-16
    Page Should Contain  lien_module

    Click Element  css=.add-16
    Wait until Page Contains  Type d'objet

    Select From List By Value  css=#module  ${name}
    Input Text  css=#ordre  0
    ${parametres_A} =  Create List
    ...    field_name=Test_Field_A\n
    ...    alias_champ_fusion=test_field_A\n
    ...    description=Test Field A\n
    ...    type=text\n
    ...    field_type=text\n
    ...    max_length=50\n
    ...    show_in_listing=false\n
    ...    searchable=false\n
    ...    object_name=instruction
    Set Suite Variable  ${parametres_A}
    Input Text  css=#parametres  ${parametres_A}

    # Optionnal params validator_cb as table [0] object or module

    Click On Submit Button
    Page Should Contain  Vos modifications ont bien été enregistrées.

    # Remplissage de la liste des identifiants des modules pour pouvoir les supprimer
    ${id_module_A} =  Get Text  css=div.form-content span#lien_module
    Set Suite Variable  ${id_module_A}

    Click On Back Button In Subform
    Page Should Contain  Ajout d'un champ sur un objet (exemple)

    ${parametres_B} =  Create List
    ...    field_name=Test_Searchable_FieldB\n
    ...    description=Test Searchable Field B\n
    ...    alias_champ_fusion=test_field_B\n
    ...    type=int\n
    ...    field_type=text\n
    ...    max_length=5\n
    ...    show_in_listing=true\n
    ...    searchable=true\n
    ...    object_name=instruction
    Set Suite Variable  ${parametres_B}
    ${id_module_B} =  Parametrer un Module sur un Evenement
    ...    ${libelle_evenement}
    ...    ${name}
    ...    None
    ...    1
    ...    ${parametres_B}
    Set Suite Variable  ${id_module_B}

    Page Should Contain  Vos modifications ont bien été enregistrées.

    Click On Back Button In Subform
    Page Should Contain  1 - 2 enregistrement(s) sur 2

Existance et fonctionnement du champ dans instruction
    [Documentation]  Test la présence d'un action helloworld dans les actions

    [Tags]  modules  exclude

    # Constitution du jeu de données spécifique à ce TestCase
    #
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Modulette
    ...  particulier_prenom=${name}
    ...  om_collectivite=MARSEILLE
    @{ref_cad} =  Create List  806  AB  0025  A  0030
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=MARSEILLE
    ${libelle_di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${libelle_di}
    ${libelle_di_sans_espace} =  Sans espace  ${libelle_di}

    # Ajouter l'instruction avec événement => ${libelle_evenement}
    Depuis le formulaire d'ajout d'une instruction du DI  ${libelle_di}
    Saisir instruction  ${libelle_evenement}

    Page Should Contain  Données complémentaires
    Page Should Contain  Test Field A
    Page Should Contain  Test Searchable Field B

    Input Text  css=#Test_Field_A  TEST-Value-Insert

    Click On Submit Button

    Page Should Contain  Donnée complémentaire 'Test_Field_A' enregistrée
    Page Should Contain  Donnée complémentaire 'Test_Searchable_FieldB' enregistrée

    # Tester la présence des champs de fusion
    Depuis l'instruction du dossier d'instruction  ${libelle_di}  ${libelle_evenement}

    Page Should Contain  TEST-Value-Insert


# Desactivation du module

#     Depuis la page d'accueil  admin  admin
#     Supprimer le module de l'evenement  ${id_module_A}
#     Valid Message Should Contain  La suppression a été correctement effectuée.
#     Supprimer le module de l'evenement  ${id_module_B}
#     Valid Message Should Contain  La suppression a été correctement effectuée.