*** Settings ***
Documentation     TestSuite "Documentation" : cette suite permet d'extraire
...    automatiquement les captures à destination de la documentation des instructions
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown
# En début de Test Case on positionne la taille de la fenêtre
# pour obtenir des captures homogènes
Test Setup    Set Window Size  ${1280}  ${1024}


*** Test Cases ***
Constitution d'un jeu de données
    [Documentation]  Constitution d'un jeu de données cohérent
    ...  pour les scénarios fonctionnels à suivre
    [Tags]  doc

    Depuis la page d'accueil  admin  admin
    &{param_values} =  Create Dictionary
    ...  libelle=option_sig
    ...  valeur=sig_externe
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}
    # action de mise à jour de la date d'affichage
    &{args_action} =  Create Dictionary
    ...  action=maj_date_affichage
    ...  libelle=mise à jour de la date d'affichage
    ...  regle_date_affichage=date_evenement
    Ajouter Action  ${args_action}
    # évènement d'affichage obligatoire
    &{args_evenement} =  Create Dictionary
    ...  evenement=89
    ...  libelle=affichage_obligatoire
    ...  action=mise à jour de la date d'affichage
    Modifier l'événement  ${args_evenement}

    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST035DATEAFF
    ...  particulier_prenom=TEST035DATEAFF
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire}
    Set Suite Variable  ${di}


Captures d'écrans des instructions
    [Documentation]  Capture des screens en lien avec les instructions
    [Tags]  doc

    # => a_instruction_action_modifier_date_affichage.png
    Depuis la page d'accueil  instrpoly  instrpoly
    Depuis le formulaire de modification du dossier d'instruction  ${di}
    Highlight heading  date_affichage
    CCSS  screenshots/instruction/a_instruction_action_modifier_date_affichage.png
    ...   css=#fieldset-form-dossier_instruction-instruction

    # => a_instruction_portlet_generate_citizen_access_key.png
    Depuis le listing  dossier_instruction
    Click Link  DURAND GÉRARD
    Highlight heading  action-form-dossier_instruction-generate_citizen_access_key
    CCSS  screenshots/instruction/a_instruction_portlet_generate_citizen_access_key.png
    ...   css=#portlet-actions

    # => a_instruction_portlet_regenerate_citizen_access_key.png
    Click On Form Portlet Action  dossier_instruction  generate_citizen_access_key
    Depuis la page d'accueil  admin  admin
    Depuis le listing  dossier_instruction
    Click Link  DURAND GÉRARD
    Highlight heading  action-form-dossier_instruction-regenerate_citizen_access_key
    CCSS  screenshots/instruction/a_instruction_portlet_regenerate_citizen_access_key.png
    ...   css=#portlet-actions

    # => a_instruction_complement_bible.png
    Ajouter une instruction au DI  ${di}  accepter un dossier sans réserve
    Click Element  css=#fieldset-sousform-instruction-complement .fieldsetContent div.field:nth-of-type(3) a
    CCSS  screenshots/instruction/a_instruction_complement_bible.png
    ...   css=#tab-bible

    # => a_instruction_portlet_geolocalisation.png
    Depuis la page d'accueil  admin  admin
    &{param_values} =  Create Dictionary
    ...  libelle=option_sig
    ...  valeur=sig_externe
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}
    Depuis le contexte du dossier d'instruction  ${di}
    Highlight heading  action-form-dossier_instruction-geolocalisation
    CCSS  screenshots/instruction/a_instruction_portlet_geolocalisation.png
    ...   css=#portlet-actions

    # => a_instruction_geolocalisation_view.png
    Click Link  css=#action-form-dossier_instruction-geolocalisation
    CCSS  screenshots/instruction/a_instruction_geolocalisation_view.png
    ...   css=#sousform-geolocalisation_sig