*** Settings ***
Documentation  Test d'ajout de valeurs dans les données techniques
...    Chaque 'Test Case' est indépendant.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Variables ***

${json_update_dossier_autorisation}    {"module":"update_dossier_autorisation"}

*** Test Cases ***

TNR Description du projet (champ et colonne)

    [Documentation]  Remplissage du cerfa n°2 et contrôle de "description du projet".

    ##
    ## Remplit les champs de donnes techniques suivants : ope_proj_desc, co_projet_desc,
    ## am_projet_desc, dm_projet_desc puis vérifie le bon affichage de ces 4 données dans
    ## la liste des DA, la fiche détaillée des demandes d'avis et DI.
    ## Vérifie que la colonne "nature du projet" a bien été renommée en "description du
    ## projet"
    ##

    Depuis la page d'accueil  guichet  guichet

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=DESFORGES
    ...  particulier_prenom=Hugues

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial

    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}
    ${dossier_autorisation} =  Get Substring  ${di_libelle}  0  -2

    Depuis la page d'accueil  instr  instr

    Ajouter une consultation depuis un dossier  ${di_libelle}  59.07 - Service de l' Espace Public
    &{donnees_techniques_values} =  Create Dictionary
    ...  co_projet_desc=Type de projet co
    ...  ope_proj_desc=Projet d'ope test
    ...  am_projet_desc=Projet d'aménagement and stuff
    ...  dm_projet_desc=détail sur le projet de démolition
    Saisir les données techniques du DI  ${di_libelle}  ${donnees_techniques_values}

    # On vérifie que le détail du DI contient bien les 4 champs des données techniques
    Depuis le contexte du dossier d'instruction  ${di_libelle}
    Element Should Contain  css=#description_projet  Type de projet co
    Element Should Contain  css=#description_projet  Projet d'ope test
    Element Should Contain  css=#description_projet  Projet d'aménagement and stuff
    Element Should Contain  css=#description_projet  détail sur le projet de démolition

    # On récupère le numéro du dossier d'autorisation depuis le numéro du DI
    # Puis on vérifie que le détail du DA contient bien les 4 champs des données techniques
    Depuis le contexte du dossier d'autorisation  ${dossier_autorisation}
    Element Should Contain  css=#description_projet  Type de projet co
    Element Should Contain  css=#description_projet  Projet d'ope test
    Element Should Contain  css=#description_projet  Projet d'aménagement and stuff
    Element Should Contain  css=#description_projet  détail sur le projet de démolition

    # On affiche la liste des Demandes d'Avis, on vérifie que la colonne "nature du projet"
    # soit bien renommée en "description du projet", et que la colonne contienne les 4
    # champs des données techniques.
    Depuis la page d'accueil avec widget de redirection  consu  consu
    ${di_libelle_se} =  Sans espace  ${di_libelle}
    Input Text  css=input.champFormulaire[name='recherche']  ${di_libelle_se}
    Click Element  adv-search-submit
    Element Should Contain  css=#tab-demande_avis_encours  description du projet
    Element Should Contain  css=#tab-demande_avis_encours  Type de projet co
    Element Should Contain  css=#tab-demande_avis_encours  Projet d'ope test
    Element Should Contain  css=#tab-demande_avis_encours  Projet d'aménagement and stuff
    Element Should Contain  css=#tab-demande_avis_encours  détail sur le projet de démolition