*** Settings ***
Documentation    Test le fonctionnement des écrans du menu Paramétrage Dossiers > Dossiers > Enjeu
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown


*** Test Cases ***
Formulaire
    [Documentation]  Avec un profil administrateur, accède au formulaire de modification
    ...  d'un enjeu et test :
    ...   - l'absence d'erreur à l'affichage des formulaires
    ...   - la gestion des champs obligatoires
    ...   - la validation et l'enregistrement des données

    Depuis la page d'accueil  admin  admin
    
    # Test du formulaire d'ajout d'un enjeu
    @{om_collectivite} =  Create List  agglo
    @{dossier_instruction_type} =  Create List  PCI - P - Initial
    &{values} =  Create Dictionary
    ...  libelle=TST PARAMETRAGE
    ...  couleur=FFBB1C
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=0
    ${paupiette} =  Ajouter un enjeu et récupérer son identifiant  ${values}
    # fil d'Ariane
    Le titre de la page doit être  Paramétrage Dossiers > Dossiers > Enjeu > ${paupiette} TST PARAMETRAGE
    # Affichage des champs
    Element Should Contain  css=#libelle  TST PARAMETRAGE 
    Element Should Contain  css=#couleur  FFBB1C
    Element Should Contain  css=#om_collectivite  agglo
    Element Should Contain  css=#dossier_instruction_type  PCI - P - Initial

    # Ajout d'un enjeu sans remplir les champs obligatoire
    &{values} =  Create Dictionary
    ...  priorite=1
    Ajouter un enjeu  ${values}
    Error Message Should Contain  Le champ libellé est obligatoire


    # Test du formulaire de modification d'un enjeu
    @{om_collectivite} =  Create List  MARSEILLE  ALLAUCH
    @{dossier_instruction_type} =  Create List  PCI - T - Transfert  PCI - M - Modificatif
    &{values} =  Create Dictionary
    ...  libelle=TST PARAMETRAGE 2
    ...  couleur=C572D6
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=33
    Modifier un enjeu  ${paupiette}  ${values}
    # Affichage des champs
    Element Should Contain  css=#libelle  TST PARAMETRAGE 2
    Element Should Contain  css=#couleur  C572D6
    Element Should Contain  css=#om_collectivite  MARSEILLE\nALLAUCH
    Element Should Contain  css=#dossier_instruction_type  PCI - M - Modificatif\nPCI - T - Transfert

    # Modification d'un enjeu sans remplir les champs obligatoire
    &{values} =  Create Dictionary
    ...  libelle=${EMPTY}
    Modifier un enjeu  ${paupiette}  ${values}
    Error Message Should Contain  Le champ libellé est obligatoire


    # Test du formulaire de suppression
    Supprimer un enjeu  ${paupiette}

Listing
    [Documentation]  Avec un profil administrateur, accède au listing des enjeux et
    ...  vérifie :
    ...    - l'absence d'erreur à l'affichage du listing
    ...    - l'affichage du fil d'Ariane
    ...    - le fonctionnement de la recherche
    ...    - le fonctionnement du tri des colonnes

    # absence d'erreur à l'affichage du listing
    Depuis le listing    enjeux
    La page ne doit pas contenir d'erreur

    # fil d'Ariane
    Le titre de la page doit être  Paramétrage Dossiers > Dossiers > Enjeu

    # fonctionnement de la recherche
    @{options_recherche} =  Get List Items  css=select[name="selectioncol"]
    @{valeurs_recherche} =  Create List  1  2  ERP  FFD700  1
    @{resultats_attendu} =  Create List  ERP  urbanisme  ERP  urbanisme  ERP
    ${nb_index} =  Get length  ${options_recherche}
    :FOR  ${index}  IN RANGE  ${nb_index} -1 
    \  Use Simple Search  @{options_recherche}[${index}]  @{valeurs_recherche}[${index}]
    \  La page ne doit pas contenir d'erreur
    \  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  @{resultats_attendu}[${index}]


    # fonctionnement du tri
    # TODO

Verification du tri de priorite dans la page du dossier
    [Documentation]  Ce test sert a verifier le tri des enjeux dans la page du dossier

    # Variable definit
    @{om_collectivite} =  Create List  MARSEILLE  ALLAUCH  agglo
    @{dossier_instruction_type} =  Create List  PCI - P - Initial

    # Jeu de données
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Maitre
    ...  particulier_prenom=GIMS
    ...  om_collectivite=agglo
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=agglo
    ${dossier} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    &{values_enjeux_1} =  Create Dictionary
    ...  libelle=enjeu1
    ...  couleur=BBBBBB
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=2
    ${id_1} =  Ajouter un enjeu  ${values_enjeux_1}
    &{values_enjeux_2} =  Create Dictionary
    ...  libelle=enjeu1_bis
    ...  couleur=BBBBBB
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=2
    ${id_2} =  Ajouter un enjeu  ${values_enjeux_2}
    &{values_enjeux_3} =  Create Dictionary
    ...  libelle=enjeu3
    ...  couleur=BBBBBB
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=1
    ${id_3} =  Ajouter un enjeu  ${values_enjeux_3}
    &{values_enjeux_4} =  Create Dictionary
    ...  libelle=aenjeu4
    ...  couleur=BBBBBB
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=2
    ${id_4} =  Ajouter un enjeu  ${values_enjeux_4}

    # Ajout des enjeux
    @{enjeux} =  Create List  ${values_enjeux_1.libelle}  ${values_enjeux_2.libelle}  ${values_enjeux_3.libelle}  ${values_enjeux_4.libelle}
    ${values} =  Create Dictionary
    ...  enjeux=${enjeux}
    Modifier le dossier d'instruction  ${dossier}  ${values}
    
    # On verifie le tri
    ${enjeux_list} =  Get Text  enjeux
    ${enjeux_list_2} =  Set Variable  ${values_enjeux_3.libelle}\n${values_enjeux_4.libelle}\n${values_enjeux_1.libelle}\n${values_enjeux_2.libelle}
    Should Be Equal    ${enjeux_list}    ${enjeux_list_2}