*** Settings ***
Documentation  Test des fonctionnalités liées au paramétrage des modèles de rapport d'instruction

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Ajout de modèles de rapport d'instruction
    [Documentation]  Avec un profil Administrateur, depuis le menu Paramétrage > Gestion des dossiers > Modèle de rapport d'instruction,
    ...  ajoute 4 modèles :
    ...   - le 1er ayant comme libellé "Modèle 1" et comme contenu "plop".
    ...   - le 2ème ayant comme libellé "Modèle 2" et comme contenu "plip"
    ...   - le 3ème ayant comme libellé "Modèle 3" et comme contenu "Périmé".
    ...   - le 4ème ayant comme libellé "Modèle 4" et comme contenu "Pas envore valide"

    Depuis la page d'accueil  admin  admin

    # Label de l'option sans modèle
    Set Suite Variable  ${contenu_sans_mod}  Choisir modele

    # Modèle 1
    Set Suite Variable  ${lib_mod_1}  Modèle 1
    Set Suite Variable  ${contenu_mod_1}  plop
    ${params} =  Create Dictionary
    ...  libelle=${lib_mod_1}
    ...  code=1
    ...  contenu_om_html=${contenu_mod_1}
    Ajouter le modele de rapport d'instruction  ${params}

    # Modèle 2
    Set Suite Variable  ${lib_mod_2}  Modèle 2
    Set Suite Variable  ${contenu_mod_2}  plip
    ${params} =  Create Dictionary
    ...  libelle=${lib_mod_2}
    ...  code=2
    ...  contenu_om_html=${contenu_mod_2}
    Ajouter le modele de rapport d'instruction  ${params}

    # Modèle 3
    Set Suite Variable  ${lib_mod_3}  Modèle 3
    ${params} =  Create Dictionary
    ...  libelle=${lib_mod_3}
    ...  code=3
    ...  contenu_om_html=Périmé
    ...  om_validite_debut=01/01/2023
    ...  om_validite_fin=01/02/2023
    Ajouter le modele de rapport d'instruction  ${params}

    # Modèle 4
    Set Suite Variable  ${lib_mod_4}  Modèle 4
    ${params} =  Create Dictionary
    ...  libelle=${lib_mod_3}
    ...  code=3
    ...  contenu_om_html=Pas envore valide
    ...  om_validite_debut=01/01/3000
    Ajouter le modele de rapport d'instruction  ${params}

Utilisation de modèle à l'ajout d'un rapport d'instruction
    [Documentation]  Avec un profil instructeur ou équivalent, depuis le contexte d'un nouveau dossier, accède au formulaire d'ajout
    ...  du rapport d'instruction. Depuis le formulaire d'ajout, lorsque le "Modèle 1" est sélectionné, le texte "plop" s'affiche
    ...  dans le champ analyse réglementaire.
    ...  Ensuite lorsque le modèle est dé-sélectionné, le texte du champs est vidé. En resélectionnant le "Modèle 1"
    ...  le texte s'affiche à nouveau.
    ...  Depuis ce formulaire, les "Modèle 3" et "Modèle 4" ne sont pas accessible en raison de leur date de validité.

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=011_02_parametrage
    ...  particulier_prenom=modele_rapport_instruction
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di}

    Depuis le contexte du rapport d'instruction  ${di}
    # Vérifie que les modèles non valide n'apparaissent pas
    @{modele_non_visible} =  Create List  ${lib_mod_3}  ${lib_mod_4}
    Select List Should Not Contain List  css=#modele  ${modele_non_visible}
    # Sélectionne le modèle voulu et vérifie que le contenu se rempli bien
    Select From List By Label  css=#modele  ${lib_mod_1}
    HTML Should Contain  analyse_reglementaire_om_html  ${contenu_mod_1}
    # Ne sélectionne aucun modèle et vérifie que le contenu est bien supprimé
    Select From List By Label  css=#modele  ${contenu_sans_mod}
    HTML Should Contain  analyse_reglementaire_om_html  ${EMPTY}
    # Sélectionne à nouveau le modèle voulu et vérifie que le contenu se rempli bien
    Select From List By Label  css=#modele  ${lib_mod_1}
    HTML Should Contain  analyse_reglementaire_om_html  ${contenu_mod_1}
    Click On Submit Button In Subform


Utilisation de modèle à la modification d'un rapport d'instruction
    [Documentation]  Avec un profil instructeur ou équivalent, depuis le formulaire de modification d'un rapport d'instruction,
    ...  lorsque le "Modèle 2" est sélectionné, le contenu précédent est supprimé et le tableau contenant plop 2 affiché.
    ...  Lorsque le modèle est dé-sélectionné, le texte du champs est vidé

    Depuis le contexte du rapport d'instruction  ${di}
    Click On SubForm Portlet Action  rapport_instruction  modifier
    # Sélectionne le modèle voulu et vérifie que le contenu se rempli bien
    HTML Should Contain  analyse_reglementaire_om_html  ${contenu_mod_1}
    Select From List By Label  css=#modele  ${lib_mod_2}
    HTML Should Contain  analyse_reglementaire_om_html  ${contenu_mod_2}
    # Vérifie que l'ancien contenu a été effacé
    HTML Should Not Contain  analyse_reglementaire_om_html  ${contenu_mod_1}

    # Ne sélectionne aucun modèle et vérifie que le contenu est bien supprimé
    Select From List By Label  css=#modele  ${contenu_sans_mod}
    HTML Should Contain  analyse_reglementaire_om_html  ${EMPTY}