*** Settings ***
Documentation     TestSuite "Documentation" : cette suite permet d'extraire
...    automatiquement les captures du portail citoyen à destination de la documentation.
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown
# A chaque début de Test Case on positionne la taille de la fenêtre
# pour obtenir des captures homogènes
Test Setup    Set Window Size  ${1280}  ${1024}

*** Test Cases ***

CE du formulaire d'acces au portail citoyen
    [Documentation]  L'objet de ce 'Test Case' est de constituer les captures d'écran
    ...    en lien avec le formulaire d'accès au portail citoyen

    [Tags]  doc

    # SCREEN : a_parametres_phases.png
    Depuis la page d'accueil    admin    admin
    Go To    http://localhost/openads/web/citizen.php
    CCSS    screenshots/portail_citoyen/a_portail_citoyen_formulaire_acces.png    css=body

CE du paramétrage des pièces

    [Documentation]  Captures d'écran concernant le suivi du de dossier du portail citoyen

    [Tags]  doc

    #
    # Type de pièce
    #

    Depuis la page d'accueil  admin  admin

    #
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Hervé
    ...  particulier_prenom=Marguerite
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    #
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis le contexte du dossier d'instruction  ${di}
    # On vérifie le fil d'Ariane
    Le titre de la page doit être    Instruction > Dossiers D'instruction > ${di} HERVÉ MARGUERITE
    # On vérifie que le champ contenant la clé d'accès au portail citoyen n'est pas vide
    Open Fieldset    dossier_instruction    demandeur
    Wait Until Element Is Visible  cle_acces_citoyen
    ${citizen_access_key} =  Get Text  cle_acces_citoyen
    Should Not Be Empty  ${citizen_access_key}

    # Formatage de la clé d'accès sans les tirets
    ${citizen_access_key} =  STR_REPLACE  -  ${EMPTY}  ${citizen_access_key}
    
    # Division de la clé d'accès en 4 parties
    ${split1} =  Get Substring  ${citizen_access_key}  0  4
    ${split2} =  Get Substring  ${citizen_access_key}  4  8
    ${split3} =  Get Substring  ${citizen_access_key}  8  12
    ${split4} =  Get Substring  ${citizen_access_key}  12  16

    # On récupère le numéro du DA
    ${da} =  Get Substring  ${di}  0  -2
    Log To Console  ${da}

    # On ouvre la page d'accueil du portail
    Go To    http://localhost/openads/web/citizen.php
    La page ne doit pas contenir d'erreur
    # On vérifie que les champs de saisis sont visible
    Page Should Contain Element  css=#dossier
    Page Should Contain Element  css=#cle_acces_citoyen_split1
    # On vérifie qu'un champ timestamp caché est présent
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Page Should Contain Element  css=#timestamp_generation_formulaire

    # On remplit le formulaire avec le numéro de dossier et la clé d'accès
    Wait Until Element Is Visible    dossier
    Input Text    dossier    ${da}
    Wait Until Element Is Visible    cle_acces_citoyen_split1
    Input Text    cle_acces_citoyen_split1    ${split1}
    Input Text    cle_acces_citoyen_split2    ${split2}
    Input Text    cle_acces_citoyen_split3    ${split3}
    Input Text    cle_acces_citoyen_split4    ${split4}
    # On valide le formulaire
    Click Element    css=input[name="validation"][type="submit"]

    # SCREEN : a_portail_citoyen_bloc_en_cours_validite.png
    # Mise en avant du bloc "En cours de validité"
    Update element style    css=.enCoursValidité    border    3px solid black
    Update element style    css=.listeLots    border    3px solid green
    Update element style    css=.historiqueDecisions    border    3px solid red

    # SCREEN : a_portail_citoyen_bloc_en_cours_instruction.png
    # Mise en avant du bloc "En cours d'instruction"
    Update element style    css=.enCoursInstruction    border    3px solid black

    CCSS    screenshots/portail_citoyen/a_portail_citoyen_suivi_dossier.png    css=.formulaire