*** Settings ***
Documentation  Test la taxe d'aménagement.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin


*** Test Cases ***
Paramétrage de la taxe d'aménagement

    [Documentation]  Paramètre la taxe d'aménagement des collectivités.

    Ajouter la taxe d'aménagement  MARSEILLE


Ajout de la demande avec secteur sélectionné automatiquement

    [Documentation]  Ajoute une demande lorsque la taxe d'aménagement est
    ...  paramétrée avec un seul secteur.

    #
    Depuis la page d'accueil  guichet  guichet
    #
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=De Riv
    ...  particulier_prenom=Géralt

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ${di} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di}
    # On clique sur le lien vers le DI du message de validation
    Click Link  css=#link_demande_dossier_instruction
    # On vérifie le fil d'Ariane
    Page Title Should Be    Instruction > Dossiers D'instruction > ${di} DE RIV GÉRALT
    # On déplie le fieldset de la taxe d'aménagement
    Open Fieldset    dossier_instruction    taxe-d_amenagement
    # On vérifie que le secteur 1 est sélectionné
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Contain    css=#tax_secteur    Secteur 1


Modification des données techniques du dossier d'instruction

    [Documentation]  Modifie les données techniques du dossier d'instruction
    ...  relancer le calcul automatique des taxes.

    #
    Depuis la page d'accueil  admin  admin
    #
    Modifier les données techniques pour le calcul des impositions  ${di}  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10  10
    # On clique sur le bouton retour
    Click On Back Button In Subform
    #
    Depuis le contexte du dossier d'instruction  ${di}
    # On déplie le fieldset de la taxe d'aménagement
    Open Fieldset    dossier_instruction    taxe-d_amenagement
    # Vérifie les montants
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Contain    css=#tax_secteur    Secteur 1
    Element Should Contain    css=#tax_mtn_part_commu    2349
    Element Should Contain    css=#tax_mtn_part_depart    4699
    Element Should Contain    css=#tax_mtn_total    7049


Modification du secteur du dossier d'instruction

    [Documentation]  Modifie le secteur du dossier d'instruction pour relancer
    ...  le calcul automatique des taxes.

    #
    Modifier la taxe d'aménagement  MARSEILLE  null  null  null  null  null  null  null  null  null  null  null  2
    #
    Modifier le dossier d'instruction  ${di}  null  null  Secteur 2
    #
    Depuis le contexte du dossier d'instruction  ${di}
    # On déplie le fieldset de la taxe d'aménagement
    Open Fieldset    dossier_instruction    taxe-d_amenagement
    # On vérifie que le secteur 2 est sélectionné
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Contain    css=#tax_secteur    Secteur 2
    # Vérifie les montants
    Element Should Contain    css=#tax_mtn_part_commu    4699
    Element Should Contain    css=#tax_mtn_part_depart    4699
    Element Should Contain    css=#tax_mtn_total    9399


Vérification du montant liquidé de la part régionale

    [Documentation]  Si la commune se situe en Île-de-France, le dossier
    ...  d'instruction est soumis à une taxe en plus, la part régionale.

    #
    Modifier la taxe d'aménagement  MARSEILLE  true  null  null  null  null  null  null  null  null  0.25
    #
    Depuis le contexte du dossier d'instruction  ${di}
    Click On Form Portlet Action    dossier_instruction    donnees_techniques
    # On clique sur l'action modifier
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click On SubForm Portlet Action  donnees_techniques  modifier
    # On valide le formulaire
    Click On Submit Button In Subform
    # On vérifie le message affiché à l'utilisateur
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Valid Message Should Be  Vos modifications ont bien été enregistrées.
    # On clique sur le bouton retour
    Click On Back Button In Subform
    #
    Depuis le contexte du dossier d'instruction  ${di}
    # On déplie le fieldset de la taxe d'aménagement
    Open Fieldset    dossier_instruction    taxe-d_amenagement
    # On vérifie que le montant de la taxe régionale existe
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Contain    css=#tax_mtn_part_reg    587
    # On vérifie le montant total qui doit être modifié
    Element Should Contain    css=#tax_mtn_total    9986