*** Settings ***
Documentation  Gestion des commissions.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Constitution du jeu de données

    #
    Depuis la page d'accueil  guichet  guichet
    #
    &{args_petitionnaire_1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Archi&Co
    ...  personne_morale_raison_sociale=SA
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=DURAND
    ...  personne_morale_prenom=Jacques
    &{args_petitionnaire_2} =  Create Dictionary
    ...  particulier_nom=BERGER
    ...  particulier_prenom=André
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    #
    ${di_1} =  Ajouter la nouvelle demande  ${args_demande}  ${args_petitionnaire_1}
    ${di_1_id} =  Sans espace  ${di_1}
    Set Suite Variable  ${di_1}
    Set Suite Variable  ${di_1_id}
    #
    ${di_2} =  Ajouter la nouvelle demande  ${args_demande}  ${args_petitionnaire_2}
    ${di_2_id} =  Sans espace  ${di_2}
    Set Suite Variable  ${di_2}
    Set Suite Variable  ${di_2_id}


test_01_ajout_type_commission_administrateur_fonctionnel

    # On se connecte en tant que "admin"
    Depuis la page d'accueil  admin  admin

    # On clique sur le menu de paramétrage
    Go To Submenu In Menu  parametrage  commission-type
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Paramétrage > Gestion Des Commissions > Type De Commission
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Type De Commission
    # On vérifie que le listing des types de commission est présent
    Element Should Be Visible  css=#tab-commission_type table.tab-tab
    # On vérifie que l'action ajouter est disponible
    Element Should Be Visible  css=#action-tab-commission_type-corner-ajouter

    # On clique sur l'action ajouter
    Click On Add Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  parametrage  commission-type
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Paramétrage > Gestion Des Commissions > Type De Commission
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Type De Commission

    # On ajoute les informations du type de commission
    &{args_type_de_commission} =  Create Dictionary
    ...  code=TTDC
    ...  libelle=Test type de commission
    ...  lieu_salle=2a
    ...  listes_de_diffusion=support@atreal.fr
    ...  participants=Atreal
    ...  corps_du_courriel=Test du type de commission
    Saisir type de commission  ${args_type_de_commission}

    # On ajoute le type de commission
    Click On Submit Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  parametrage  commission-type
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Paramétrage > Gestion Des Commissions > Type De Commission
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Type De Commission
    # Vérification du message de validation
    Valid Message Should Be  Vos modifications ont bien été enregistrées.

    # On retourne sur le tableau listant les types de commission
    Click On Back Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  parametrage  commission-type
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Paramétrage > Gestion Des Commissions > Type De Commission
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Type De Commission
    # On vérifie que le listing des types de commission est présent
    Element Should Be Visible  css=#tab-commission_type table.tab-tab

    # On vérifie que le type de commission nouvellement créé avec les informations
    # ci-dessus existe bien
    Use Simple Search  libellé  Test type de commission
    Element Should Contain  css=#tab-commission_type table.tab-tab tbody  TTDC


test_02_ajout_demande_de_passage_instructeur

    # On se connecte en tant que "instr"
    Depuis la page d'accueil  instr  instr
    #
    Depuis l'onglet commission(s) du dossier d'instruction  ${di_1}
    # On vérifie que l'action ajouter est disponible
    Element Should Be Visible  css=#action-soustab-dossier_commission-corner-ajouter

    # On clique sur l'action ajouter
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=#action-soustab-dossier_commission-corner-ajouter
    # On vérifie que la date du jour est pré-remplie dans le champs "date souhaitée"
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#sformulaire #date_souhaitee  ${DATE_FORMAT_DD/MM/YYYY}

    # On clique sur le bouton "Ajouter" du formulaire sans sélectionner de type de commission
    Click On Submit Button In Subform
    # On vérifie que le message d'erreur est présent
    Error Message Should Contain In Subform  Le champ type de commission est obligatoire
    Error Message Should Contain In Subform  SAISIE NON ENREGISTRÉE

    # On ajoute les informations de la demande de passage
    &{args_dossier_commission} =  Create Dictionary
    ...  commission_type=Test type de commission
    ...  motivation=blablablabla
    Saisir la demande de passage en commission  ${args_dossier_commission}

    # On clique sur le bouton "Ajouter" du formulaire avec toutes les informations saisies
    Click On Submit Button In Subform
    # On vérifie que le message de validation est présent
    Valid Message Should Be In Subform  Vos modifications ont bien été enregistrées.

    # On clique sur le bouton retour
    Click On Back Button In Subform
    # On vérifie que nous avons bien la consultation affichée
    Element Should Contain  css=#sousform-dossier_commission  Test type de commission


test_03_creation_commission_cellule_suivi

    # On se connecte en tant que "suivi"
    Depuis la page d'accueil  suivi  suivi

    # On clique sur l'entrée de menu "Suivi -> Commissions -> Gestion"
    Go To Submenu In Menu  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission
    # On vérifie que le listing est présent
    Element Should Be Visible  css=#tab-commission table.tab-tab
    # On vérifie que l'action ajouter est disponible
    Element Should Be Visible  css=#action-tab-commission-corner-ajouter

    # On clique sur le bouton d'ajout de commission
    Click On Add Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission
    # On vérifie que la date du jour est pré-remplie dans le champs "date"
    Form Value Should Be  css=#date_commission  ${DATE_FORMAT_DD/MM/YYYY}

    # On clique sur le bouton "Ajouter" du formulaire sans sélectionner de type de commission
    Click On Submit Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission
    # On vérifie que le message d'erreur est présent
    Error Message Should Contain  Le champ type de commission est obligatoire
    Error Message Should Contain  SAISIE NON ENREGISTRÉE

    # On choisit un type de commission
    Select From List By Label  css=#commission_type  Test type de commission
    # On vérifie que les informations du type de commision sélectionnées sont bien
    # dans les champs
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#libelle  Test type de commission
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#lieu_salle  2a
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#listes_de_diffusion  support@atreal.fr
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#participants  Atreal
    # Aucune adresse n'avait été saisie dans le champ concernant l'adresse
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Value Should Be  css=#lieu_adresse_ligne1  ${EMPTY}

    # Saisie d'une adresse
    &{args_commission} =  Create Dictionary
    ...  lieu_adresse_ligne1=1 boulevard de la république
    ...  heure_commission=15:00
    Saisir la commission  ${args_commission}

    # On ajoute la commission
    Click On Submit Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission
    # On vérifie que le message de validation est présent
    Valid Message Should Be  Vos modifications ont bien été enregistrées.

    # On retourne sur le tableau listant les commissions
    Click On Back Button
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission

    # On vérifie que la commission nouvellement avec les informations ci-dessus
    # existe bien
    Element Should Contain  css=#tab-commission  1 boulevard de la république


test_04_preparation_commission_cellule_suivi

    # On se connecte en tant que "suivi"
    Depuis la page d'accueil  suivi  suivi

    ## Vérification de la fiche de visualisation d'une commission
    # On se positionne sur l'écran de gestion de la commission
    Depuis le contexte de la commission  TTDC${DATE_FORMAT_YYYYMMDD}
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission

    ## Aucun dossier n'est planifié à la commission
    On clique sur l'onglet  dossier_planifie  Les Dossiers Planifiés
    Element Should Contain  css=#sousform-dossier_commission .pagination-text  1 - 0 enregistrement(s) sur 0

    ## Planification d'une demande existante à la commission
    On clique sur l'onglet  commission_dossiers_planifier_retirer  Planifier/retirer Des Dossiers
    # On sélectionne la demande de passage
    Select Checkbox  css=tr#dossier_commission-${di_1_id} input[type='checkbox']
    # On valide le formulaire
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click Element  css=#ui-tabs-2 div.formControls input[type="submit"]
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Be Visible  css=#ui-tabs-2 div.message
    Page Should Not Contain Errors
    # On vérifie que le formulaire s'est bien validé
    Element Should Contain  css=#ui-tabs-2 .message .text  Mise à jour de la planification effectuée.

    ## Un dossier est planifié à la commission
    On clique sur l'onglet  dossier_planifie  Les Dossiers Planifiés
    Element Should Contain  css=#sousform-dossier_commission .pagination-text  1 - 1 enregistrement(s) sur 1

    ##
    On clique sur l'onglet  commission_dossiers_planifier_numero  Planifier Un Dossier Spécifique
    #
    Input Text  css=#dossier  ${di_2_id}
    # On valide le formulaire
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click Element  css=#ui-tabs-3 div.formControls input[type="submit"]
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Be Visible  css=#ui-tabs-3 div.message
    Page Should Not Contain Errors
    # On vérifie que le formulaire s'est bien validé
    Element Should Contain  css=#ui-tabs-3 .message .text  Dossier ajouté avec succès.

    ## Deux dossiers sont planifiés à la commission
    On clique sur l'onglet  dossier_planifie  Les Dossiers Planifiés
    Element Should Contain  css=#sousform-dossier_commission .pagination-text  1 - 2 enregistrement(s) sur 2

    ##
    On clique sur l'onglet  commission_dossiers_planifier_numero  Planifier Un Dossier Spécifique
    #
    Input Text  css=#dossier  ${di_2_id}
    # On valide le formulaire
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click Element  css=#ui-tabs-3 div.formControls input[type="submit"]
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Be Visible  css=#ui-tabs-3 div.message
    Page Should Not Contain Errors
    # On vérifie que le formulaire s'est bien validé
    Element Should Contain  css=#ui-tabs-3 .message .text  Ce dossier est déjà à l'ordre du jour.

    ##
    Click On Form Portlet Action  commission  edition_ordre_jour
    # On ouvre le PDF
    Open PDF  form
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ORDRE DU JOUR
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  blablablabla
    # On ferme le PDF
    Close PDF

    ## Planification d'une demande existante à la commission
    On clique sur l'onglet  commission_dossiers_planifier_retirer  Planifier/retirer Des Dossiers
    # On sélectionne la demande de passage
    Unselect Checkbox  css=tr#dossier_commission-${di_2_id} input[type='checkbox']
    # On valide le formulaire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=#ui-tabs-2 div.formControls input[type="submit"]
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#ui-tabs-2 div.message
    Page Should Not Contain Errors
    # On vérifie que le formulaire s'est bien validé
    Element Should Contain  css=#ui-tabs-2 .message .text  Mise à jour de la planification effectuée.

    ## Un dossier est planifié à la commission
    On clique sur l'onglet  dossier_planifie  Les Dossiers Planifiés
    Element Should Contain  css=#sousform-dossier_commission .pagination-text  1 - 1 enregistrement(s) sur 1


    ## La motivation doit apparaître sur la proposition d'ordre du jour
    Click On Form Portlet Action  commission  edition_proposition_ordre_jour
    # On ouvre le PDF
    Open PDF  form
    # On vérifie le contenu du pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ORDRE DU JOUR
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  blablablabla
    # On ferme le PDF
    Close PDF

    ##
    Click On Form Portlet Action  commission  edition_ordre_jour
    # On ouvre le PDF
    Open PDF  form
    # On vérifie le contenu du pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ORDRE DU JOUR
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  blablablabla
    # On ferme le PDF
    Close PDF

    ##
    Click On Form Portlet Action  commission  diffuser_ordre_jour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Be  La diffusion de l'ordre du jour s'est effectuée avec succès.
    ${uid_odj}    Get Value    css=#om_fichier_commission_ordre_jour
    ##
    Click On Form Portlet Action  commission  edition_ordre_jour
    # On ouvre le PDF
    Open PDF  file
    # On vérifie le contenu du pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ORDRE DU JOUR
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  blablablabla
    # On ferme le PDF
    Close PDF

    # On vérifie que le l'ordre du jour est mis à jour apres redifusion
    Click On Form Portlet Action  commission  diffuser_ordre_jour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Be  La diffusion de l'ordre du jour s'est effectuée avec succès.
    ${uid_odj_2}    Get Value    css=#om_fichier_commission_ordre_jour
    Should Be Equal    ${uid_odj}    ${uid_odj_2}


test_05_saisie_des_avis_par_la_cellule_suivi

    # On se connecte en tant que "suivi"
    Depuis la page d'accueil  suivi  suivi

    ## Vérification de la fiche de visualisation d'une commission
    # On se positionne sur l'écran de gestion de la commission
    Depuis le contexte de la commission  TTDC${DATE_FORMAT_YYYYMMDD}
    # On vérifie que le menu est ouvert sur l'élément correct
    Submenu In Menu Should Be Selected  suivi  commissions
    # On vérifie que le titre de la page est cohérent
    Page Title Should Be  Suivi > Commissions > Gestion
    # On vérifie que le titre de l'onglet est cohérent
    First Tab Title Should Be  Commission

    ##
    # Affichage en visualisation du dossier qui est passé en commission
    Click Link  ${di_1}
    # On saisie le retour
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Input Text  css=textarea#avis  AVISTESTFavorable
    # Validation du formulaire
    Click On Submit Button In Subform
    # La modification a bien été prise en compte
    Valid Message Should Be In Subform  Vos modifications ont bien été enregistrées.

    ##
    Click On Form Portlet Action  commission  edition_compte_rendu
    # On ouvre le PDF
    Open PDF  form
    # On vérifie le contenu du pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  COMPTE RENDU
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  AVISTESTFavorable
    # On ferme le PDF
    Close PDF

    ##
    Click On Form Portlet Action  commission  diffuser_compte_rendu
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Be  La diffusion du compte-rendu s'est effectuée avec succès.
    ${uid_cr}    Get Value    css=#om_fichier_commission_compte_rendu
    ##
    Click On Form Portlet Action  commission  edition_compte_rendu
    # On ouvre le PDF
    Open PDF  file
    # On vérifie le contenu du pdf
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  COMPTE RENDU
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_2}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  AVISTESTFavorable
    # On ferme le PDF
    Close PDF

    # On vérifie que le compte rendu est mis à jour apres redifusion
    Click On Form Portlet Action  commission  diffuser_compte_rendu
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Be  La diffusion du compte-rendu s'est effectuée avec succès.
    ${uid_cr_2}    Get Value    css=#om_fichier_commission_compte_rendu
    Should Be Equal    ${uid_cr}    ${uid_cr_2}


test_06_gestion_du_retour_de_commission_par_l_instructeur

    # On se connecte en tant que "instr"
    Depuis la page d'accueil  instr  instr

    # On verifie le message du widget
    Element Should Contain  css=#dashboard  Vous avez 1 demande de passage en commission pour laquelle un avis a été rendu.

    # On clique sur le lien du widget
    Click Link  Voir mes retours de commission
    Page Should Not Contain Errors

    # On accède au listing des retours de commission
    Element Should Contain  css=#tab-commission_mes_retours  AVISTESTFavorable
    # On clique sur le retour du dossier
    Click Link  ${di_1}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Portlet Action Should Be In SubForm  dossier_commission  lu
    Page Should Not Contain Errors

    # On marque comme lu
    Click On SubForm Portlet Action  dossier_commission  lu
    Element Should Contain  css=#sousform-dossier_commission  Mise a jour effectue avec succes
    Element Should Contain  css=#lu  Oui

    # Retour sur le tableau de bord
    Depuis la page d'accueil  instr  instr
    # On vérifie le tableau de bord
    Element Should Contain  css=#dashboard  Vous n'avez aucune demande de passage en commission pour laquelle un avis a été rendu.


TNR Vérifie que les fichiers sont supprimés à la suppression de la commission

    [Documentation]  Vérifie dans le filestorage si les fichiers des éditions de
    ...  la commisson sont correctement supprimés lors de la suppression de la
    ...  commission.

    Depuis la page d'accueil  admin  admin
    #
    Depuis le contexte de la commission  TTDC${DATE_FORMAT_YYYYMMDD}
    # On diffuse l'ordre du jour et le compte rendu
    Click On Form Portlet Action    commission    diffuser_ordre_jour
    Click On Form Portlet Action    commission    diffuser_compte_rendu
    # Récupération de l'uid de l'ordre du jour
    Depuis le contexte de la commission  TTDC${DATE_FORMAT_YYYYMMDD}
    ${oj_uid} =  Get Value  om_fichier_commission_ordre_jour
    ${oj_path_1} =  Get Substring  ${oj_uid}  0  2
    ${oj_path_2} =  Get Substring  ${oj_uid}  0  4
    # Vérification dans le filestorage des fichier de l'OJ
    File Should Exist  ..${/}var${/}filestorage${/}${oj_path_1}${/}${oj_path_2}${/}${oj_uid}
    File Should Exist  ..${/}var${/}filestorage${/}${oj_path_1}${/}${oj_path_2}${/}${oj_uid}.info
    # Récupération de l'uid du compte rendu
    ${cr_uid} =  Get Value  om_fichier_commission_compte_rendu
    ${cr_path_1} =  Get Substring  ${cr_uid}  0  2
    ${cr_path_2} =  Get Substring  ${cr_uid}  0  4
    # Vérification dans le filestorage des fichiers du CR
    File Should Exist  ..${/}var${/}filestorage${/}${cr_path_1}${/}${cr_path_2}${/}${cr_uid}
    File Should Exist  ..${/}var${/}filestorage${/}${cr_path_1}${/}${cr_path_2}${/}${cr_uid}.info
    #
    Supprimer la demande de commission depuis le contexte du dossier d'instruction  ${di_1}  Test type de commission
    #
    Supprimer le suivi de la commission  TTDC${DATE_FORMAT_YYYYMMDD}
    # Vérification dans le filestorage des fichier de l'OJ
    File Should Not Exist  ..${/}var${/}filestorage${/}${oj_path_1}${/}${oj_path_2}${/}${oj_uid}
    File Should Not Exist  ..${/}var${/}filestorage${/}${oj_path_1}${/}${oj_path_2}${/}${oj_uid}.info
    # Vérification dans le filestorage des fichiers du CR
    File Should Not Exist  ..${/}var${/}filestorage${/}${cr_path_1}${/}${cr_path_2}${/}${cr_uid}
    File Should Not Exist  ..${/}var${/}filestorage${/}${cr_path_1}${/}${cr_path_2}${/}${cr_uid}.info