*** Settings ***
Documentation  Test des fonctionnalités introduites par le multicollectivité.
...    Chaque 'Test Case' est indépendant.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Variables ***

${json_update_dossier_autorisation}    {"module":"update_dossier_autorisation"}

*** Test Cases ***

Constitution du jeu de données
    [Documentation]  Constitution du jeu de données
    ...    En tant que guichetier
    Depuis la page d'accueil  guichet  guichet
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=DURAND
    ...  particulier_prenom=GÉRARD

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire comprenant ou non des démolitions
    ...  demande_type=Dépôt Initial
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

# Affichage da avis
#     [Documentation]  Test l'affichage des da qui ont une demande d'avis pour
#     ...    le profil Service consulté

# Affichage da di avis
#     [Documentation]  Test l'affichage des da qui ont une demande d'avis pour
#     ...    le profil Admin

Etat perime
    [Documentation]  L'objet de ce 'Test Case' est de vérifier que le WS passe
    ...    à l'état périmé les dossiers d'autorisation remplissant les conditions :
    ...    - état = Accordé
    ...    - avec date de décision
    ...    - date de validité dans le passé
    ...    - aucun DOC ou DAACT avec avis favorable

    Depuis la page d'accueil    instr    instr
    Go To Submenu In Menu    autorisation    dossier_autorisation
    Page Should Not Contain Errors
    Click On Link    PA 013055 12 00001
    Page Title Should Be    Autorisation > Dossiers D'autorisation
    Element Text Should Be    css=#da_etat    Accordé
    Vérifier le code retour du web service et vérifier que son message est    Post    maintenance    ${json_update_dossier_autorisation}    200    2 dossier(s) d'autorisation(s) mis à jour.

    Reload Page
    Element Text Should Be    css=#da_etat    Périmé


TNR Bug "Erreur de base de données" dans la recherche avancée des DA sur le critère date de décision

    [Documentation]    Test de non régression sur le bug "Erreur de base de
    ...    données" sur la validation de la recherche avancée dans le listing
    ...    "Autorisation" -> "Dossiers d'Autorisation" sur le critère "Date de
    ...    décision".

    #
    Depuis la page d'accueil    instr    instr
    #
    Depuis le listing des dossiers d'autorisation
    # On remplit les critères date de décision de la recherche avancée
    Input Text  css=div#adv-search-adv-fields input#date_decision_min  01/05/2015
    Input Text  css=div#adv-search-adv-fields input#date_decision_max  31/05/2015
    # On valide le formulaire de recherche
    Click On Search Button
    # On ne fait aucune vérification ici car le keyword précédent "Click On
    # Search Button" permet de vérifier qu'il n'y a pas d'erreur de base de
    # données

TNR Bug Recalcul du DA si plusieurs DI sans décision

    [Documentation]    Test de non régression sur le bug impactant le recalcul
    ...     du DA si plusieurs DI sans décision

    #
    Depuis la page d'accueil    admin    admin

    @{etats_autorises} =    Create List
    ...    delai majore
    ...    delai de notification envoye
    ...    dossier sans notification de delai

    &{args_demande_type} =  Create Dictionary
    ...    code=TNR Bug Recalcul du DA
    ...    libelle=TNR Bug Recalcul du DA
    ...    groupe=Autorisation ADS
    ...    dossier_autorisation_type_detaille=PCI (Permis de construire pour une maison individuelle et / ou ses annexes)
    ...    demande_nature=Dossier existant
    ...    etats_autorises=@{etats_autorises}
    ...    contraintes=Avec récupération demandeur
    ...    dossier_instruction_type=PCI - Modificatif
    ...    evenement=Notification de delai

    Ajouter un nouveau type de demande depuis le menu    ${args_demande_type}

    Depuis la page d'accueil  guichet  guichet

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=DURAND
    ...  particulier_prenom=Marcel

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    &{args_demande} =  Create Dictionary
    ...  demande_type=TNR Bug Recalcul du DA
    ${di_libelle_2} =  Ajouter la demande sur existant depuis le tableau de bord    ${di_libelle}    ${args_demande}