*** Settings ***
Documentation  Actions spécifiques aux instructions.

*** Keywords ***
Ouvrir la bible du complément d'instruction n°
    [Arguments]  ${numero_complement}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=a[onclick^="bible(${numero_complement});"]

Ajout automatique de complément(s) d'instruction
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=a[onclick^="bible_auto();"]

Ajouter une instruction au DI
    [Arguments]  ${di}  ${evenement}  ${date_evenement}=null

    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  action-soustab-instruction-corner-ajouter
    Saisir instruction  ${evenement}  ${date_evenement}
    Click On Submit Button In Subform
    Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.

Ajouter une instruction au DI et la finaliser
    [Arguments]  ${di}  ${evenement}  ${date_evenement}=null

    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  action-soustab-instruction-corner-ajouter
    Saisir instruction  ${evenement}  ${date_evenement}
    Click On Submit Button In Subform
    Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.
    Click On Back Button In Subform
    Click On Link  ${evenement}
    Click On SubForm Portlet Action  instruction  finaliser


Saisir instruction
    [Arguments]  ${evenement}=null  ${date_evenement}=null

    Wait Until Element Is Visible  evenement
    # On sélectionne l'événement, avec utilisation de doubles quotes pour que
    # les événements contenant une apostrophe ne fassent pas bug
    Run Keyword If  "${evenement}" != "null"  Select From List By Label  evenement  ${evenement}
    # On saisit la date
    Run Keyword If  "${date_evenement}" != "null"  Input Text  date_evenement  ${date_evenement}

Depuis l'instruction du dossier d'instruction

    [Documentation]  Permet d'accéder à la fiche de l'instruction du dossier
    ...  d'instruction.

    [Arguments]  ${dossier_instruction}  ${instruction}

    Depuis l'onglet instruction du dossier d'instruction  ${dossier_instruction}
    # On clique sur l'instruction
    Click On Link  ${instruction}

Supprimer l'instruction
    [Arguments]  ${di}  ${libelle}

    Depuis l'instruction du dossier d'instruction  ${di}  ${libelle}
    # On clique sur l'action modifier
    Click On SubForm Portlet Action  instruction  supprimer
    # On valide
    Click On Submit Button In Subform
    # Vérification qu'il n'y a aucune erreur
    Page Should Not Contain Errors
    # On vérifie le message de validation
    Valid Message Should Contain  La suppression a été correctement effectuée.


Récupérer le code barres de l'instruction
    [Arguments]  ${di}  ${libelle}

    Depuis l'instruction du dossier d'instruction  ${di}  ${libelle}
    ${instruction} =  Get Text  css=.form-content #instruction
    ${code_barres} =  STR_PAD_LEFT  ${instruction}  10  0
    ${code_barres} =  Catenate  11${code_barres}

    [Return]  ${code_barres}