*** Settings ***
Documentation  Test des évènements d'instruction.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin


*** Test Cases ***
Finalisation
    [Documentation]  L'objet de ce 'Test Case' est de vérifier le log de
    ...    l'utilisateur qui a finalisé l'évènement.

    # Constitution du jeu de données : deux utilisateurs dont un est instructeur
    # car si tel est le cas son nom d'instructeur surcharge son nom d'utilisateur.
    # En tant qu'administrateur
    Depuis la page d'accueil  admin  admin
    # Donnée 1/3 : guichetier
    Ajouter l'utilisateur depuis le menu  Margand Joanna  support@atreal.fr  guimars  guimars  GUICHET UNIQUE
    # Donnée 2/3 : instructeur
    Ajouter l'utilisateur depuis le menu  Marois Alain -UTIL-  support@atreal.fr  instrmars  instrmars  INSTRUCTEUR
    Ajouter l'instructeur depuis le menu  Marois Alain -INSTR-  subdivision H  Marois Alain -UTIL-
    # Donnée 3/3 : affectation automatique du nouvel instructeur
    Ajouter l'affectation depuis le menu  Marois Alain -INSTR-

    # En tant que guichetier
    Depuis la page d'accueil  guimars  guimars
    # On crée une nouvelle demande via le tableau de bord
    ${di_libelle} =  Ajouter la nouvelle demande depuis le tableau de bord  Permis de construire pour une maison individuelle et / ou ses annexes  Dépôt Initial  Perrault  Sophie
    # En tant qu'instructeur de Martigues
    Depuis la page d'accueil  instrmars  instrmars
    # On ouvre l'onglet instruction du nouveau DI
    Depuis l'onglet instruction du dossier d'instruction  ${di_libelle}
    # On accède à l'instruction
    Click On Link  Notification du delai legal maison individuelle
    # On vérifie qu'elle a été finalisée par le guichetier automatiquement
    # lors de la création
    Wait Until Element Is Visible  om_final_instruction_utilisateur
    Element Text Should Be  om_final_instruction_utilisateur  guimars (Margand Joanna)
    # On reprend la rédaction
    Click On SubForm Portlet Action  instruction  definaliser
    # On vérifie qu'il n'y a pas le champ "finalisé par"
    Element Should Not Be Visible  om_final_instruction_utilisateur
    # On finalise
    Click On SubForm Portlet Action  instruction  finaliser
    # On vérifie le log
    Wait Until Element Is Visible  om_final_instruction_utilisateur
    Element Text Should Be  om_final_instruction_utilisateur  instrmars (Marois Alain -INSTR-)