*** Settings ***
Documentation  Gestion des demandes d'avis.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Constitution du jeu de données

    [Documentation]  Constitue le jeu de données.

    # Date du jour au format : JJ/MM/AAAA
    ${date_jour} =  Date du jour FR
    Set Suite Variable  ${date_jour}


Réponse à une consultation par le service consulté

    [Documentation]

    ##
    ## Constitution du jeu de données
    ##
    #
    # Le dossier di_1 est affecté à l'instructeur "Louis Laurent" (instr) division "H"
    #
    #
    Depuis la page d'accueil  guichet  guichet
    #
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=DUPONT
    ...  particulier_prenom=Jacques
    #
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=12/04/2015
    #
    ${di} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}
    #
    Depuis la page d'accueil  instr  instr
    #
    Ajouter une consultation depuis un dossier  ${di}  59.01 - Direction de l'Eau et de l'Assainissement

    ##
    ## Cas d'usage n°1 :
    ##
    ## Connexion et redirection automatique ver le listing des demandes
    ## d'avis en cours
    ##
    # On se connecte en tant que "consu"
    Depuis la page d'accueil avec widget de redirection  consu  consu
    # On vérifie que nous sommes dans le contexte (listing) "Demande d'avis en cours"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_encours
    Page Title Should Be  Demandes D'avis > En Cours
    First Tab Title Should Be  Demandes D'avis En Cours
    # Le dossier doit apparaître dans ce listing
    Page Should Contain  ${di}

    ##
    ## Cas d'usage n°2 :
    ##
    ## On rend l'avis sans saisir aucune valeur mais le dossier est toujours disponible
    ## dans les demandes d'avis en cours
    ##
    # On clique sur le lien du dossier
    Click On Link  ${di}
    # On vérifie que nous sommes dans le contexte (form) "Demande d'avis en cours"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_encours
    Page Title Should Be  Demandes D'avis > En Cours
    First Tab Title Should Be  Demandes D'avis En Cours
    # On clique sur le lien "Rendre un avis" dans le portlet
    Click On SubForm Portlet Action  demande_avis_encours  rendre_avis
    # On clique sur le bouton "Modifier" du formulaire sans saisir de retour d'avis
    Click On Submit Button In Subform  #sousform-demande_avis_encours
    # On vérifie que le message de validation est présent
    Page Should Contain  Vos modifications ont bien été enregistrées.
    # Retour à la liste des demandes
    Click On Back Button In Subform
    # On vérifie que nous sommes dans le contexte (listing) "Demande d'avis en cours"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_encours
    Page Title Should Be  Demandes D'avis > En Cours
    First Tab Title Should Be  Demandes D'avis En Cours
    # Le dossier doit apparaître dans ce listing
    Page Should Contain  ${di}

    ##
    ## Cas d'usage n°3 :
    ##
    ## On accède au document d'avis au format PDF, on rend l'avis et le
    ## dossier n'est plus disponible dans les demandes d'avis en cours
    ## mais se retrouve dans les demandes d'avis passées
    ##
    # On clique sur le lien du dossier
    Click On Link  ${di}
    # On vérifie que nous sommes dans le contexte (form) "Demande d'avis en cours"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_encours
    Page Title Should Be  Demandes D'avis > En Cours
    First Tab Title Should Be  Demandes D'avis En Cours
    # On clique sur le lien "Edition" dans le portlet
    Click On SubForm Portlet Action  demande_avis_encours  consulter_pdf
    # On ouvre le PDF
    Open PDF  file
    # On vérifie le champ de fusion du di
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di}
    # On ferme le PDF
    Close PDF
    # On clique sur le lien "Rendre un avis" dans le portlet
    Click On SubForm Portlet Action  demande_avis_encours  rendre_avis
    # Saisie des valeurs dans le formulaire
    Select From List By Label  css=select#avis_consultation  Defavorable
    Input Text  css=textarea#motivation  Pas motivé
    Add File  fichier  lettre_rar16042013124515.pdf
    # On clique sur le bouton "Modifier" du formulaire
    Click On Submit Button In Subform  #sousform-demande_avis_encours
    # On vérifie que le message de validation est présent
    Page Should Contain  Vos modifications ont bien été enregistrées.
    # Retour à la liste des demandes
    Click On Back Button In Subform
    # On vérifie que nous sommes dans le contexte (listing) "Demande d'avis en cours"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_encours
    Page Title Should Be  Demandes D'avis > En Cours
    First Tab Title Should Be  Demandes D'avis En Cours
    # Le dossier ne doit pas apparaître dans ce listing
    Page Should Not Contain  ${di}
    # On vérifie que nous sommes dans le contexte (listing) "Demande d'avis passée"
    Go To Submenu In Menu  demande_avis  demande_avis_passee
    Page Title Should Be  Demandes D'avis > Passées
    First Tab Title Should Be  Demandes D'avis Passées
    # Le dossier doit apparaître dans ce listing
    Page Should Contain  ${di}

    ##
    ## Cas d'usage n°4 :
    ##
    ## Une fois l'avis rendu, le dossier n'est plus disponible dans les
    ## demandes d'avis en cours mais se retrouve dans les demandes d'avis
    ## passées. On peut accéder au document d'avis au format PDF. On peut
    ## visualiser l'avis rendu, la motivation et le fichier
    ##
    # On clique sur le lien du dossier
    Click On Link  ${di}
    # On vérifie que nous sommes dans le contexte (listing) "Demande d'avis passée"
    Submenu In Menu Should Be Selected  demande_avis  demande_avis_passee
    Page Title Should Be  Demandes D'avis > Passées
    First Tab Title Should Be  Demandes D'avis Passées
    # On vérifie que les valeurs saisies ont bien été enregistrées
    Element Should Contain  css=#dossier_libelle  ${di}
    Element Should Contain  css=#avis_consultation  Defavorable
    Element Should Contain  css=#motivation  Pas motivé
    Element Should Contain  css=#fichier  consultation_avis
    # On clique sur le lien "Edition" dans le portlet
    Click On SubForm Portlet Action  demande_avis_passee  consulter_pdf
    # On ouvre le PDF
    Open PDF  file
    # On vérifie le champ de fusion du di
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di}
    # On vérifie le libellé du service et le type de consultation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Avis demandé - pour conformité
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Direction de l'Eau et de l'Assainissement
    # On ferme le PDF
    Close PDF
    # Déconnexion spécifique avec l'utilisateur consu
    Se déconnecter avec widget de redirection


Export des demandes d'avis

    [Documentation]

    # On se connecte en tant que "consu"
    S'authentifier avec widget de redirection  consu  consu
    # Télécharge le fichier d'export CSV sur le disque
    Depuis le listing des demandes d'avis exports
    ${link} =  Get Element Attribute  css=div.tab-export a@href
    ${output_dir}  ${output_name} =  Télécharger un fichier  ${SESSION_COOKIE}  ${link}  ${EXECDIR}${/}binary_files${/}
    ${full_path_to_file} =  Catenate  SEPARATOR=  ${output_dir}  ${output_name}
    # On vérifie dans le fichier téléchargé que l'entête correspond à ce qui est attendu
    ${content_file} =  Get File  ${full_path_to_file}
    ${header_csv_file} =  Set Variable  consultation;"date limite";dossier;"description du projet";"adresse du terrain";pétitionaire;surface;service;"type de consultation"
    Should Contain  ${content_file}  ${header_csv_file}
    # Déconnexion spécifique avec l'utilisateur consu
    Se déconnecter avec widget de redirection


Marquer un dossier pour une demande d'avis en cours

    [Documentation]  Créée un dossier, lui ajoute une consultation, puis vérifie qu'en
    ...  tant que profil "consu" marquer et démarquer un dossier est possible. On vérifie
    ...  ensuite l'icone affiché dans le listing des demandes d'avis en cours.

    Depuis la page d'accueil  guichet  guichet
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Leduc
    ...  particulier_prenom=Emmanuel
    #
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=08/04/2016
    #
    ${di} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # Ajout d'une consultation
    Depuis la page d'accueil  instr  instr
    Ajouter une consultation depuis un dossier  ${di}  59.01 - Direction de l'Eau et de l'Assainissement

    Depuis la page d'accueil avec widget de redirection  consu  consu
    Depuis le listing des demandes d'avis en cours
    # On vérifie que le dossier créé est présent
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  tab-demande_avis_encours  ${di}
    # Le dossier doit être non-marqué de base et l'icone correspondant doit être affiché
    Element Should Be Visible  css=span.demarque-16

    Depuis la demande d'avis en cours du dossier  ${di}
    Marquer le dossier
    Depuis le listing des demandes d'avis en cours
    # L'icone "marque" doit être présent
    Element Should Be Visible  css=span.marque-16

    Depuis la demande d'avis en cours du dossier  ${di}
    Dé-marquer le dossier
    Depuis le listing des demandes d'avis en cours
    # L'icone "demarque" doit être présent
    Element Should Be Visible  css=span.demarque-16
    Se déconnecter avec widget de redirection