*** Settings ***
Documentation  Test les pièces.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Test Cases ***
Constitution d'un jeu de données

    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...  données cohérent pour les scénarios fonctionnels qui suivent.

    #
    Depuis la page d'accueil  guichet  guichet
    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Rivière
    ...  particulier_prenom=Coralie
    #
    ${di} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # Liste des arguments pour la demande
    &{args_demande_at} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Demande d'autorisation de construire, d'aménager ou de modifier un ERP
    ...  demande_type=Dépôt Initial
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire_at} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Duplanty
    ...  particulier_prenom=Dominic
    #
    ${di_at} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande_at}  ${args_petitionnaire_at}

    #
    Depuis la page d'accueil  instr  instr
    #
    Ajouter une consultation depuis un dossier  ${di}  59.13 - Régie des Tranports de Marseille - DTP/CIP

    # Les dossiers sont accessibles dans la suite du test
    Set Suite Variable  ${di}
    Set Suite Variable  ${di_at}


Ajout d'une pièce

    [Documentation]  Ajoute une pièce. Vérifie l'unicité des pièces et ajoute une pièce
    ...  sur une dossier AT pour vérifier l'envoi ERP.

    # Données de la pièce
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=15/09/2015
    ...  document_numerise_type=autres pièces composant le dossier (A0)
    #
    Depuis la page d'accueil  instr  instr
    #
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}
    # On ajoute la même pièce pour vérifier le message d'erreur, car une pièce
    # doit être unique
    Ajouter une pièce depuis le dossier d'instruction  ${di}  ${document_numerise_values}  Les valeurs saisies dans les champs dossier, Nom du fichier existent déjà, veuillez saisir de nouvelles valeurs.
    # On ajoute une pièce sur un AT pour vérifier la transmission ERP
    # Ajouter une pièce depuis le dossier d'instruction  ${di_at}  ${document_numerise_values}  Le message a été transmis au référentiel ERP.


Modification d'une pièce

    [Documentation]  Modifie une pièce et vérifie que son nom est régénéré.

    # Données de la pièce
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel2.pdf
    ...  date_creation=20/09/2015
    #
    Depuis la page d'accueil  divi  divi
    #
    Modifier une pièce depuis le dossier d'instruction  ${di}  autres pièces composant le dossier (A0)  ${document_numerise_values}
    #
    Depuis la page d'accueil  instr  instr
    #
    Depuis le contexte du dossier d'instruction de mes encours  ${di}
    On clique sur l'onglet  document_numerise  Pièce(s)
    # On clique pour visualiser le document, le nom doit avoir été modifié par
    # rapport à la date
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=tr.col3 td.firstcol a.lienTable span.reqmo-16
    Open PDF  file
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Page Should Contain  TEST IMPORT MANUEL 2
    # On ferme le PDF
    Close PDF


Vérification de l'affichage sur le dossier d'autorisation

    [Documentation]  Vérifie l'affichage sur les dossiers d'autorisation.

    # On récupère le numéro du dossier d'autorisation depuis le numéro du DI
    ${dossier_autorisation} =  Get Substring  ${di}  0  -2
    #
    Depuis la page d'accueil  guichet  guichet
    #
    Depuis l'onglet des pièces du dossier d'autorisation  ${dossier_autorisation}
    # On vérifie que le numéro du dossier d'instruction est affiché
    Page Should Contain  ${di}
    # On vérifie que le nom du fichier est affiché
    Page Should Contain  20150920AUTPDG.pdf
    # On clique pour visualiser le document
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=tr.col4 td.col-1 a.lienTable span.reqmo-16
    Open PDF  file
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Page Should Contain  TEST IMPORT MANUEL 2
    # On ferme le PDF
    Close PDF


Vérification de l'affichage sur la demande d'avis

    [Documentation]  Vérifie l'affichage sur les demandes d'avis.

    #
    Depuis la page d'accueil avec widget de redirection  consu  consu
    #
    Depuis l'onglet des pièces de la demande d'avis en cours du dossier d'instruction  ${di}
    # On vérifie que le nom du fichier est affiché
    Page Should Contain  20150920AUTPDG.pdf
    # On clique pour visualiser le document
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=tr.col3 td.firstcol a.lienTable span.reqmo-16
    Open PDF  file
    # On vérifie la localisation du terrain
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Page Should Contain  TEST IMPORT MANUEL 2
    # On ferme le PDF
    Close PDF
    #
    Se déconnecter avec widget de redirection


Suppression d'une pièce

    [Documentation]  Supprime une pièce.

    #
    Depuis la page d'accueil  chef  chef
    #
    Supprimer une pièce depuis le dossier d'instruction  ${di}  autres pièces composant le dossier (A0)


TNR Ajout de pièces au DI en tant qu'instructeur

    [Documentation]  L'utilisation d'un getval faisait qu'un dossier au hasard était
    ...  récupéré lors de l'ajout de pièces, quand ce dossier était clôturé l'ajout de
    ...  pièces produisait une erreur de droits insuffisants pour les instructeurs.

    # On crée une nouvelle demande pour le TNR
    Depuis la page d'accueil  guichet  guichet
        &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Riel
    ...  particulier_prenom=Sébastien

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # Le bug provenait du fait que l'on instanciait à tort le premier document
    # numérisé créé en base de données. Celui-ci est lié au AZ 013055 12 00001P0.
    # Ainsi on testait toujours ce DI pour savoir s'il était clôturé et donc si
    # on avait le droit ou non d'ajouter une pièce.
    Depuis la page d'accueil  instrpoly  instrpoly
    Ajouter une instruction au DI  AZ 013055 12 00001P0  ARRÊTÉ DE REFUS
    Click On Back Button In Subform
     # En cloturant le AZ 013055 12 00001P0 on reproduit le use case.
    Click On Link  ARRÊTÉ DE REFUS
    Click On SubForm Portlet Action  instruction  finaliser
    Click On SubForm Portlet Action  instruction  definaliser
    Click On SubForm Portlet Action  instruction  modifier
    ${today} =  Date du jour FR
    Input Datepicker  date_retour_rar  ${today}
    Click On Submit Button In Subform

    # On teste l'ajout de pièces sur le DI de test en tant qu'instructeur
    # Cela doit fonctionner bien que le AZ 013055 12 00001P0 soit clôturé
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=15/09/2015
    ...  document_numerise_type=autres pièces composant le dossier (A0)
    Ajouter une pièce depuis le dossier d'instruction  ${di_libelle}  ${document_numerise_values}

    # On supprime les événements d'instruction créés spécifiquement pour le TNR
    Depuis la page d'accueil  admin  admin
    Supprimer l'instruction  AZ 013055 12 00001P0  Arrêté de Refus signé
    Supprimer l'instruction  AZ 013055 12 00001P0  ARRÊTÉ DE REFUS