*** Settings ***
Documentation  Test sur les dossiers d'instruction.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Constitution du jeu de données nécessaire pour les tests.
        Depuis la page d'accueil  admin  admin

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Geault
    ...  particulier_prenom=Sivette
    ...  om_collectivite=MARSEILLE
    ${di_lib} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di_lib}
    ${di} =  Sans espace  ${di_lib}
    Set Suite Variable  ${di}

    # Création de données complémentaires sur le DI
    ${xd_def} =  Execute SQL  INSERT INTO openads.extra_data_register_def (extra_data_register_def, name, description, type, object_name, max_length) VALUES (nextval('openads.extra_data_register_def_seq'), 'xd_doss', 'XD dossier', 'string', 'dossier', 6)
    Log  ${xd_def}
    ${res} =  Execute SQL  INSERT INTO openads.extra_data_register_values (extra_data_register_values, definition_ref, object_id, value_int) VALUES (nextval('openads.extra_data_register_values_seq'), ${xd_def}, '${di}', 10)
    Log  ${res}

    # Ajout d'une nouvelle instruction
    ${instr_id} =  Ajouter une instruction au DI et la finaliser  ${di_lib}
    ...  accepter un dossier sans réserve  true
    Set Suite Variable  ${instr_id}
    Log  ${instr_id}

    # Création de données complémentaires sur l'instruction
    ${xd_def} =  Execute SQL  INSERT INTO openads.extra_data_register_def (extra_data_register_def, name, description, type, object_name, max_length) VALUES (nextval('openads.extra_data_register_def_seq'), 'xd_instr', 'XD instruction', 'string', 'instruction', 6)
    Log  ${xd_def}
    ${res} =  Execute SQL  INSERT INTO openads.extra_data_register_values (extra_data_register_values, definition_ref, object_id, value_int) VALUES (nextval('openads.extra_data_register_values_seq'), ${xd_def}, ${instr_id}, 20)
    Log  ${res}


Paramétrage de l'affichage des données complémentaires

    # Ajout de 2 (om) requêtes pour les données complémentaires du dossier (une avec données, l'autre sans)
    Ajouter la requête  xd_req_d1  XD requête dossier 1  extra data - requête dossier 1  sql
    ...  SELECT value_int AS val1 FROM &DB_PREFIXEextra_data_register_values WHERE object_id = '&idx'
    Ajouter la requête  xd_req_d2  XD requête dossier 2  extra data - requête dossier 2  sql
    ...  SELECT value_str AS val2 FROM &DB_PREFIXEextra_data_register_values WHERE object_id = '&idx'

    # Ajout d'un template (Twig) pour le dossier
    &{tpl_doss} =  Create Dictionary
    ...  libelle=tpl_xd_doss
    ...  code=XD dossier 1: {% if val1 is defined and val1|length > 0 %}{{ val1 }}{% else %}Aucune donnée supplémentaire{% endif %}\n<br/>XD dossier 2: {% if val2 is defined and val2|length > 0 %}{{ val2 }}{% else %}Aucune donnée supplémentaire{% endif %}
    Ajouter template  ${tpl_doss}

    # Affectation de la requête et du template au type de dossier correspondant
    @{dit_req} =  Create List
    ...  XD requête dossier 1 (xd_req_d1)
    ...  XD requête dossier 2 (xd_req_d2)
    &{dit_mod} =  Create Dictionary
    ...  extra_data_req=${dit_req}
    ...  extra_data_tpl=tpl_xd_doss
    Modifier type de dossier d'instruction  PCI  P  ${dit_mod}

    # Ajout d'une (om) requête pour les données complémentaires de l'instruction
    Ajouter la requête  xd_req_i  XD requête instruction  extra data - requête instruction  sql
    ...  SELECT value_int AS val FROM &DB_PREFIXEextra_data_register_values WHERE object_id = '&idx'

    # Ajout d'un template (Twig)
    &{tpl_instr_page} =  Create Dictionary
    ...  libelle=tpl_xd_instr_page
    ...  code=XD instruction: {% if val is defined and val|length > 0 %}{{ val }}{% else %}Aucune donnée supplémentaire{% endif %}
    Ajouter template  ${tpl_instr_page}

    # Ajout d'un template (Twig)
    &{tpl_instr_list} =  Create Dictionary
    ...  libelle=tpl_xd_instr_lst
    ...  code=XD instruction lst: {% if val is defined and val|length > 0 %}{{ val }}{% else %}Aucune donnée supplémentaire{% endif %}
    Ajouter template  ${tpl_instr_list}

    # Affectation des requêtes et des templates à l'évènement d'instruction
    @{evt_req} =  Create List  XD requête instruction (xd_req_i)
    &{evt_mod} =  Create Dictionary
    ...  libelle=accepter un dossier sans réserve
    ...  obj_extra_data_req=${evt_req}
    ...  obj_extra_data_tpl=tpl_xd_instr_page
    ...  list_extra_data_req=${evt_req}
    ...  list_extra_data_tpl=tpl_xd_instr_lst
    Modifier l'événement  ${evt_mod}


#Reset params before
#    # Reset de l'option d'affichage des données complémentaires
#    &{param_values} =  Create Dictionary
#    ...  libelle=option_affichage_donnees_complementaires
#    ...  valeur=${EMPTY}
#    ...  om_collectivite=agglo
#    #Gerer le paramètre par WS  ${param_values}
#    Ajouter le paramètre depuis le menu  option_affichage_donnees_complementaires  ${EMPTY}  agglo


Vérification de l'affichage des données complémentaires sur le DI

    # Sans l'option, rien ne doit être affiché
    Depuis le contexte du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires
    Depuis l'instruction du dossier d'instruction  ${di_lib}  accepter un dossier sans réserve
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=fieldset#fieldset-sousform-instruction-donnees-complementaires
    Depuis l'onglet instruction du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=div.soustab-container .tab-listing-container table tr.tab-data td.col-1 a.lienTable span.extended

    # Ajout de l'option d'affichage des données complémentaires pour les dossiers
    &{param_values} =  Create Dictionary
    ...  libelle=option_affichage_donnees_complementaires
    ...  valeur=dossier
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    # Vérification de l'affichage des données complémentaires sur l'onglet du DI
    Depuis le contexte du dossier d'instruction  ${di_lib}
    # Le fieldset "Données complémentaires" doit être affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires
    Element Should Be Visible  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires
    # Le contenu du fieldset doit avoir les données complémentaires définies
    Page Should Contain Element  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires div.fieldsetContent
    Element Should Be Visible  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires div.fieldsetContent
    Element Should Contain  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires div.fieldsetContent
    ...  XD dossier 1: 10
    Element Should Contain  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires div.fieldsetContent
    ...  XD dossier 2: Aucune donnée supplémentaire

    # Avec l'option uniquement active sur les dossiers, les instructions ne doivent pas être impactées
    Depuis l'instruction du dossier d'instruction  ${di_lib}  accepter un dossier sans réserve
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=fieldset#fieldset-sousform-instruction-donnees-complementaires
    Depuis l'onglet instruction du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=div.soustab-container .tab-listing-container table tr.tab-data td.col-1 a.lienTable span.extended

    # Ajout de l'option d'affichage des données complémentaires pour les instructions
    &{param_values} =  Create Dictionary
    ...  libelle=option_affichage_donnees_complementaires
    ...  valeur=instruction
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    # Vérification de l'affichage des données complémentaires sur l'instruction
    Depuis l'instruction du dossier d'instruction  ${di_lib}  accepter un dossier sans réserve
    # Le fieldset "Données complémentaires" doit être affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=fieldset#fieldset-sousform-instruction-donnees-complementaires
    Element Should Be Visible  css=fieldset#fieldset-sousform-instruction-donnees-complementaires
    # Le contenu du fieldset doit avoir les données complémentaires définies
    Page Should Contain Element  css=fieldset#fieldset-sousform-instruction-donnees-complementaires div.fieldsetContent
    Element Should Be Visible  css=fieldset#fieldset-sousform-instruction-donnees-complementaires div.fieldsetContent
    Element Should Contain  css=fieldset#fieldset-sousform-instruction-donnees-complementaires div.fieldsetContent
    ...  XD instruction: 20

    # Vérification de l'affichage des données complémentaires sur le listing des instructions
    Depuis l'onglet instruction du dossier d'instruction  ${di_lib}
    # Le span des données complémentaires doit être affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=div.soustab-container .tab-listing-container table tr.tab-data td.col-1 a.lienTable span.extended
    # Le contenu du span doit avoir les données complémentaires définies
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=div.soustab-container .tab-listing-container table tr.tab-data td.col-1 a.lienTable span.extended
    ...  XD instruction lst: 20

    # Avec l'option uniquement active sur les instructions, les dossiers ne doivent pas être impactées
    Depuis le contexte du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Not Contain Element  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires

    # Ajout de l'option d'affichage des données complémentaires pour les dossiers et les instructions
    &{param_values} =  Create Dictionary
    ...  libelle=option_affichage_donnees_complementaires
    ...  valeur=dossier,instruction
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    # Avec l'option active sur les dossiers et les instructions les deux devraiement être impactés
    Depuis le contexte du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=fieldset#fieldset-form-dossier_instruction-donnees-complementaires
    Depuis l'instruction du dossier d'instruction  ${di_lib}  accepter un dossier sans réserve
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=fieldset#fieldset-sousform-instruction-donnees-complementaires
    Depuis l'onglet instruction du dossier d'instruction  ${di_lib}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Page Should Contain Element  css=div.soustab-container .tab-listing-container table tr.tab-data td.col-1 a.lienTable span.extended

Reset params after

    # Suppression de l'option d'affichage des données complémentaires
    Supprimer le paramètre  option_affichage_donnees_complementaires