*** Settings ***
Documentation     TestSuite "Documentation" : cette suite permet d'extraire
...    automatiquement les captures à destination de la documentation.
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown
# A chaque début de Test Case on positionne la taille de la fenêtre
# pour obtenir des captures homogènes
Test Setup    Set Window Size  ${1280}  ${1024}

*** Test Cases ***

CE du formulaire de paramètrage de phases

    [Documentation]  L'objet de ce 'Test Case' est de constituer les captures d'écran
    ...    en lien avec le paramétrage phase de l'application

    [Tags]  doc

    # SCREEN : a_parametres_phases.png
    Depuis la page d'accueil    admin    admin
    Go To    http://localhost/openads/app/index.php?module=form&obj=phase&action=0&advs_id=&premier=0&tricol=&valide=&retour=form
    CCSS    screenshots/parametres/a_parametres_phase.png    css=#form-container


CE du paramétrage des pièces

    [Documentation]  Captures d'écran concernant la gestion des pièces.

    [Tags]  doc

    #
    # Type de pièce
    #

    Depuis la page d'accueil  admin  admin
    Depuis le listing  document_numerise_type
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_document_numerise_type_form.png
    ...    content



CE du paramétrage de la nomenclature des pièces

    [Documentation]  Captures d'écran concernant la gestion des pièces.

    [Tags]  doc

    #
    # Nomenclature de pièce
    #

    Depuis la page d'accueil  admin  admin
    Depuis le listing  lien_document_n_type_d_i_t
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_document_numerise_nomenclature_form.png
    ...    content

CE du menu de mise à jour des métadonnées

    [Documentation]  Captures d'écran concernant la gestion des pièces.

    [Tags]  doc

    #
    # Type de pièce
    #

    Depuis la page d'accueil  admin  admin
    Depuis le listing  document_numerise_type
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_document_numerise_type_form.png
    ...    content

    #
    # Traitement des pièces
    #

    Go To  ${PROJECT_URL}${OM_ROUTE_FORM}&obj=document_numerise_traitement_metadonnees&action=100&idx=0
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_document_numerise_metadata_treatment.png
    ...    content

    # Afin d'avoir un fichier en erreur, on le supprime sur le filestorage
    Remove Directory  ../var/filestorage/79/79d4  true
    # On modifie un type de pièces
    ${dnt_code} =  Set Variable  ART
    &{dnt_values} =  Create Dictionary
    ...  aff_da=true
    Modifier le type de pièces  ${dnt_code}  ${dnt_values}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    Go To  ${PROJECT_URL}${OM_ROUTE_FORM}&obj=document_numerise_traitement_metadonnees&action=100&idx=0
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Cette page permet de mettre à jour certaines métadonnées des pièces numérisées.
    Click On Submit Button
    Sleep  1
    La page ne doit pas contenir d'erreur
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Le traitement s'est correctement déroulé, sauf pour les pièces numérisées ci-dessous :
    Valid Message Should Contain  Dossier d'instruction n°AZ0130551200001P0 : le document 20160919ART.pdf n'a pas pu être mis à jour.

    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_document_numerise_metadata_treatment_res.png
    ...    content

CE du parametrage des commissions
    [Tags]  doc
    [Documentation]  L'objet de ce 'Test Case' est de faire une CE du
    ...  type de commission.

    Depuis la page d'accueil  admin  admin
    Depuis le listing  commission_type
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_type_commission_parametrage.png
    ...    css=#formulaire

CE du parametrage des services
    [Tags]  doc
    [Documentation]  L'objet de ce 'Test Case' est de faire une CE du
    ...  formulaire d'ajout des services

    Depuis la page d'accueil  admin  admin
    Depuis le listing  service
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_service_parametrage.png
    ...    css=#formulaire
    

CE du parametrage des tiers
    [Tags]  doc
    [Documentation]  L'objet de ce 'Test Case' est de faire une CE du
    ...  formulaire d'ajout des tiers et du listing des tiers.
    ...  La capture du listing des tiers met en évidence le fait que si
    ...  une catégorie est lié à plusieurs collectvité alors un tiers
    ...  rattaché à cette catégorie sera affiché une fois pour chaque
    ...  collectivités liées.

    Depuis la page d'accueil  admin  admin
    Depuis le listing  tiers_consulte
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_tiers_parametrage.png
    ...    css=#formulaire
    

    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie MA
    ...  abrege=TMA
    ...  libelle=tiers M/A
    ...  ville=MARSEILLE
    ...  liste_diffusion=support@atreal.fr
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    Depuis le listing  tiers_consulte
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_listing_tiers.png
    ...    css=#formulaire

CE du parametrage des bibles
    [Tags]  doc
    [Documentation]  L'objet de ce 'Test Case' est de faire une CE des
    ...  bibles

    Depuis la page d'accueil  admin  admin
    Depuis le listing  bible
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_bible.png
    ...    css=#formulaire

CE du paramétrage des logos
    [Documentation]  Captures d'écran concernant la gestion des logos.
    [Tags]  doc

    Depuis la page d'accueil  admin  admin
    Depuis le listing  om_logo
    Click On Add Button
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_edition_logo.png
    ...    content
    Depuis le listing  om_logo
    Click Link  logopdf.png multi
    Capture and crop page Screenshot Sleep  screenshots/parametres/a_parametrage_edition_logo_portlet.png
    ...  portlet-actions