*** Settings ***
Documentation  Actions spécifiques aux événements d'instruction.

*** Keywords ***
Depuis le tableau des événements
    [Documentation]  Permet d'accéder au listing des événements.

    # On ouvre le tableau
    Go To Tab  evenement

Saisir l'événement
    [Arguments]  ${form_values}

    # On saisit le libellé (obligatoire)
    Input Text  libelle  ${form_values.libelle}

    # autres champs (optionels)
    Si "type" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "etats_depuis_lequel_l_evenement_est_disponible" existe dans "${form_values}" on execute "Select Multiple By Label" dans le formulaire
    Si "dossier_instruction_type" existe dans "${form_values}" on execute "Select Multiple By Label" dans le formulaire
    Si "action" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "etat" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "lettretype" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "evenement_retour_ar" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "phase" existe dans "${form_values}" on execute "Select From List By Label" dans le formulaire
    Si "restriction" existe dans "${form_values}" on execute "Input Text" dans le formulaire


Ajouter l'événement depuis le menu
    [Arguments]  ${form_values}

    # On ouvre le tableau des événements
    Depuis le tableau des événements
    # On clique sur l'icone ajouter
    Click On Add Button
    # On remplit le formulaire
    Saisir l'événement  ${form_values}
    # On valide
    Click On Submit Button
    # Vérification qu'il n'y a aucune erreur
    Page Should Not Contain Errors
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Depuis le contexte de l'événement
    [Documentation]  Permet d'accéder au formulaire en consultation
    ...    d'un événement.
    [Arguments]  ${libelle}

    # On ouvre le tableau des événements
    Depuis le tableau des événements
    # On recherche l'événement
    Use Simple Search  libellé  ${libelle}
    # On clique sur l'événement
    Click On Link  ${libelle}

Modifier l'événement
    [Arguments]  ${form_values}

    # On accède à la fiche de l'événement
    Depuis le contexte de l'événement  ${form_values.libelle}
    # On clique sur l'action modifier
    Click On Form Portlet Action  evenement  modifier
    # On remplit le formulaire
    Saisir l'événement  ${form_values}
    # On valide
    Click On Submit Button
    # Vérification qu'il n'y a aucune erreur
    Page Should Not Contain Errors
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Saisir l'action
    [Arguments]  ${form_values}

    ${items}=  Get Dictionary Items  ${form_values}
    :FOR  ${key}  ${value}  IN  @{items}
    \  Input Text  ${key}  ${value}


Ajouter l'action depuis le menu
    [Arguments]  ${form_values}

    # On ouvre le tableau des événements
    Depuis le tableau des actions
    # On clique sur l'icone ajouter
    Click On Add Button
    # On remplit le formulaire
    Saisir l'action  ${form_values}
    # On valide
    Click On Submit Button
    # Vérification qu'il n'y a aucune erreur
    Page Should Not Contain Errors
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Depuis le tableau des actions
    [Documentation]  Permet d'accéder au listing des événements.

    # On ouvre le tableau
    Go To Tab  action