*** Settings ***
Documentation  Test des tasks Controle des données retour d'avis.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  Run Keywords
    ...         For Suite Setup
    ...  AND    Activation des options générales
    ...  AND    Composition du jeu de données
Suite Teardown  Run Keywords
    ...         Desactivation des options générales
    ...  AND    For Suite Teardown

*** Keywords ***
Activation des options générales
    [Documentation]  Il est nécessaire de faire : 
    ...  l'activation de 'option_notification_piece_numerisee' pour éviter le fail : 
    ...  FAIL: Element with locator 'dossier_message_id' not found.
    ...  l'activation de l'option 'option_afficher_division' pour éviter le fail 
    ...  liée a l'affichage de la vision ex : '"Juriste" == "Juriste (H)"' should be true.

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    # Permet le même comportement du test qu'il soit exécuté en runone ou runall
    &{param_division} =  Create Dictionary
    ...  libelle=option_afficher_division
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_division}

    Depuis la page d'accueil  admin  admin
    Rendre les types de dossier d'autorisation détaillés utilisés transmissible à Plat'AU  PCI

Desactivation des options générales
    [Documentation]  Reset des options

    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}

    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_afficher_division
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}

    Depuis la page d'accueil  admin  admin
    Rendre un type de dossier d'autorisation detailles non transmissible a Plat'AU  PCI

Composition du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données

    Run Keyword If  '${CONTEXT_TASK_CREATED}' == 'False'  Initialisation du jeu de données 300_task
    Set Global Variable  ${CONTEXT_TASK_CREATED}  True


*** Test Cases ***
Test intégration task prescription
    [Documentation]  Test intégration task prescription

    # Ajout d'un dossier
    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST308TASK_PEC_PRESCRIPTION_NOM01
    ...  particulier_prenom=TEST308TASK_PEC_PRESCRIPTION_PRENOM01
    ...  om_collectivite=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ${di} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}
    ${di_se} =  Sans espace  ${di}

    Ajouter une consultation depuis un dossier  ${di}  ${code_service1} - ${libelle_service1}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#sousform-consultation #service
    ${consultation_id} =  Get Value  css=#sousform-consultation #consultation

    ${external_uid_di} =  Set Variable  EXT_UID_DOS_${di_se}
    &{external_uid_values} =  Create Dictionary
    ...  object=dossier
    ...  object_id=${di_se}
    ...  external_uid=${external_uid_di}
    ...  dossier=${di_se}
    ...  category=platau
    ${status} =  Run Keyword And Return Status  Récupérer un external UID  ${di_se}  dossier
    Run Keyword If  ${status} == False  Ajouter un external UID  ${external_uid_values}

    ${external_uid_consult} =  Set Variable  EXT_UID_CSL_${consultation_id}
    &{external_uid_values} =  Create Dictionary
    ...  object=consultation
    ...  object_id=${consultation_id}
    ...  external_uid=${external_uid_consult}
    ...  dossier=${di_se}
    ...  category=platau
    ${status} =  Run Keyword And Return Status  Récupérer un external UID  ${consultation_id}  consultation
    Run Keyword If  ${status} == False  Ajouter un external UID  ${external_uid_values}

    ${json_payload} =  Get File  ${EXECDIR}${/}binary_files${/}json_payload_consultation_prescription_input.json

    ${date} =  Date du jour FR

    ${json_payload} =  Replace String  ${json_payload}  AAA-BBB-CCC  ${external_uid_consult}
    ${json_payload} =  Replace String  ${json_payload}  RRR-SSS-TTT  ${external_uid_di}
    ${json_payload} =  Replace String  ${json_payload}  OOO-PPP-QQQ  EXT-UID-PRE_${consultation_id}
    ${task_values} =  Create Dictionary
    ...  type=prescription_consultation
    ...  json_payload=${json_payload}
    ${task_id} =  Ajouter la tâche par WS  ${task_values}  application

    Déclencher le traitement des tâches par WS

    Depuis le contexte de la consultation  ${di}  ${consultation_id}

    Element Should Contain  css=#fieldset-sousform-consultation-retour #date_retour  05/05/2022
    Element Should Contain  css=#fieldset-sousform-consultation-retour #prescription_consultation  Absence de prescription / renonciation à prescrire
    Element Should Contain  css=#fieldset-sousform-consultation-informations-plat_au #texte_fondement_avis  Test 308 Fondement01